Word文書の特定のページをOutlookの電子メールにすばやく添付する方法

Outlookソリューション 2025 年 9 月 29 日

MS Wordには、ユーザーが現在のWord文書を電子メールの添付ファイルとして送信することをサポートする直接機能があります。ただし、Word文書の特定のページのみをOutlookの電子メールに添付したい場合もあります。さて、この記事はあなたに方法を共有します。

MS WordアプリケーションでWord文書全体を電子メールの添付ファイルとして送信するには、[ファイル]メニューに移動し、[保存して送信]タブに移動すると、[添付ファイルとして送信]ボタンが表示されます。ただし、送信したいのはドキュメントの特定のページだけである場合もあります。この状況では、以下で紹介する方法を使用してそれを実行できます。

Word文書の特定のページを電子メールに添付する

まず、特定のページを電子メールで送信するソースのWord文書を開く必要があります。
次に、MS Wordウィンドウに入った後、「Alt + F11」キーボタンを押す必要があります。
次に、MSWordのVBAエディターにアクセスします。
その後、「Microsoft Outlook ObjectLib」を有効にする必要がありますrary」。あなたはそれを達成するために「ツール」>「参照」を押すことができます。
その後、次のVBAコードを使用されていないモジュールにコピーする必要があります。

Sub AttachSpecificPagesToOutlookEmail()
    Dim strDocumentName As String
    Dim objSelectedPages As Word.Range
    Dim objTempDocument As Word.Document
    Dim objTempRange As Word.Range
    Dim i As Long
    Dim strTempDocument As String
    Dim objOutlookApp As Outlook.Application
    Dim objMail As Outlook.MailItem
 
    strDocumentName = Left(ActiveDocument.Name, InStr(ActiveDocument.Name, ".") - 1)
 
    'Copy the contents from Page 2 to 4
    'You can change the page as per your own needs
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=2
    Set objSelectedPages = Selection.Range
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=4
    objSelectedPages.End = Selection.Bookmarks("\Page").Range.End
    objSelectedPages.Select
    objSelectedPages.Copy
 
    'Paste the copied contents into a new Word Document
    Set objTempDocument = Word.Application.Documents.Add
    objTempDocument.Activate
    Set objTempRange = objTempDocument.Range(0, 0)
    objTempRange.PasteAndFormat (wdFormatOriginalFormatting)

    For i = objTempDocument.Paragraphs.Count To 1 Step -1
        If Len(objTempDocument.Paragraphs(i).Range) = 1 Then
           objTempDocument.Paragraphs(i).Range.Delete
        Else
           Exit For
        End If
    Next i
 
    'Save this document
    strTempDocument = "E:\" & strDocumentName & " (Excerpt).doc"
    objTempDocument.SaveAs2 strTempDocument, wdFormatDocument
 
    'Attach the new document to a new Outlook email
    On Error Resume Next
    Set objOutlookApp = GetObject(, "Outlook.Application")
    If objOutlookApp Is Nothing Then
       Set objOutlookApp = CreateObject("Outlook.Application")
    End If
 
    Set objMail = objOutlookApp.CreateItem(olMailItem)
    objMail.Attachments.Add (strTempDocument)
    objMail.Display
 
    objTempDocument.Close False
    Kill strTempDocument
End Sub

最後に、このマクロを実行できます。 F5キーボタンを押すか、ツールバーの「実行」アイコンをタップするだけです。
マクロが終了すると、次のスクリーンショットのように、ソースWordドキュメントの抜粋が添付された新しいOutlook電子メールが表示されます。

破損したOutlookファイルから最大のデータを抽出します

Outlookを何十年も使用している場合は、ポップアップの内部エラーメッセージ、突然のクラッシュ、重大なファイルの損傷など、さまざまなOutlookの問題に直面している可能性があります。という事実のためにスキャンプスト、組み込みの修復ツールは、小さな問題にしか対処できません。外部の強力な修正ツールを手元に置いておくとよいでしょう。 DataNumen Outlook Repair。破損したOutlookデータファイルから最大のデータを引き出すことができます。

著者紹介：

Shirley Zhangは、のデータ復旧の専門家です。 DataNumen、Inc。は、以下を含むデータ復旧技術の世界的リーダーです。 SQL修正と見通し修理ソフトウェア製品。詳細については、次のWebサイトをご覧ください。 WWW。datanumen.com