WindowsフォルダからOutlookに電子メールをインポートする3つの方法

Outlookソリューション 2025 年 9 月 29 日

おそらく、WindowsフォルダにいくつかのOutlook電子メールを保存しました。さて、それらをOutlookフォルダーにインポートして戻したい場合、どうすればよいでしょうか。この記事では、3つの方法を説明します。

ご存知のとおり、Outlookには「名前を付けて保存」という組み込みのオプションがあり、これを使用して電子メールをWindowsフォルダーに保存できます。ただし、エクスポートされた電子メールをOutlookフォルダーに再度追加する機能はありません。したがって、Outlookの電子メールをOutlookにインポートして戻したい場合、どうすればそれを実現できますか？以下では、3つの方法をお教えします。お好みでお選びいただけます。

方法1：ドラッグアンドドロップしてインポート

最初に、OutlookにインポートするOutlook電子メールを保存しているソースWindowsフォルダーにアクセスする必要があります。
次に、Outlookアプリケーションを起動します。
次に、電子メールをインポートするOutlookフォルダーを開きます。
その後、その間に表示できるようになるまで、WindowsフォルダウィンドウとOutlookウィンドウの両方を絞り込む必要があります。
その後、WindowsフォルダでOutlookの電子メールのXNUMXつを選択し、「Ctrl + A」を押してすべてを選択できます。
後で、次のスクリーンショットのように、選択した電子メールを表示されているOutlookフォルダーにドラッグアンドドロップできます。
最後に、次の画像に示すように、すべてのOutlook電子メールがWindowsフォルダーからOutlookフォルダーにインポートされていることがわかります。

方法2：VBAで「CreateItemFromTemplate」を使用する

まず、Outlookのメインウィンドウで「Alt + F11」キーを押します。
次に、OutlookVBAエディターウィンドウにアクセスします。
次に、次のVBAコードを空のモジュールにコピーします。

Sub ImportAllOutlookEmailsfromLocaltoOutlook1()
    Dim objFileSystem As Object
    Dim strLocalFolderPath As String
    Dim objLocalFolder As Object
    Dim objTargetFolder As Outlook.Folder
    Dim objFiles As Object
    Dim objFile As Object
    Dim strFileType As String
    Dim objItem As Object
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    strLocalFolderPath = strSelectedFolder("")
    Set objLocalFolder = objFileSystem.GetFolder(strLocalFolderPath)
    Set objFiles = objLocalFolder.Files
 
    'Set the target Outlook folder
    Set objTargetFolder = Session.GetDefaultFolder(olFolderInbox).folders("Ago")
 
    For Each objFile In objFiles
        strFileType = objFileSystem.GetExtensionName(objFile)
  
        If strFileType = "msg" Then
           Set objItem = Outlook.Application.CreateItemFromTemplate(objFile.Path)
 
           objItem.Move objTargetFolder
           'Delete the source file in the Windows folder
           'objFileSystem.DeleteFile (objFile.Path)
        End If
    Next
End Sub

Function strSelectedFolder(strStartFolder As String) As String
    Dim objShell As Object
    Dim objFolder As Object
 
    On Error Resume Next
    Set objShell = CreateObject("Shell.Application")
    Set objFolder = objShell.BrowseForFolder(0, "Select the source folder:", 0, strStartFolder)
 
    strSelectedFolder = objFolder.self.Path
End Function

次に、現在のモジュールウィンドウでF5キーを押すと、マクロが開始されます。
その後、ポップアップダイアログボックスでソースWindowsフォルダーを参照する必要があります。
最後に、ソースフォルダーを選択すると、そのフォルダー内のすべてのOutlookアイテムが事前定義されたOutlookフォルダーにインポートされます。
注：このように、インポートされた電子メールはすべて新しい新しい電子メールであり、次のスクリーンショットのように自由に作成できます。

方法3：VBAで「OpenSharedItem」を利用する

方法2と同様に、次のVBAコードを別のモジュールにコピーします。

Sub ImportAllOutlookEmailsfromLocaltoOutlook2()
    Dim objFileSystem As Object
    Dim strLocalFolderPath As String
    Dim objLocalFolder As Object
    Dim objTargetFolder As Outlook.Folder
    Dim objFiles As Object
    Dim objFile As Object
    Dim strFileType As String
    Dim objItem As Object
    Dim objCopiedItem As Outlook.MailItem

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    strLocalFolderPath = strSelectedFolder("")
    Set objLocalFolder = objFileSystem.GetFolder(strLocalFolderPath)
    Set objFiles = objLocalFolder.Files
 
    'Set the target Outlook folder
    Set objTargetFolder = Session.GetDefaultFolder(olFolderInbox).folders("Ago")
 
    For Each objFile In objFiles
        strFileType = objFileSystem.GetExtensionName(objFile)
 
        If strFileType = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)
           'Only import emails
           If TypeOf objItem Is MailItem Then
              Set objCopiedItem = objItem.Copy
              objCopiedItem.Move objTargetFolder
              'Delete the source file in the Windows folder
              'objFileSystem.DeleteFile (objFile.Path)
           End If
       End If
    Next
End Sub

Function strSelectedFolder(strStartFolder As String) As String
    Dim objShell As Object
    Dim objFolder As Object
 
    On Error Resume Next
    Set objShell = CreateObject("Shell.Application")
    Set objFolder = objShell.BrowseForFolder(0, "Select the source folder:", 0, strStartFolder)
 
    strSelectedFolder = objFolder.self.Path
End Function

次に、「F5」キーボタンを押してこのマクロを実行します。
次に、ソースフォルダを選択します。
最終的に、すべての電子メールは以下の画像としてインポートされます。

比較

メソッド	優位性	デメリット
方法1	VBAに慣れていない人は受け入れやすいです。	これには、両方が表示されるまでXNUMXつのウィンドウを絞り込む必要があります。
方法2	インポートしたメールを新しいメールとして使用し、自由に作成して送信できます。	連絡先やタスクなど、「。msg」形式で保存された他のOutlookアイテムがある場合、この方法でもそれらがインポートされます。
方法3	Outlookの電子メールを正確に認識し、他のOutlookアイテムをエスケープできます。	これにより、インポートされた電子メールを方法2ほど簡単に作成して送信することはできません。

PSTデータの破損をブロックする手段

ご存知のとおり、Outlookには組み込みのツールがプリインストールされています– スキャンプストほとんどの場合、小さな問題を解決することができます。しかし、問題が非常に深刻な場合は、組み込みツールでは失敗する傾向があります。そのため、次のようなより強力なツールに頼る方が良いでしょう。 DataNumen Outlook Repair.

著者紹介：

Shirley Zhangは、のデータ復旧の専門家です。 DataNumen、Inc。は、以下を含むデータ復旧技術の世界的リーダーです。 SQL Server 腐敗と見通し修理ソフトウェア製品。詳細については、次のWebサイトをご覧ください。 WWW。datanumen.com