Outlook電子メールのすべての画像添付ファイルをExcelワークシートにすばやくエクスポートする方法

Outlookソリューション 2025 年 9 月 29 日
今すぐ共有：

Outlook電子メールのすべての画像添付ファイルをExcelワークシートにすばやくエクスポートする場合は、この記事を参照してください。 ここでは、手動でエクスポートするよりも効果的な方法を紹介します。

ああを含むメールを受け取ったときost 写真の添付ファイルのうち、Excelでレポートを作成するために使用する場合は、これらの画像をExcelワークシートにバッチでエクスポートできる方法を切望する必要があります。 それでは、そのようなアプローチを以下に紹介します。

Outlook電子メールのすべての画像添付ファイルをExcelワークシートにすばやくエクスポートする

電子メールのすべての画像添付ファイルをExcelワークシートにエクスポートする

  1. まず、通常の方法でOutlookアプリケーションにアクセスします。
  2. 次に、Outlookウィンドウで「Alt + F11」キーのショートカットを押すと、「Microsoft Visual BasicforApplications」ウィンドウが表示されます。
  3. この画面では、使用していないモジュールを開くか、新しいモジュールをまっすぐ挿入する必要があります。
  4. 次に、以下のVBAコードの一部をこのモジュールにコピーする必要があります。
Sub ExportAllImageAttachmentsToExcelWorksheet()
    Dim objSourceMail As Outlook.MailItem
    Dim objAttachment As Outlook.Attachment
    Dim strImage As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim objFile As Object
    Dim objFiles As Object
    Dim nRow As Integer
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objSourceMail = ActiveInspector.currentItem
           Case olExplorer
                Set objSourceMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    If Not (objSourceMail Is Nothing) Then
 
       'Save the image attachments to a temporary folder
       strTempFolder = Environ("Temp") & "\" & Format(Now, "yyyymmddhhmmss") & "\"
       MkDir (strTempFolder)
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
       For Each objAttachment In objSourceMail.Attachments
           If IsEmbedded(objAttachment) = False Then
              Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
                     Case "jpg", "jpeg", "png", "bmp", "gif"
                          objAttachment.SaveAsFile strTempFolder & objAttachment.filename
              End Select
           End If
       Next
 
       'Create a new Excel workbook
        Set objExcelApp = CreateObject("Excel.Application")
        Set objExcelWorkbook = objExcelApp.Workbooks.Add
        Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
        objExcelApp.Visible = True
        objExcelWorkbook.Activate
 
        'Get the images in the temporary folder
        Set objFiles = objFileSystem.GetFolder(strTempFolder).Files
 
        'Insert the images into this new Excel worksheet
        For Each objFile In objFiles
            strImage = strTempFolder & Trim(objFile.Name)
            nRow = nRow + 1
            With objExcelWorksheet
                 .Range("A" & nRow).value = objFile.Name
                 'Change the height and width as per your needs
                 .Range("B" & nRow).ColumnWidth = 10
                 .Range("B" & nRow).RowHeight = 80
                 .Range("B" & nRow).Activate
                 With .Pictures.insert(strImage)
                      With .ShapeRange
                           .LockAspectRatio = msoTrue
                           .Width = 50
                           .Height = 70
                      End With
                 End With
                 .Columns("A").AutoFit
                 .Activate
            End With
       Next
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

VBAコード-電子メールのすべての画像添付ファイルをExcelワークシートにエクスポートする

  1. その後、マクロを終了できます。
  2. 次に、「ファイル」>「オプション」>「クイックアクセスツールバー」に移動して、このマクロをクイックアクセスツールバーに追加します。
  3. 最後に、このマクロを今すぐ試すことができます。
  • まず、ソースメールを選択または開きます。
  • 次に、クイックアクセスツールバーのマクロボタンをクリックします。
  • マクロが完了すると、次のスクリーンショットのようなExcelワークシートが表示されます。エクスポートされたExcelワークシート

Outlookファイルが破損しないように保護する

Outlookは破損しやすいことが知られています。 したがって、Outlookフォームの破損を保護する方法を理解する必要があります。 まず、ウイルス攻撃をブロックするために、ウイルス対策ソフトウェアをインストールし、不明な添付ファイルをダウンロードしないようにする必要があります。 さらに、次のような強力な修復ツールを入手することをお勧めします。 DataNumen Outlook Repair。 それはmを提供することができますost の場合の効果的な救済 Outlookの破損.

著者紹介：

Shirley Zhangは、のデータ復旧の専門家です。 DataNumen、Inc。は、以下を含むデータ復旧技術の世界的リーダーです。 SQLの回復 と見通し修理ソフトウェア製品。 詳細については、次のWebサイトをご覧ください。 WWW。datanumen.com

今すぐ共有：

コメントは締め切りました。