異なるページに異なるカテゴリのOutlookタスクのリストを印刷する2つの方法

Outlookソリューション 2025 年 9 月 29 日

Outlookタスクにさまざまな色のカテゴリを割り当てており、さまざまなカテゴリのタスクのリストをさまざまなページに印刷したい場合は、この記事を参照してください。ここでは、それを取得するための2つの方法を紹介します。

タスクを分類して適切に管理するために、タスクに色のカテゴリを適用した可能性があります。さて、異なるページに異なるカテゴリのタスクのリストを印刷したい場合は、読み進めてください。以下では、それを取得するための2つの手段を紹介します。

方法1：タスクリストをXNUMXつずつ手動で印刷する

まず、Outlookで[タスク]ペインにアクセスします。
次に、タスクフォルダを開きます。
次に、「Ctrl + E」を押して、「検索」リボンをアクティブにします。
その後、「検索」タブで「分類」ボタンをクリックします。
ドロップダウンリストから、色のカテゴリを選択します。
次に、選択したカテゴリのタスクのみがリストに残ります。
次に、「ファイル」>「印刷」に移動して、このタスクリストを印刷します。
続いて、同様に、他の色のカテゴリのタスクのリストをXNUMXつずつ手動で印刷します。

方法2：VBAによるタスクリストのバッチ印刷

最初に、「」に従ってVBAエディタをトリガーします。OutlookでVBAコードを実行する方法"
次に、「MS Excel ObjectLib」への参照を追加しますrary」は「オブジェクトライブラリを追加する方法raryVBAでの参照"
次に、次のVBAコードをモジュールにコピーします。

Sub PrintTaskList_SpecificColorCategory()
    Dim objTasks As Outlook.Items
    Dim objTask As Outlook.TaskItem
    Dim objDictionary As Object
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varKey As Variant
    Dim strKey As String
    Dim i As Long
    Dim bSheetFound As Boolean
    Dim nLastRow As Integer
    Dim objSheet As Excel.Worksheet
 
    Set objTasks = Application.Session.GetDefaultFolder(olFolderTasks).Items
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
     'Get All Tasks' Categories
    For Each objTask In objTasks
        arrCategory = Split(objTask.Categories, ",")
        For Each varCategory In arrCategory
            If objDictionary.Exists(Trim(varCategory)) = False Then
               objDictionary.Add Trim(varCategory), 0
            End If
        Next
    Next
 
    'Export the Tasks with Different Categories into Different Sheet in an Excel Workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelApp.Visible = True
 
    i = 0
    For Each varKey In objDictionary.Keys
        strKey = CStr(varKey)

        On Error Resume Next
        objExcelWorkbook.Sheets(strKey).Select
        bSheetFound = (Err = 0)
        On Error GoTo 0
        If bSheetFound = False Then
           i = i + 1
           If i < 4 Then
              Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
           Else
              Set objExcelWorksheet = objExcelWorkbook.Sheets.Add(After:=objExcelWorkbook.Sheets(objExcelWorkbook.Sheets.Count))
           End If
           objExcelWorksheet.Name = strKey
        End If
 
        With objExcelWorksheet
             .Cells(1, 1) = strKey
             .Cells(1, 1).Font.Bold = True
             .Cells(1, 1).Font.Size = 18
             .Cells(2, 1) = "Subject"
             .Cells(2, 1).Font.Bold = True
             .Cells(2, 2) = "Start Date"
             .Cells(2, 2).Font.Bold = True
             .Cells(2, 3) = "Due Date"
             .Cells(2, 3).Font.Bold = True
        End With
 
        For Each objTask In objTasks
            If InStr(objTask.Categories, strKey) > 0 Then
               nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
               With objExcelWorksheet
                    .Range("A" & nLastRow) = objTask.Subject
                    .Range("B" & nLastRow) = objTask.startDate
                    .Range("C" & nLastRow) = objTask.DueDate
               End With
            End If
        Next
 
        objExcelWorksheet.Columns("A:C").AutoFit
    Next
 
    'Print out All Sheets in this Excel Workbook
    For Each objSheet In objExcelWorkbook.Sheets
        objSheet.PrintOut
    Next
 
    objExcelWorkbook.Close False
    objExcelApp.Quit
End Sub

その後、「F5」キーボタンを押して、このマクロをすぐに実行します。
マクロが終了すると、次のスクリーンショットに示すように、さまざまなカテゴリのタスクのリストがさまざまなページに印刷されます。

侵害されたPSTファイルから貴重なデータを取り戻す

アクセスできないPSTファイルの対象となる場合、次のステップは間違いなくです PST修復。この場合、最初に受信トレイ修復ツールを試すことができます。失敗した場合は、次のような別の外部ツールを試すことができます。 DataNumen Outlook Repair。それは迅速にPSTデータを回復することができます。

著者紹介：

Shirley Zhangは、のデータ復旧の専門家です。 DataNumen、Inc。は、以下を含むデータ復旧技術の世界的リーダーです。 mdfを回復すると見通し修理ソフトウェア製品。詳細については、次のWebサイトをご覧ください。 WWW。datanumen.com