VBAを介して複数のOutlook電子メールをXNUMXつのWord文書にバッチエクスポートする方法

Outlookソリューション 2025 年 9 月 29 日

複数のOutlook電子メールをXNUMXつのWord文書にバッチエクスポートする場合は、この記事に示されているVBAコードを使用できます。それはあなたが数秒以内にこのタスクを達成するのを助けることができます。

以前の記事で、Outlookの電子メールをWord文書に変換する方法を紹介したことがあります。Outlookの電子メールをWord文書に変換する2つの効果的な方法」。ただし、そのpで言及されている2つの意味は両方ともost 多くの電子メールをXNUMXつのWord文書にバッチエクスポートしたい場合は無力になります。したがって、ここでは別の方法をお教えします。さて、それを詳しく理解するために読んでください。

複数のOutlook電子メールをXNUMXつのWord文書にバッチエクスポート

にtarで、Outlookプログラムを起動します。
次に、Outlookのメインウィンドウに入った後、「Alt + F11」キーボタンを押す必要があります。
次に、空のモジュールを開く必要があるOutlookVBAエディターにアクセスします。
続いて、開いたモジュールウィンドウに以下のVBAコードをコピーします。

Sub ExportMultipleEmails_OneWordDocument()
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim objSelection As Outlook.Selection
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim objWordApp As Word.Application
    Dim objNewWordDocument As Word.Document
    Dim objWordRange As Word.Range
    Dim strWordDocument As String
    Dim i As Long
  
    'Create a temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp" & Format(Now, "YYYYMMDDhhmmss")
    MkDir (strTempFolder)
 
    On Error Resume Next
    'Save each selected email as an individual Word document in a temp folder
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
    For Each objMail In objSelection
        strFileName = objMail.Subject
 
        'Remove the unsupported characters in email subject
        strFileName = Replace(strFileName, "/", " ")
        strFileName = Replace(strFileName, "\", " ")
        strFileName = Replace(strFileName, ":", "")
        strFileName = Replace(strFileName, "?", " ")
        strFileName = Replace(strFileName, Chr(34), " ")
 
        objMail.SaveAs strTempFolder & "\" & strFileName & ".doc", olDoc
    Next
 
    'Merge all the Word documents into a single document
    Set objWordApp = CreateObject("Word.Application")
    Set objNewWordDocument = objWordApp.Documents.Add
 
    strWordDocument = Dir(strTempFolder & "\" & "*.doc")
    i = 0
    Do Until strWordDocument = ""
       i = i + 1
       Set objWordRange = objNewWordDocument.Range
       With objWordRange
           .Collapse wdCollapseEnd
           If i > 1 Then
             .InsertBreak wdSectionBreakNextPage
             .End = objNewWordDocument.Range.End
             .Collapse wdCollapseEnd
           End If
           .InsertFile strTempFolder & "\" & strWordDocument
      End With
      strWordDocument = Dir()
    Loop
 
    'Change the path as per your own needs
    objNewWordDocument.SaveAs "E:\Exported Emails " & Format(Now, "YYYY-MM-DD hh-mm-ss")
    objWordApp.Quit
 
    'Delete the temp folder
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

その後、この新しいVBAプロジェクトをクイックアクセスツールバーまたはリボンに追加することをお勧めします。
最終的には、試してみることができます。

まず、複数のOutlookメールを選択します。
次に、新しく追加されたマクロボタンを見つけてクリックします。
「完了」のプロンプトが表示されたら、事前定義されたローカルフォルダーを参照して、新しいWord文書を見つけることができます。
このドキュメントを開くと、選択したすべてのメールがエクスポートされていることがわかります。

強力な回復ツールを近くに置いてください

多くの機能に関係なく、Outlookは依然としてエラーの影響を受けません。あなたがエラーをそのままにしておくことに慣れていて、それらが山積みになっている場合、Outlookのクラッシュは間違いなく発生します。その時点で、次のような強力で効果的な回復ツールに戻ることが不可欠です。 DataNumen Outlook Repair。それはよく精通しています PST修正。それがあれば、Outlookのデータ損失について心配する必要はもうありません。

著者紹介：

Shirley Zhangは、のデータ復旧の専門家です。 DataNumen、Inc。は、以下を含むデータ復旧技術の世界的リーダーです。破損したmdf と見通し修理ソフトウェア製品。詳細については、次のWebサイトをご覧ください。 WWW。datanumen.com