Outlook 연락처 그룹의 모든 구성원을 Excel로 내보내는 2가지 방법

Outlook 솔루션 2025 년 9 월 29 일

때때로 특정 Outlook 연락처 그룹의 구성원을 내보내고 싶을 수 있습니다. 따라서 이 기사에서는 그룹 구성원을 Excel로 추출하는 두 가지 방법을 공유합니다.

Outlook은 특정 연락처 폴더의 모든 연락처를 내보낼 수 있는 기본 기능을 제공합니다. 그러나 연락처 그룹의 구성원을 추출하는 것은 말할 것도 없고 연락처 그룹을 내보낼 수도 없습니다. 따라서 선택한 연락처 그룹의 구성원을 추출하려면 더 많은 노력이 필요합니다. 다음은 참조할 수 있는 두 가지 팁입니다.

방법 1: 다른 이름으로 저장을 통해 그룹 구성원 추출

맨 처음에 Outlook을 시작합니다.
그런 다음 구성원을 추출해야 하는 연락처 그룹을 찾아 선택합니다.
다음으로 "파일" 메뉴로 이동하여 "다른 이름으로 저장"을 클릭해야 합니다.
그런 다음 "다른 이름으로 저장" 팝업 대화 상자에서 저장할 대상 폴더를 선택하고 "파일 형식" 드롭다운 목록에서 "텍스트만"을 선택합니다.
그런 다음 "저장"을 클릭합니다.
그런 다음 Excel을 열고 새 Excel 파일을 만듭니다.
나중에 "파일"로 전환하고 "열기" 버튼을 클릭해야 합니다.
이어서 나타나는 "열기" 대화 상자에서 방금 연락처 그룹을 저장한 폴더에 먼저 액세스해야 합니다.
그런 다음 "파일 이름" 줄의 두 번째 상자를 클릭하고 드롭다운 목록에서 "모든 파일"을 선택합니다.
그런 다음 연락처 그룹의 텍스트 파일을 선택하고 "열기"를 누르십시오.
팝업 "텍스트 가져오기 마법사" 대화 상자에서 "구분"이 선택되어 있는지 확인하고 "마침" 버튼을 클릭합니다.
마지막으로 다음 스크린샷과 같이 구성원을 얻습니다.

방법 2: Outlook VBA를 통해 그룹 구성원 추출

우선 Outlook에서 "Alt + F11"키 버튼을 누릅니다.
그런 다음 VBA 편집기 창에서 새 모듈을 엽니다.
그런 다음 다음 VBA 코드를 복사하십시오.

Sub ExtractContactGroupMembersToExcel()
    Dim objContactGroup As Outlook.DistListItem
    Dim objMember As Outlook.recipient
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim i As Integer
    Dim nRow As Integer
    Dim strPath As String
    Dim strFilename As String
 
    Select Case Application.ActiveWindow.Class
           Case olExplorer
                Set objContactGroup = Application.ActiveExplorer.Selection(1)
           Case olInspector
                Set objContactGroup = Application.ActiveInspector.CurrentItem
    End Select
 
    If TypeOf objContactGroup Is DistListItem Then
       'Create a new Excel workbook
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkBook = objExcelApp.Workbooks.Add
       Set objExcelWorkSheet = objExcelWorkBook.Worksheets(1)
 
       'Set the two column headers
       objExcelWorkSheet.Cells(1, 1) = "Contact Name"
       objExcelWorkSheet.Cells(1, 2) = "Email Address"

       nRow = 2
 
       'Extract the contact group members' names and email addresses
       For i = 1 To objContactGroup.MemberCount
           Set objMember = objContactGroup.GetMember(i)
           objExcelWorkSheet.Cells(nRow, 1) = objMember.Name
           objExcelWorkSheet.Cells(nRow, 2) = objMember.Address
           nRow = nRow + 1
       Next
 
       'AutoFit the columns in the new Excel worksheet
       objExcelWorkSheet.Columns("A:B").AutoFit
 
       'Change the strPath to your actual case
       strPath = "C:\Contact Groups\"
       strFilename = strPath & objContactGroup.DLName & ".xlsx"
 
       'Save the Excel workbook
       objExcelWorkBook.Close True, strFilename
 
       'Notify you of the export complete
       MsgBox ("Export Complete!")
    End If
End Sub

그런 다음 평상시처럼 QAT(빠른 액세스 도구 모음)에 매크로를 추가할 수 있습니다.
나중에 연락처 그룹을 선택하고 QAT에서 매크로 버튼을 클릭할 수 있습니다.
내보내기가 끝나면 "내보내기 완료!"라는 메시지가 표시됩니다.
결국 VBA 코드에 미리 정해진 폴더에서 Excel 파일을 찾을 수 있습니다. 열면 아래 이미지와 같이 그룹 구성원을 볼 수 있습니다.

이전 PST 데이터 복구

Outlook은 충돌에 취약하므로 PST 데이터가 징조 없이 손상될 수 있습니다. 따라서 PST 파일을 정기적으로 백업해야 합니다. 또한 다음과 같은 강력한 도구를 준비하는 것이 좋습니다. DataNumen Outlook Repair, 이는 수 수리 Outlook 적시에 데이터.

저자 소개 :

Shirley Zhang은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. SQL 수정 및 전망 수리 소프트웨어 제품. 자세한 내용은 WWW.datanumen.COM