როგორ სწრაფად ამოიღოთ ყველა მიმღები მრავალი Outlook შეტყობინების (.msg) ფაილიდან

Outlook Solutions სექტემბერი 29, 2025

ზოგიერთ მომხმარებელს სურს სწრაფად ამოიღოს ყველა მიმღები Outlook-ის ელფოსტიდან შენახული Outlook-ის შეტყობინებების რამდენიმე ფაილიდან. ახლა, ეს პost შევხედავთ ამას სწრაფი მიდგომის გასაზიარებლად.

მიმღებების ამოსაღებად ერთი Outlook შეტყობინების ფაილიდან, შეგიძლიათ მხოლოდ ორჯერ დააწკაპუნოთ მის გასახსნელად და შემდეგ დააკოპიროთ მიმღებები გახსნილ Message ფანჯარაში. მაგრამ, თუ თქვენ გჭირდებათ Outlook შეტყობინებების ფაილების ჯგუფთან გამკლავება, სახელმძღვანელო მეთოდი საკმარისად ეფექტური არ არის. ამრიგად, თქვენ შეგიძლიათ მოძებნოთ ბევრად უფრო ეფექტური გზა. აი ასეთს გაგაცნობთ. წაიკითხეთ მისი დეტალების გასაგებად.

ამოიღეთ ყველა მიმღები მრავალი Outlook შეტყობინების (.msg) ფაილიდან

როგორცtart, მიიღეთ წვდომა Outlook VBA რედაქტორზე ""როგორ გაუშვათ VBA კოდი თქვენს Outlook-ში".
შემდეგი, დააკოპირეთ და ჩასვით შემდეგი VBA კოდი ცარიელ მოდულში.

Dim strRecipients As String

Sub ExtractRecipientsFromOutlookMSGFiles()
    Dim objShell, objWindowsFolder As Object
 
    strRecipients = ""
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       Call ProcessWindowsFolders(objWindowsFolder.self.Path & "\")
       'Display a Message
       MsgBox "Recipients: " & vbCrLf & strRecipients, vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessWindowsFolders(strFolderPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.Recipient
    Dim objSubfolder As Object

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strFolderPath)
 
    For Each objFile In objFolder.Files
        If objFileSystem.GetExtensionName(objFile) = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)

           If TypeName(objItem) = "MailItem" Then
              Set objMail = objItem
              'Extract recipients' email addresses
              For Each objRecipient In objMail.Recipients
                  strRecipients = strRecipients & objRecipient.Address & vbCr
              Next
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubfolder In objFolder.SubFolders
           If ((objSubfolder.Attributes And 2) = 0) And ((objSubfolder.Attributes And 4) = 0) Then
               Call ProcessWindowsFolders(objSubfolder.Path)
           End If
       Next
    End If
End Sub

შემდეგ გადაიტანეთ კურსორი პირველ ქვეპროგრამაში.
შემდეგ დააჭირეთ ღილაკს "გაშვება" ან დააჭირეთ "F5" ღილაკს.
შემდეგ, ამომხტარ დიალოგურ ფანჯარაში, აირჩიეთ Windows საქაღალდე, რომელიც შეიცავს წყარო Outlook შეტყობინების (.msg) ფაილებს.
არჩევის შემდეგ დააწკაპუნეთ „OK“-ზე, რათა მაკრო გააგრძელოს მუშაობა.
როდესაც მაკრო დასრულდება, გამოჩნდება შეტყობინება, რომელშიც მითითებულია ყველა ამოღებული მიმღების ელფოსტის მისამართი, როგორც ნაჩვენებია შემდეგ ეკრანის სურათზე.

დაიცავით თქვენი Outlook მონაცემები საფრთხისგან

Outlook-ის მონაცემები აშკარად მიდრეკილია კორუფციისკენ. აქედან გამომდინარე, საკმაოდ რთული ამოცანაა Outlook-ის მონაცემების დაცვა. ის მოითხოვს თქვენგან დაჟინებას Outlook მონაცემების რეგულარული სარეზერვო ასლის გაკეთებაში. ასევე, თუ ეს შესაძლებელია, გონივრული და რეკომენდებულია გამოცდილი და პროფესიონალი Outlook-ის მომზადება PST შეკეთება ინსტრუმენტი, როგორიცაა DataNumen Outlook Repair, ასე რომ თქვენ შეგიძლიათ მიიღოთ დაუყოვნებლივი და დროული გადარჩენა Outlook-ის კორუფციის შემთხვევაში.

ავტორი შესავალი:

შირლი ჟანგი არის მონაცემთა აღდგენის ექსპერტი DataNumen, Inc., რომელიც მსოფლიო ლიდერია მონაცემთა აღდგენის ტექნოლოგიებში, მათ შორის გამოჯანმრთელება Sql Server და Outlook სარემონტო პროგრამული პროდუქტები. დამატებითი ინფორმაციისთვის ეწვიეთ www.datanumen. ერთად