さまざまな色のカテゴリのOutlook会議のさまざまなリマインダー時間を自動設定する方法

Outlookソリューション 2025 年 9 月 29 日

Outlookの会議を色のカテゴリで分類していて、さまざまな色のカテゴリの会議に異なるリマインダー時間を設定する場合は、この記事を参照してください。ここでは、OutlookVBAでそれを実現する方法を説明します。

例えば、会議を2つのグループに分けます。1つは会議場所が遠すぎるため「オフサイト」、もう1つは会議場所がすぐ近くにあるため「オンサイト」とします。ここで、Outlookで「オフサイト」会議のリマインダー時間を開始の1時間前、「オンサイト」会議のリマインダー時間を開始の15分前に自動的に設定したいとします。この要件を踏まえ、以下では簡単な方法をご紹介します。

さまざまな色のカテゴリの会議にさまざまなリマインダーを自動設定

まず、Outlookアプリケーションを起動します。
次に、「Alt + F11」キーボタンを押して、VBAエディタウィンドウにアクセスします。
次に、次のウィンドウで、以下のVBAコードをコピーして「ThisOutlookSession」プロジェクトに貼り付けます。

Public WithEvents objCalendar As Outlook.Folder
Public WithEvents objCalendarItems As Outlook.Items

Private Sub Application_Startup()
    Set objCalendar = Outlook.Application.Session.GetDefaultFolder(olFolderCalendar)
    Set objCalendarItems = objCalendar.Items
End Sub

Private Sub objCalendarItems_ItemAdd(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub objCalendarItems_ItemChange(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub SetReminder_BasedOnCategories(ByVal objCalendarItem As Object)
    Dim objMeeting As Outlook.AppointmentItem
    Dim strCategories As String
 
    If objCalendarItem.Class = olAppointment Then
       'Check if the item is a meeting
       If objCalendarItem.MeetingStatus = olMeeting Then
          Set objMeeting = objCalendarItem
          strCategories = objMeeting.Categories
 
          'Set Reminder as 60 min before start for offsite appointments
          If InStr(strCategories, "Offsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 60
                 .Save
             End With
             'Set Reminder as 15 min before start for onsite appointments
          ElseIf InStr(strCategories, "Onsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 15
                 .Save
             End With
          End If
       End If
    End If
End Sub

その後、「Application_Startup」サブルーチンをクリックして「F5」キーを押すと、このマクロが実行されます。
それ以降、新しい会議がデフォルトのカレンダーに追加されるか、既存の会議を変更するたびに、Outlookは会議のカテゴリを自動チェックし、異なるリマインダー時間を自動設定します。

Outlookのエラーを排除する

Outlook では、時折さまざまな問題が発生する可能性があります。そのため、ユーザーは Outlook の問題に対処する方法を学ぶことが非常に重要です。まず、定期的に Outlook データのバックアップを作成することをお勧めします。さらに、可能であれば、強力なバックアップを作成することをお勧めします。 Outlookの修復近くのツールなど DataNumen Outlook Repair。 PSTファイルをスキャンしてOutlookの問題を特定し、簡単に解決できます。

著者紹介：

Shirley Zhangは、のデータ復旧の専門家です。 DataNumen、Inc。は、以下を含むデータ復旧技術の世界的リーダーです。 SQLの回復と見通し修理ソフトウェア製品。詳細については、次のWebサイトをご覧ください。 WWW。datanumen.com