Come rimuovere in batch tutti gli indirizzi e-mail con un dominio specifico dai tuoi contatti di Outlook

A volte, potresti sperare di rimuovere dai tuoi contatti tutti gli indirizzi email con un dominio specifico. In questa situazione, devi essere riluttante a farlo uno per uno. Così, questa post ti insegnerà un metodo molto più intelligente.

Ad esempio, una società cambia nome. Nel frattempo, anche il dominio dell'azienda viene modificato. Tuttavia, in Outlook, hai memorizzato molti contatti in questa azienda, i cui indirizzi e-mail sono con il vecchio dominio. Naturalmente, questi indirizzi e-mail non sono più validi. Quindi, in questa circostanza, se desideri rimuovere questi indirizzi e-mail in una volta sola, puoi utilizzare la seguente modalità.

Rimuovi in ​​batch tutti gli indirizzi e-mail con un dominio specifico dai contatti

1. Per cometart, accedi all'editor VBA di Outlook tramite la scorciatoia da tastiera - "Alt + F11".
2. Quindi, nella nuova finestra, inserisci il seguente codice VBA in un modulo vuoto.

Dim strDomain As String

Sub BatchRemoveAllEmailAddressesInSpecificDomain()
    Dim objStore As Store
    Dim objFolder As Folder
    Dim lTotalCount As Long
 
    'Input the specific domain
    strDomain = InputBox("Enter the specific domain:", , "@false.com")
 
    If Len(strDomain) <> 0 Then
       lTotalCount = 0
       'Process all Contact folders in your Outlook
       For Each objStore In Application.Session.Stores
           For Each objFolder In objStore.GetRootFolder.Folders
               If objFolder.DefaultItemType = olContactItem Then
                  Call ProcessContactFolders(objFolder, lTotalCount)
               End If
           Next
       Next
 
       'Prompt you
       MsgBox lTotalCount & " email addresses in " & strDomain & " are removed!", vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessContactFolders(ByVal objCurrentFolder As Folder, ByRef lCount As Long)
    Dim objContacts As Items
    Dim i As Long
    Dim objContact As ContactItem
 
    Set objContacts = objCurrentFolder.Items
 
    For i = objContacts.Count To 1 Step -1
        If TypeName(objContacts(i)) = "ContactItem" Then
           Set objContact = objContacts(i)
 
           'Check 3 email addresses of each contact
           If InStr(objContact.Email1Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email1Address = ""
              objContact.Email1DisplayName = ""
           ElseIf InStr(objContact.Email2Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email2Address = ""
              objContact.Email2DisplayName = ""
           ElseIf InStr(objContact.Email3Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email3Address = ""
              objContact.Email3DisplayName = ""
           End If
 
           objContact.Save
        End If
     Next
 
     If objCurrentFolder.Folders.Count > 0 Then
        For Each objSubfolder In objCurrentFolder.Folders
            Call ProcessContactFolders(objSubfolder, lCount)
        Next
     End If
End Sub

3. Successivamente, posiziona il cursore nella subroutine "BatchRemoveAllEmailAddressesInSpecificDomain".
4. Infine, fai clic sul pulsante "F5" per attivare questa macro.
5. Successivamente, inserisci il dominio specifico nella finestra di dialogo popup.
6. Dopo aver fatto clic su "OK", verrà eseguita la macro.
7. Al termine, riceverai un messaggio sui risultati.
8. Ora puoi controllare i contatti. Tutti gli indirizzi email con il dominio specifico devono essere scomparsi.

Conserva il tuo file di Outlook

Con sempre più rischi che circondano il tuo Outlook, è sempre più difficile salvaguardare i tuoi preziosi dati di Outlook. Ad esempio, non solo dovresti persistere nei backup regolari dei dati, ma devi anche fare attenzione alle tue operazioni. Non è saggio fidarsi prontamente delle e-mail provenienti da mittenti sconosciuti. Altrimenti, se contiene virus, il tuo file di Outlook verrà infettato. In quel momento, devi provare Riparazione di Outlook tramite un notevole strumento di correzione, come ad esempio DataNumen Outlook Repair.

Introduzione dell'autore:

Shirley Zhang è un'esperta di recupero dati in DataNumen, Inc., che è il leader mondiale nelle tecnologie di recupero dati, tra cui recuperare Sql Server e prodotti software di riparazione di Outlook. Per maggiori informazioni visita www.datanumen.com