複数のOutlookメッセージ（.msg）ファイルからすべての受信者をすばやく抽出する方法

Outlookソリューション 2025 年 9 月 29 日

一部のユーザーは、Outlook電子メールから保存された複数のOutlookメッセージファイルからすべての受信者をすばやく抽出したいと考えています。さて、このpost これを見て、迅速なアプローチを共有します。

単一のOutlookメッセージファイルから受信者を抽出するには、ダブルクリックしてファイルを開き、開いたメッセージウィンドウに受信者をコピーします。ただし、Outlookメッセージファイルのバッチを処理する必要がある場合は、手動による方法では十分に効率的ではありません。したがって、はるかに効率的な方法を探すことができます。ここではそのようなものを紹介します。詳細については、以下をお読みください。

複数のOutlookメッセージ（.msg）ファイルからすべての受信者を抽出する

としてtart、「次のようにOutlookVBAエディターにアクセスします。OutlookでVBAコードを実行する方法"
次に、次のVBAコードをコピーして空のモジュールに貼り付けます。

Dim strRecipients As String

Sub ExtractRecipientsFromOutlookMSGFiles()
    Dim objShell, objWindowsFolder As Object
 
    strRecipients = ""
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       Call ProcessWindowsFolders(objWindowsFolder.self.Path & "\")
       'Display a Message
       MsgBox "Recipients: " & vbCrLf & strRecipients, vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessWindowsFolders(strFolderPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.Recipient
    Dim objSubfolder As Object

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strFolderPath)
 
    For Each objFile In objFolder.Files
        If objFileSystem.GetExtensionName(objFile) = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)

           If TypeName(objItem) = "MailItem" Then
              Set objMail = objItem
              'Extract recipients' email addresses
              For Each objRecipient In objMail.Recipients
                  strRecipients = strRecipients & objRecipient.Address & vbCr
              Next
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubfolder In objFolder.SubFolders
           If ((objSubfolder.Attributes And 2) = 0) And ((objSubfolder.Attributes And 4) = 0) Then
               Call ProcessWindowsFolders(objSubfolder.Path)
           End If
       Next
    End If
End Sub

次に、最初のサブルーチンでカーソルを移動します。
続いて、「実行」ボタンをクリックするか、「F5」キーを押します。
次に、ポップアップダイアログボックスで、ソースOutlookメッセージ（.msg）ファイルが含まれているWindowsフォルダーを選択します。
選択後、「OK」をクリックしてマクロの実行を継続します。
マクロが終了すると、次のスクリーンショットに示すように、抽出されたすべての受信者の電子メールアドレスを一覧表示するメッセージが表示されます。

OutlookデータをJeopardyから保護する

Outlookデータは確かに破損しがちです。したがって、Outlookデータを保護することは非常に面倒な作業です。 Outlookデータの定期的なバックアップを作成することに固執する必要があります。また、可能であれば、経験豊富で専門的なOutlookを準備することをお勧めします。 PST修復のようなツール DataNumen Outlook Repair、Outlookが破損した場合に、即座にタイムリーに救助できるようにします。

著者紹介：

Shirley Zhangは、のデータ復旧の専門家です。 DataNumen、Inc。は、以下を含むデータ復旧技術の世界的リーダーです。回復します Sql Server と見通し修理ソフトウェア製品。詳細については、次のWebサイトをご覧ください。 WWW。datanumen.com