Outlookの古いカレンダーアイテムから添付ファイルをバッチ削除する方法

Outlookソリューション 2025 年 9 月 29 日

Outlookの古い予定や会議から添付ファイルを削除する場合は、この記事を読むことができます。ここでは、それを一度に実現する方法を紹介します。

Outlookファイルのサイズを小さくするには、古いアイテムをクリーンアップすることを強くお勧めします。これは、古いアイテムを定期的に自動的に削除できる組み込みの「AutoArchive」機能によって実現できます。ただし、一部のユーザーは、アイテム自体に影響を与えずに、古いアイテムの添付ファイルを削除したいだけです。以下では、古いカレンダーアイテムから添付ファイルを一括削除する方法を説明します。

古いカレンダーアイテムから添付ファイルをバッチ削除する

まず、「Alt + F11」でOutlookVBAエディターにアクセスします。
次に、[Microsoft Visual Basic for Applications]ウィンドウで、VBAコードをモジュールにコピーします。

Sub BatchDeleteAttachmentsOfOldCalendarItems()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Change to your own Outlook file
    Set objOutlookFile = Outlook.Application.Session.Folders("John Smith")
 
    For Each objFolder In objOutlookFile.Folders
        If objFolder.DefaultItemType = olAppointmentItem Then
           Call LoopCalendars(objFolder)
        End If
    Next
End Sub

Sub LoopCalendars(ByVal objCalendar As Outlook.Folder)
    Dim i, n As Long
    Dim objCalendarItem As Outlook.AppointmentItem
    Dim nDateDiff As Integer
    Dim objAttachments As Outlook.Attachments
    Dim objSubCalendar As Outlook.Folder
 
    For i = objCalendar.Items.Count To 1 Step -1
        Set objCalendarItem = objCalendar.Items(i)
 
        'Remove attachments from items that are more than 2 months old
        'Change the datediff as per your needs
        nDateDiff = DateDiff("m", objCalendarItem.End, Now) '=> "m" refers to month; "d" for day; "y" for year
        If nDateDiff > 2 Then
           Set objAttachments = objCalendarItem.Attachments
           If objAttachments.Count > 0 Then
              For n = objAttachments.Count To 1 Step -1
                  objAttachments(n).Delete
              Next
           End If
           objCalendarItem.Save
        End If
    Next

    'Process all subfolders recursively
    If objCalendar.Folders.Count > 0 Then
       For Each objSubCalendar In objCalendar.Folders
           Call LoopCalendars(objSubCalendar)
       Next
    End If
End Sub

その後、「BatchDeleteAttachmentsOfOldCalendarItems」マクロをクリックします。
最終的に、「F5」キーボタンを押してこのマクロを実行します。
マクロが完了すると、すべてのOutlookカレンダーを確認できます。
Outlookは、2か月以上経過したカレンダーアイテムのすべての添付ファイルを削除している必要があります。

破損したOutlookファイルに対処する

Outlookの破損に遭遇したことがありますか？通常、どのように処分しますか？多くの場合、最初に受信トレイ修復ツールを試してみます– スキャンプスト。ただし、PSTに重大な損傷が発生した場合、組み込みのユーティリティは役に立ちません。したがって、次のような、より経験豊富で注目に値するサードパーティツールを近くに置くことをお勧めします。 DataNumen Outlook Repair.

著者紹介：

Shirley Zhangは、のデータ復旧の専門家です。 DataNumen、Inc。は、以下を含むデータ復旧技術の世界的リーダーです。 SQL修復と見通し修理ソフトウェア製品。詳細については、次のWebサイトをご覧ください。 WWW。datanumen.com