各色のカテゴリのOutlookの予定に費やされた合計時間をすばやくエクスポートする方法

Outlookソリューション 2025 年 9 月 29 日

各カラーカテゴリの予定に費やした合計時間に関するレポートを作成する場合は、この記事で紹介した方法を利用できます。手動で数える必要なしに、これを短時間で達成するのに役立ちます。

多くのユーザーは、ほとんどのアクティビティをOutlookカレンダーに記録することに慣れています。また、それらをより簡単に管理・区別するために、それぞれにカテゴリを割り当てています。この場合、一部のユーザーは、各色のカテゴリのカレンダー項目に費やした合計時間を示すレポートを作成したいと考えます。もちろん、手動でカウントして入力するのは面倒です。そこで、ここでは簡単なクリック操作でこのタスクを実行できる方法をご紹介します。

各カラーカテゴリの予定に費やされた合計時間をエクスポートする

まず、Outlookアプリケーションを起動します。
次に、Outlookウィンドウに入った後、「Alt + F11」キーボタンをタップできます。
その後、「Microsoft Visual BasicforApplications」ウィンドウにアクセスできるようになります。
次に、「Microsoft Excel オブジェクトライブラリ」を有効にする必要があります。「ツール」＞「参照」をクリックすると有効になります。
次に、使用されていないモジュールを見つけて開く必要があります。
その後、次のVBAコードをこのモジュールにコピーする必要があります。

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

最後に、ツールバーの「実行」アイコンをクリックするか、「F5」キーボタンを押すかどうかに関係なく、このマクロをトリガーできます。
次に、特定のカレンダーを選択するように求められます。
「OK」を選択して押すと、マクロは引き続き実行されます。終了すると、バックグラウンドで表示される新しいExcelファイルが表示されます。
あなたはそれにアクセスすることができます。次のスクリーンショットのようになります。

Outlook周辺の潜在的な脅威に注意してください

Outlookユーザーは、不明な電子メールの添付ファイル、埋め込みリンク、人的エラーなど、すべての潜在的なリスクに注意する必要があります。そうしないと、Outlookがいつでも破損する可能性があります。また、定期的なOutlookデータのバックアップを作成し、専用の修復ツールを維持することが必要です。 DataNumen Outlook Repair は、最も推奨される修復ツールの1つです。 Outlookを修復する瞬間の問題。

著者紹介：

Shirley Zhangは、のデータ復旧の専門家です。 DataNumen、Inc。は、以下を含むデータ復旧技術の世界的リーダーです。破損したmdf と見通し修理ソフトウェア製品。詳細については、次のWebサイトをご覧ください。 WWW。datanumen.com