როგორ მივიღოთ შეტყობინება, თუ არ მიიღებთ პასუხს კონკრეტულ ელფოსტაზე მოსალოდნელ დროში

ეს სტატია გასწავლით VBA-ს გამოყენებით სწრაფ ხრიკს, რათა Outlook-მა ავტომატურად მოგთხოვოთ, გაგზავნოთ თუ არა შეტყობინების ელფოსტა, როდესაც კონკრეტულ წერილზე პასუხი არ მიგიღიათ კონკრეტულ დროში.

ხანდახან, სასიცოცხლოდ მნიშვნელოვანი ელ.წერილებისთვის, თქვენ აუცილებლად მოუთმენლად ელით მის პასუხებს. სხვა სიტყვებით რომ ვთქვათ, თქვენ უნდა გქონდეთ იმედი, რომ მიმღებს შეუძლია რაც შეიძლება მალე გიპასუხოთ. წინააღმდეგ შემთხვევაში, სანამ პასუხი ჯერ არ მიგიღიათ მოსალოდნელ დროში, თქვენ კვლავ გაუგზავნით მიმღებს შემდგომ შეტყობინების ელფოსტას. ამიტომ, ამ მოთხოვნის საპასუხოდ, აქ შემოგთავაზებთ მეთოდს, რომელიც იყენებს VBA-ს, რათა Outlook-მა ავტომატურად გააფრთხილოს და მოგთხოვოთ ასეთ შემთხვევაში. წაიკითხეთ დაწვრილებითი ნაბიჯებისა და კოდების მისაღებად.

მიიღეთ შეტყობინება, თუ არ მიიღებთ პასუხს კონკრეტულ ელფოსტაზე მოსალოდნელ დროში

1. თავიდანვე, სtarთქვენი Outlook.
2. შემდეგ თქვენ უნდა დააყენოთ კონკრეტული შეხსენების დრო კონკრეტულ ელფოსტაზე.

• პირველ რიგში, დააწკაპუნეთ მაუსის მარჯვენა ღილაკით კონკრეტულ ელ.წერილზე.
• შემდეგ აირჩიეთ „შემდეგი“ > „შეხსენების დამატება“.
• დიალოგურ ფანჯარაში შეგიძლიათ დააყენოთ შეხსენების დრო იგივე კონკრეტული დროის განმავლობაში, რომლის ფარგლებშიც გსურთ მიიღოთ მისი პასუხი.

3. ამის შემდეგ დააჭირეთ "Alt + F11" ღილაკებს Outlook VBA რედაქტორზე წვდომისთვის.
4. შემდეგ ახალ ფანჯარაში გახსენით პროექტი „ThisOutlookSession“ და დააკოპირეთ მასში შემდეგი კოდები.

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

'If receive the reply, clear the flag and remove the reminder
Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objSentItems As Outlook.Items
    Dim objVariant As Variant
    Dim i As Long
    Dim strSubject As String
    Dim dSendTime As String
 
    Set objSentItems = Outlook.Application.Session.GetDefaultFolder(olFolderSentMail).Items
 
    If Item.Class = olMail Then
       For i = 1 To objSentItems.Count
           If objSentItems.Item(i).Class = olMail Then
              Set objVariant = objSentItems.Item(i)
              strSubject = LCase(objVariant.Subject)
              dSendTime = objVariant.SentOn
 
              If LCase(Item.Subject) = "re: " & strSubject Or InStr(LCase(Item.Subject), strSubject) > 0 Then
                 If Item.SentOn > dSendTime Then
                    With objVariant
                         .ClearTaskFlag
                         .ReminderSet = False
                         .Save
                    End With
                 End If
              End If
           End If
       Next i
    End If
End Sub

'Get a prompt asking if to send a notification email
Private Sub Application_Reminder(ByVal Item As Object)
    Dim strPrompt As String
    Dim nResponse As Integer
    Dim objFollowUpMail As Outlook.MailItem
 
    'You can change the subject as per your real case
    If (Item.Class = olMail) And (LCase(Item.Subject) = "datanumen outlook repair") Then
       strPrompt = "You haven't yet recieved the reply of " & Chr(34) & Item.Subject & Chr(34) & " within your expected time. Do you want to send a follow-up notification email?"
       nResponse = MsgBox(strPrompt, vbYesNo + vbQuestion, "Confirm to Send a Follow-Up Notification Email")
       If nResponse = vbYes Then
          Set objFollowUpMail = Application.CreateItem(olMailItem)
          With objFollowUpMail
               .To = Item.Recipients.Item(1).Address
               .Subject = "Follow Up: " & Chr(34) & Item.Subject & Chr(34)
               .Body = "Please respond to my email " & Chr(34) & Item.Subject & Chr(34) & "as soon as possible"
               .attachments.Add Item
               .Display
          End With
       End If
    End If
End Sub

5. ამის შემდეგ, მოაწერეთ ხელი ამ კოდს.
6. მოგვიანებით შეცვალეთ Outlook მაკრო პარამეტრი ციფრულად ხელმოწერილი მაკროების დასაშვებად.
7. საბოლოოდ რეზtart Outlook ახალი მაკროს გასააქტიურებლად. ამიერიდან Outlook იმუშავებს შემდეგნაირად:

• თუ თქვენ მიიღეთ პასუხი კონკრეტულ ელფოსტაზე, სანამ მისი შეხსენება გამოჩნდება, Outlook ავტომატურად გაასუფთავებს დროშას და გამორთავს შეხსენებას.
• თუ არ მიგიღიათ პასუხი მისი შეხსენების გაშვებისას, Outlook მოგთხოვთ გაგზავნოთ თუ არა შემდგომი შეტყობინების ელფოსტა. თუ აირჩევთ "დიახ", ელ.წერილი გაიგზავნება. თუ აირჩიეთ "არა", მოთხოვნა ერთდროულად გაქრება.

მოაგვარეთ შემაშფოთებელი Outlook საკითხები

როგორც Outlook არის შეცდომის მიდრეკილება, თავიდან აცილების მიზნით პერსპექტიული კორუფციასჯობს არ დაეყრდნოთ მხოლოდ შემოსულების ინსტრუმენტს, Scanpst.exe. თქვენ უნდა მოამზადოთ სხვა ძლიერი და რეპუტაციის მქონე სარემონტო ინსტრუმენტი, როგორიცაა DataNumen Outlook Repair, რომელსაც შეუძლია გადაჭრას შემაშფოთებელი საკითხები, რომლებსაც Scanpst.exe ვერ მოაგვარებს.

ავტორი შესავალი:

შირლი ჟანგი არის მონაცემთა აღდგენის ექსპერტი DataNumen, Inc., რომელიც მსოფლიო ლიდერია მონაცემთა აღდგენის ტექნოლოგიებში, მათ შორის sql კორუფცია და Outlook სარემონტო პროგრამული პროდუქტები. დამატებითი ინფორმაციისთვის ეწვიეთ www.datanumen. ერთად