Outlookで特定のタスクが完了したときに通知メールを自動送信する方法

Outlookソリューション 2025 年 9 月 29 日

Outlookでタスクを完了した後、多くのユーザーは、上司などの誰かに通知するために通知メールを送信したい場合があります。メールを手動で送信するには時間がかかります。この記事では、この種の電子メールを自動送信する簡単な方法を紹介します。

記事から「Outlookの他のユーザーにタスクを割り当てるための4つの迅速な手順」、タスクが上司からあなたに割り当てられており、下のスクリーンショットのように事前にステータスレポートが必要な場合、レポートメールを自動的に受信できることがわかります。

ただし、タスクが自分で作成されたばかりの場合、タスクを完了としてマークしたときにOutlookが通知メールを送信することはありません。この場合、作業を報告するための通知メールを送信する場合は、手動で行う必要があります。ただし、次のVBAコードを使用すると、Outlookに自動的に実行させることができます。

特定のタスクが完了したときに通知メールを自動送信する

最初は、tart Outlookを選択し、「開発者」タブに移動します。
次に、「VisualBasic」ボタンを見つけてクリックします。新しい「MicrosoftVisualBasicforApplications」ウィンドウが表示されます。
その後、「ThisOutlookSession」プロジェクトをダブルクリックして開き、次のVBAコードをコピーします。

Public WithEvents olItems As Outlook.Items

Private Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderTasks).Items
End Sub

Private Sub olItems_ItemChange(ByVal Item As Object)
    Dim obApp As Outlook.Application
    Dim olMail As Outlook.MailItem
    Dim Recip As String
 
    'Replace "test" as per your needs
    If InStr(LCase(Item.Subject), "test") > 0 And Item.Complete = True Then
       'Replace with your desired contact
       Recip = "John Smith"
       If MsgBox("Do you want to send a report to " & Recip & " ?", vbYesNo + vbQuestion, "Confirm Sending Report") = vbYes Then
          Set obApp = Outlook.Application
          Set olMail = obApp.CreateItem(olMailItem)
          With olMail
               .To = Recip
               .Subject = "Complete: " & Item.Subject
               .Body = "Dear Mr. Smith" & vbCrLf & "I've completed this task in " & DateDiff("d", Item.CreationTime, Now) & " day" & Chr(40) & "s" & Chr(41) & "." & vbCrLf & vbCrLf & "Task Name: " & Item.Subject & vbCrLf & "Start Date: " & Item.StartDate & vbCrLf & "Due Date: " & Item.DueDate & vbCrLf & "Creation Time: " & Item.CreationTime & vbCrLf & "Completed Time: " & Now & vbCrLf & vbCrLf & "Task Details: " & vbCrLf & Item.Body
               .ReadReceiptRequested = True
               'To directly send it,use ".Send" instead
               .Display
          End With
       End If
    End If
End Sub

その後、このコードに署名し、デジタル署名されたマクロのみを許可するようにマクロ設定を変更します。
最後に、現在のウィンドウを終了して試してみることができます。

タスクを完了としてマークすると、次の画像のようなメッセージが表示されます。
「はい」ボタンをクリックすると、次の図のような新しいメッセージが開きます。

メモ: 「.display」を「.Send」行に置き換えると、このメールは表示されずに直接送信されます。

不明なメールアドレスからのメッセージに注意してください

不明なアドレスから多くのメールを受信したことがあるはずです。この種の電子メールには注意することをお勧めします。無害に見えるかもしれませんが、悪意のあるリンク、添付ファイル、またはマクロが含まれているためです。それらをクリックまたは開くと、Outlookが感染する可能性があります。その時点で、Outlookデータを取り戻すには、恒星を利用する以外に選択肢はありません。破損したOutlookデータ修正ユーティリティ、といった DataNumen Outlook Repair.

著者紹介：

Shirley Zhangは、のデータ復旧の専門家です。 DataNumen、Inc。は、以下を含むデータ復旧技術の世界的リーダーです。 SQLmdfの問題を修復すると見通し修理ソフトウェア製品。詳細については、次のWebサイトをご覧ください。 WWW。datanumen.com