Cara Mengekspor Banyak Foto dan Informasi Kontak dengan Outlook VBA

Jika Anda ingin mengekstrak foto kontak dan informasi utamanya ke folder di disk lokal Anda secara berkelompok, Anda perlu menggunakan Outlook VBA. Artikel ini akan mengajari Anda cara mencapainya secara detail.

Outlook mengizinkan Anda mengekspor informasi kontak melalui fitur "Impor dan Ekspor". Anda dapat membuka "File"> "Cetak"> "Impor"> "Ekspor ke file".

Namun, fitur ini tidak memungkinkan Anda mengekspor foto kontak. Jadi, jika Anda ingin mengekstrak informasi kontak dan foto, Anda harus menggunakan Outlook VBA. Berikut ini adalah kode VBA dan langkah-langkah yang dapat menyimpan foto kontak ke folder lokal tertentu dan mengekstrak informasi kontak ke dalam file teks.

Ekspor Batch Foto dan Informasi Beberapa Kontak

1. Pertama-tama, luncurkan Outlook dan tekan tombol "Alt + F11".
2. Kemudian Anda akan mendapatkan akses ke editor VBA. Sekarang Anda harus membuka modul yang tidak digunakan atau membuat modul baru dengan "Sisipkan"> "Modul".
3. Selanjutnya, salin dan tempel kode VBA berikut ke modul baru.

Sub BatchExportContactPhotosandInformation()
    Dim objContacts As Outlook.Items
    Dim objContact As ContactItem
    Dim strContactInfo As String
    Dim objFileSystem As Object
    Dim objTextfile As Object
    Dim objAttachments As Attachments
    Dim objAttachment As Attachment
    Dim strName As String
 
    'Specify the contacts in the default contact folder
    Set objContacts = Outlook.Application.Session.GetDefaultFolder(olFolderContacts).Items
 
    For Each objContact In objContacts
        If TypeOf objContact Is ContactItem Then
           'Get the contact's primary informtaion
           strContactInfo = "Name: " & objContact.FullName & vbCrLf & "Email: " & objContact.Email1Address & vbCrLf & "Company: " & objContact.Companies & vbCrLf & "Job Title: " & objContact.JobTitle & vbCrLf & "Business Address: " & objContact.BusinessAddress & vbCrLf & "Business Phone: " & objContact.BusinessTelephoneNumber
           'Create a Text file
           Set objFileSystem = CreateObject("Scripting.FileSystemObject")
           'You can change the folder path as per your needs
           Set objTextfile = objFileSystem.CreateTextFile("C:\Outlook Contacts\" & objContact.FullName & ".txt", True)
           objTextfile.WriteLine (strContactInfo)
 
           'Save the contact photos
           If objContact.Attachments.Count > 0 Then
              Set objAttachments = objContact.Attachments
              For Each objAttachment In objAttachments
                  If InStr(LCase(objAttachment.filename), "contactpicture.jpg") > 0 Then
                     strName = objContact.FullName & ".jpg"
                     objAttachment.SaveAsFile ("C:\Outlook Contacts\" & strName)
                  End If
              Next
           End If
       End If
    Next
End Sub

Catatan: Kode di atas akan mengekspor foto dan informasi kontak di folder kontak default Anda. Anda dapat mengubah kontak yang ditentukan.

• Jika Anda ingin mengekspor foto dan informasi kontak di folder yang sedang dibuka, maka Anda harus mengganti "Set objContacts =… .." dengan:

Set objContacts = Outlook.Application.ActiveExplorer.CurrentFolder.Items

• Jika Anda hanya berharap untuk mengekspor foto dan informasi dari kontak yang dipilih, Anda dapat menggunakan baris berikut:

Dim objSelection as Selection
Set objSelection = Outlook.Application.ActiveExplorer.Selection
For each objContact in objSelection

4. Setelah itu, Anda dapat menutup editor VBA dan melanjutkan untuk menambahkan proyek baru ke Bilah Alat Akses Cepat seperti biasa.
5. Terakhir, Anda dapat mengklik tombol makro di Bilah Alat Akses Cepat. Sekaligus, foto dan informasi kontak akan diekspor ke folder yang ditentukan di disk lokal.

Anda dapat membuka satu file Teks, di mana informasi utama akan dicantumkan, seperti tangkapan layar berikut:

Tangani Korupsi Outlook Tak Terduga

Ini adalah fakta yang tidak perlu dipertanyakan lagi bahwa Outlook rentan. Karenanya, jika Anda mengalami kerusakan Outlook, yang harus Anda lakukan pertama kali adalah menenangkan diri. Kemudian Anda dapat terus memperbaiki file email Outlook PST rusak. Anda dapat menggunakan alat perbaikan kotak masuk untuk mencobanya. Jika gagal, maka Anda tidak punya pilihan selain menggunakan alat yang jauh lebih kuat, seperti DataNumen Outlook Repair.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk memperbaiki database mdf SQL yang rusak dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com