特定の役職を持つすべてのOutlook連絡先から連絡先グループをすばやく作成する方法

Outlookソリューション 2025 年 9 月 29 日

特定の役職の連絡先とより簡単に通信できるように、これらの連絡先から連絡先グループをすばやく作成することをお勧めします。さて、この記事では、私たちはあなたと速い方法を共有します。

特定の役職を持つ連絡先にメール、タスク、または会議の招待状を頻繁にバッチ送信する場合は、それらから連絡先グループを作成するとはるかに便利です。通常、標準的な方法では、最初に新しい連絡先グループを作成してから、連絡先をXNUMXつずつメンバーとしてグループに追加する必要があります。少し面倒です。したがって、以下では、それを取得するためのはるかに高速な方法を説明します。

特定の役職を持つすべての連絡先から連絡先グループを作成する

まず、連絡先フォルダで、特定の役職を持つ連絡先を選択します。
次に、「Alt + F11」を押して、OutlookVBAエディターにアクセスします。
次に、次のVBAコードを空のモジュールまたはプロジェクトにコピーします。

Dim objContact As Outlook.ContactItem
Dim strJobTitle As String
Dim objNewGroup As Outlook.DistListItem
Dim objTempMail As Outlook.MailItem

Sub CreateContactGroupfromContactsSameJobTitle()
    Dim objStore As Outlook.Store
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    Set objContact = Outlook.Application.ActiveExplorer.Selection(1)
    strJobTitle = objContact.JobTitle
 
    Set objNewGroup = Outlook.Application.CreateItem(olDistributionListItem)
    Set objTempMail = Outlook.Application.CreateItem(olMailItem)
 
    'Process all Contacts folders
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olContactItem Then
               Call ProcessContactsFolders(objFolder)
            End If
        Next
    Next
 
    objNewGroup.AddMembers objTempMail.Recipients
    objNewGroup.Display
End Sub

Sub ProcessContactsFolders(ByVal objCurFolder As Outlook.Folder)
    Dim objItem As Object
    Dim objSubfolder As Outlook.Folder
 
    For Each objItem In objCurFolder.Items
        If objItem.Class = olContact Then
           If objItem.JobTitle = strJobTitle Then
              'Add the contact having the specific job title to the new group
              objTempMail.Recipients.Add (objItem.Email1Address)
              objTempMail.Recipients.ResolveAll
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objCurFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurFolder.Folders
           Call ProcessContactsFolders(objSubfolder)
       Next
    End If
End Sub

その後、カーソルを最初のサブルーチンに移動します。
最後に、「F5」キーボタンをタップしてこのマクロを実行します。
マクロが完了すると、新しい連絡先グループが表示されます。これには、ステップ1で選択した連絡先と同じ役職のすべての連絡先が含まれます。

Outlookデータを効果的に保護する

Outlookは機能が豊富ですが、脆弱であるという事実を取り除くことはできません。したがって、貴重なOutlookデータを失いたくない場合は、それを保護するための努力をする必要があります。たとえば、Outlookデータのバックアップを定期的に作成する必要があります。また、手頃な価格の場合は、次のような最先端のPST修復ツールを用意することをお勧めします DataNumen Outlook Repair、そのことができます PSTを修復する瞬間のデータ。

著者紹介：

Shirley Zhangは、のデータ復旧の専門家です。 DataNumen、Inc。は、以下を含むデータ復旧技術の世界的リーダーです。破損したSQL と見通し修理ソフトウェア製品。詳細については、次のWebサイトをご覧ください。 WWW。datanumen.com