Bagaimana Mendapatkan Pemberitahuan Jika Tidak Menerima Balasan dari Email Tertentu dalam Waktu yang Diharapkan

Artikel ini akan mengajari Anda trik cepat menggunakan VBA agar Outlook secara otomatis meminta Anda untuk mengirim email pemberitahuan jika Anda belum menerima balasan email tertentu dalam waktu tertentu.

Terkadang, untuk email yang sangat penting, Anda pasti akan menantikan balasannya. Dengan kata lain, Anda harus berharap penerima dapat membalas Anda sesegera mungkin. Jika tidak, selama Anda belum menerima balasan dalam waktu yang diharapkan, Anda akan mengirim email pemberitahuan tindak lanjut ke penerima lagi. Oleh karena itu, sebagai tanggapan atas persyaratan ini, di sini kami akan memperkenalkan metode yang menggunakan VBA untuk membuat Outlook memperingatkan secara otomatis dan meminta Anda dalam kasus seperti itu. Baca terus untuk mendapatkan langkah-langkah dan kode yang lengkap.

Dapatkan Pemberitahuan Jika Tidak Menerima Balasan dari Email Tertentu dalam Waktu yang Diharapkan

1. Pada awalnya, start Outlook Anda.
2. Kemudian Anda perlu mengatur waktu pengingat tertentu ke email tertentu.

• Pertama, klik kanan pada email tertentu.
• Kemudian pilih "Tindak Lanjut"> "Tambahkan Pengingat".
• Di kotak dialog, Anda dapat menyetel waktu pengingat sama dengan waktu tertentu yang Anda inginkan untuk menerima balasannya.

3. Setelah itu, tekan tombol “Alt + F11” untuk mengakses editor Outlook VBA.
4. Selanjutnya di jendela baru, buka proyek "ThisOutlookSession" dan salin kode berikut ke dalamnya.

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

'If receive the reply, clear the flag and remove the reminder
Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objSentItems As Outlook.Items
    Dim objVariant As Variant
    Dim i As Long
    Dim strSubject As String
    Dim dSendTime As String
 
    Set objSentItems = Outlook.Application.Session.GetDefaultFolder(olFolderSentMail).Items
 
    If Item.Class = olMail Then
       For i = 1 To objSentItems.Count
           If objSentItems.Item(i).Class = olMail Then
              Set objVariant = objSentItems.Item(i)
              strSubject = LCase(objVariant.Subject)
              dSendTime = objVariant.SentOn
 
              If LCase(Item.Subject) = "re: " & strSubject Or InStr(LCase(Item.Subject), strSubject) > 0 Then
                 If Item.SentOn > dSendTime Then
                    With objVariant
                         .ClearTaskFlag
                         .ReminderSet = False
                         .Save
                    End With
                 End If
              End If
           End If
       Next i
    End If
End Sub

'Get a prompt asking if to send a notification email
Private Sub Application_Reminder(ByVal Item As Object)
    Dim strPrompt As String
    Dim nResponse As Integer
    Dim objFollowUpMail As Outlook.MailItem
 
    'You can change the subject as per your real case
    If (Item.Class = olMail) And (LCase(Item.Subject) = "datanumen outlook repair") Then
       strPrompt = "You haven't yet recieved the reply of " & Chr(34) & Item.Subject & Chr(34) & " within your expected time. Do you want to send a follow-up notification email?"
       nResponse = MsgBox(strPrompt, vbYesNo + vbQuestion, "Confirm to Send a Follow-Up Notification Email")
       If nResponse = vbYes Then
          Set objFollowUpMail = Application.CreateItem(olMailItem)
          With objFollowUpMail
               .To = Item.Recipients.Item(1).Address
               .Subject = "Follow Up: " & Chr(34) & Item.Subject & Chr(34)
               .Body = "Please respond to my email " & Chr(34) & Item.Subject & Chr(34) & "as soon as possible"
               .attachments.Add Item
               .Display
          End With
       End If
    End If
End Sub

5. Selanjutnya, tanda tangani kode ini.
6. Kemudian ubah pengaturan makro Outlook untuk mengizinkan makro yang ditandatangani secara digital.
7. Akhirnya restart Outlook untuk mengaktifkan makro baru. Mulai sekarang, Outlook akan berfungsi sebagai berikut:

• Jika Anda telah menerima balasan dari email tertentu sebelum pengingatnya muncul, Outlook akan secara otomatis menghapus bendera dan menonaktifkan pengingat.
• Jika Anda belum menerima balasan saat pengingatnya aktif, Outlook akan menanyakan apakah Anda akan mengirim email pemberitahuan tindak lanjut. Jika Anda memilih "Ya", email akan dikirim. Jika memilih “No”, prompt akan segera hilang.

Selesaikan Masalah Outlook yang Mengganggu

Karena Outlook rawan kesalahan, untuk mencegahnya Korupsi Outlook, Anda sebaiknya tidak hanya mengandalkan alat kotak masuk, Scanpst.exe. Anda harus menyiapkan alat perbaikan lain yang kuat dan bereputasi baik, seperti DataNumen Outlook Repair, yang dapat membuang masalah mengganggu yang tidak dapat diselesaikan oleh Scanpst.exe.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk korupsi sql dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com