OutlookVBAを使用して複数の連絡先の写真と情報をバッチエクスポートする方法

Outlookソリューション 2025 年 9 月 29 日

連絡先の写真とその主要情報をローカルディスク上のフォルダーにバッチで抽出する場合は、OutlookVBAを使用する必要があります。この記事では、それを実現する方法を詳しく説明します。

Outlookでは、「インポートとエクスポート」機能を使用して連絡先情報をエクスポートできます。「ファイル」>「印刷」>「インポート」>「ファイルにエクスポート」に移動できます。

ただし、この機能では連絡先の写真をエクスポートすることはできません。したがって、連絡先情報と写真の両方を抽出する場合は、OutlookVBAに戻る必要があります。以下は、連絡先の写真を指定されたローカルフォルダーに保存し、連絡先情報をテキストファイルに抽出できるVBAコードと手順です。

複数の連絡先の写真と情報をバッチエクスポートする

まず、Outlookを起動し、「Alt + F11」キーボタンを押します。
次に、VBAエディターにアクセスします。ここで、使用されていないモジュールを開くか、「挿入」>「モジュール」で新しいモジュールを作成する必要があります。
続いて、次のVBAコードをコピーして新しいモジュールに貼り付けます。

Sub BatchExportContactPhotosandInformation()
    Dim objContacts As Outlook.Items
    Dim objContact As ContactItem
    Dim strContactInfo As String
    Dim objFileSystem As Object
    Dim objTextfile As Object
    Dim objAttachments As Attachments
    Dim objAttachment As Attachment
    Dim strName As String
 
    'Specify the contacts in the default contact folder
    Set objContacts = Outlook.Application.Session.GetDefaultFolder(olFolderContacts).Items
 
    For Each objContact In objContacts
        If TypeOf objContact Is ContactItem Then
           'Get the contact's primary informtaion
           strContactInfo = "Name: " & objContact.FullName & vbCrLf & "Email: " & objContact.Email1Address & vbCrLf & "Company: " & objContact.Companies & vbCrLf & "Job Title: " & objContact.JobTitle & vbCrLf & "Business Address: " & objContact.BusinessAddress & vbCrLf & "Business Phone: " & objContact.BusinessTelephoneNumber
           'Create a Text file
           Set objFileSystem = CreateObject("Scripting.FileSystemObject")
           'You can change the folder path as per your needs
           Set objTextfile = objFileSystem.CreateTextFile("C:\Outlook Contacts\" & objContact.FullName & ".txt", True)
           objTextfile.WriteLine (strContactInfo)
 
           'Save the contact photos
           If objContact.Attachments.Count > 0 Then
              Set objAttachments = objContact.Attachments
              For Each objAttachment In objAttachments
                  If InStr(LCase(objAttachment.filename), "contactpicture.jpg") > 0 Then
                     strName = objContact.FullName & ".jpg"
                     objAttachment.SaveAsFile ("C:\Outlook Contacts\" & strName)
                  End If
              Next
           End If
       End If
    Next
End Sub

メモ: 上記のコードは、デフォルトの連絡先フォルダにある連絡先の写真と情報をエクスポートします。指定した連絡先を変更できます。

現在開いているフォルダ内の連絡先の写真と情報をエクスポートする場合は、「SetobjContacts =…..」を次のように置き換える必要があります。

Set objContacts = Outlook.Application.ActiveExplorer.CurrentFolder.Items

選択した連絡先の写真と情報のみをエクスポートする場合は、次の行を使用できます。

Dim objSelection as Selection
Set objSelection = Outlook.Application.ActiveExplorer.Selection
For each objContact in objSelection

その後、VBAエディターを閉じて、通常どおり新しいプロジェクトをクイックアクセスツールバーに追加できます。
最後に、クイックアクセスツールバーのマクロボタンをクリックできます。すぐに、連絡先の写真と情報がローカルディスクの指定されたフォルダにエクスポートされます。

次のスクリーンショットのように、主要な情報が一覧表示されるXNUMXつのテキストファイルを開くことができます。

予期しないOutlookの破損に対処する

Outlookが脆弱であることは疑いの余地のない事実です。したがって、Outlookが破損した場合、最初にすべきことは落ち着くことです。その後、修理を続けることができます破損したOutlookPSTメール。受信トレイ修復ツールを使用して試すことができます。それが失敗した場合は、次のようなはるかに強力なツールを使用する以外に選択肢はありません。 DataNumen Outlook Repair.

著者紹介：

Shirley Zhangは、のデータ復旧の専門家です。 DataNumen、Inc。は、以下を含むデータ復旧技術の世界的リーダーです。破損したSQLmdfデータベースを修復すると見通し修理ソフトウェア製品。詳細については、次のWebサイトをご覧ください。 WWW。datanumen.com