Outlook連絡先グループのすべてのメンバーの詳細をExcelにすばやくエクスポートする方法

Outlookソリューション 2025 年 9 月 29 日

デフォルトでは、連絡先グループのメンバー名と電子メールアドレスのみを表示できます。メンバーのその他の詳細を取得したい場合は、この記事で紹介した方法を使用できます。

連絡先グループをダブルクリックして開くと、そのウィンドウには、グループメンバーの名前と電子メールアドレスのみが表示されます。会社、役職、電話番号、会社の住所など、メンバーの他の詳細を取得することはできません。通常、これらの詳細を取得するには、連絡先フォルダーでメンバーに対応する連絡先を手動で見つける必要があります。面倒すぎる。ここでは、これらの詳細をExcelワークブックにすばやくエクスポートできるVBAコードを紹介します。

連絡先グループのすべてのメンバーの詳細をExcelにエクスポートする

まず、Outlookアプリケーションを起動してください。
次に、Outlookのメインウィンドウで「Alt + F11」キーのショートカットを押す必要があります。
次に、新しい「Microsoft Visual Basic for Applications」ウィンドウで、使用されていないモジュールを開くか、新しいモジュールを直接挿入する必要があります。
続いて、次のVBAコードをコピーしてこのモジュールに貼り付けます。

Sub ExportMemberContactDetailsToExcel()
    Dim objContactGroup As Outlook.DistListItem
    Dim objGroupMember As Outlook.recipient
    Dim objContacts As Outlook.Items
    Dim objFoundContact As Outlook.ContactItem
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim i As Integer
    Dim nRow As Integer
    Dim strFilename As String
 
    Set objContactGroup = Application.ActiveExplorer.Selection(1)
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkBook = objExcelApp.Workbooks.Add
    Set objExcelWorkSheet = objExcelWorkBook.Worksheets(1)
 
    'Set the seven column headers
    With objExcelWorkSheet
         .Cells(1, 1) = "Name"
         .Cells(1, 2) = "Email Address"
         .Cells(1, 3) = "Company"
         .Cells(1, 4) = "Job Title"
         .Cells(1, 5) = "Phone Number"
         .Cells(1, 6) = "Mailing Address"
         .Cells(1, 7) = "Birthday"
    End With
 
    Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items.Restrict("[Email1Address]>''")
 
    nRow = 2
    For i = 1 To objContactGroup.MemberCount
        Set objGroupMember = objContactGroup.GetMember(i)
 
        strFilter = "[Email1Address] = '" & objGroupMember.Address & "'"
        Set objFoundContact = objContacts.Find(strFilter)
 
        If Not (objFoundContact Is Nothing) Then
           'Input the Contact Details
           With objExcelWorkSheet
                .Cells(nRow, 1) = objFoundContact.FullName
                .Cells(nRow, 2) = objFoundContact.Email1Address
                .Cells(nRow, 3) = objFoundContact.CompanyName
                .Cells(nRow, 4) = objFoundContact.JobTitle
                .Cells(nRow, 5) = objFoundContact.BusinessTelephoneNumber
                .Cells(nRow, 6) = objFoundContact.MailingAddress
             If objFoundContact.Birthday = #1/1/4501# Then
                .Cells(nRow, 7) = ""
             Else
                .Cells(nRow, 7) = objFoundContact.Birthday
             End If
           End With
       Else
           With objExcelWorkSheet
               .Cells(nRow, 1) = objGroupMember.Name
               .Cells(nRow, 2) = objGroupMember.Address
           End With
       End If
       nRow = nRow + 1
    Next
 
    'Fit the columns
    objExcelWorkSheet.Columns("A:G").AutoFit
 
    'Change the Path as per where you want to save the new Excel file
    strFilename = "E:\" & objContactGroup.DLName & " Member Contact Details.xlsx"
    'Save the Excel workbook
    objExcelWorkBook.Close True, strFilename
 
    MsgBox ("Complete!")
End Sub

その後、便利なチェックのために、新しいVBAプロジェクトをクイックアクセスツールバーまたはリボンに追加できます。
後で、Outlookマクロのセキュリティレベルを低く設定します。
最終的には、試してみることができます。

まず、連絡先グループを選択します。
次に、クイックアクセスツールバーまたはリボンのマクロボタンを押します。
すぐに、マクロが実行されます。
完了すると、「完了！」というプロンプトが表示されます。
その後、新しいExcelファイルを見つけることができる事前定義された宛先ローカルフォルダーに移動できます。
それを開くと、次のスクリーンショットのようなグループメンバーの連絡先の詳細が表示されます。

Outlookの問題に直面して慌てる必要はありません

ポップアップエラーメッセージや破損したOutlook データファイル。したがって、ユーザーはOutlookの問題に遭遇するとパニックになる傾向があります。その場合、落ち着きを保ちたいのであれば、XNUMXつの必需品を手に入れる必要があります。 XNUMXつは現在のOutlookデータのバックアップです。もうXNUMXつは、次のような強力なOutlook修正ソフトウェアです。 DataNumen Outlook Repair.

著者紹介：

Shirley Zhangは、のデータ復旧の専門家です。 DataNumen、Inc。は、以下を含むデータ復旧技術の世界的リーダーです。 SQLの回復と見通し修理ソフトウェア製品。詳細については、次のWebサイトをご覧ください。 WWW。datanumen.com