2 Cara Cepat untuk Mengekspor Daftar Semua Email Outlook yang Ditandai ke Excel

Jika Anda ingin mengekspor daftar semua email berbendera dari kotak surat Outlook Anda ke Excel, Anda dapat menggunakan salah satu dari 2 metode yang dibagikan dalam artikel ini.

Misalnya, untuk menangani semua email yang ditandai lebih tepat waktu atau membagikannya dengan orang lain, Anda mungkin berharap untuk mengekspornya ke lembar kerja Excel. Di sini kami akan memperkenalkan 2 pendekatan untuk mewujudkannya. Yang pertama menggunakan fitur "Impor dan Ekspor" standar setelah menemukan email yang ditandai. Sejujurnya, ini agak membosankan. Jadi, yang terakhir ini, kami akan mengajari Anda cara yang lebih nyaman dalam menerapkan VBA.

Metode 1: Ekspor Semua Email Berbendera yang Ditemukan Secara Manual

1. Pertama-tama, klik di kotak pencarian di atas daftar surat.
2. Kemudian, klik "Semua Item Email" di grup "Cakupan" pada tab "Pencarian".
3. Selanjutnya, klik tombol "Ditandai" di grup "Tentukan".
4. Setelah semua email yang ditandai ditampilkan dalam daftar, pilih satu email dan tekan "Ctrl + A" untuk memilih semuanya.
5. Lalu, tekan pintasan tombol “Ctrl + Shift + V”.
6. Di kotak dialog baru, buat folder baru di bawah file Outlook.
7. Kemudian, pilih folder yang baru dibuat dan klik "OK", yang akan memindahkan semua email yang ditandai dan ditemukan ke folder baru.
8. Setelah itu, klik "File"> "Buka"> "Impor",
9. Di kotak dialog popup, pilih "Ekspor ke file"> "Berikutnya"> "Microsoft Excel 97-2003"> "Berikutnya".
10. Di layar baru, pilih folder yang benar dan tekan "Next".
11. Selanjutnya, ikuti wizard untuk menyelesaikan "Ekspor".
12. Anda akan mendapatkan file Excel baru, seperti gambar di bawah ini.

Metode 2: Ekspor Daftar Semua Email yang Ditandai melalui VBA

1. Di Outlook, tekan "Alt + F11" untuk memicu editor VBA.
2. Kemudian, aktifkan "Objek MS Excel" sesuai dengan "Cara Menambahkan Object Library Referensi di VBA".
3. Selanjutnya, salin kode VBA di bawah ini ke dalam modul.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllFlaggedEmailsToExcel()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
  
    'Select a source PST file
    Set objOutlookFile = Outlook.Application.Session.PickFolder
 
    If Not (objOutlookFile Is Nothing) Then
       'Create a new Excel file
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
       objExcelApp.Visible = True
 
       With objExcelWorksheet
           .Cells(1, 1) = "Subject"
           .Cells(1, 1).Font.Bold = True
           .Cells(1, 2) = "Start Date"
           .Cells(1, 2).Font.Bold = True
           .Cells(1, 3) = "Due Date"
           .Cells(1, 3).Font.Bold = True
           .Cells(1, 4) = "From"
           .Cells(1, 4).Font.Bold = True
           .Cells(1, 5) = "To"
           .Cells(1, 5).Font.Bold = True
      End With
 
      For Each objFolder In objOutlookFile.Folders
          If objFolder.DefaultItemType = olMailItem Then
             Call ProcessMailFolders(objFolder)
          End If
      Next
 
      objExcelWorksheet.Columns("A:E").AutoFit

      MsgBox "Completed!", vbInformation + vbOKOnly, "Export Emails"
    End If
End Sub

Sub ProcessMailFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objFlaggedMail As Outlook.MailItem
    Dim nLastRow As Integer
    Dim objSubfolder As Outlook.Folder
 
    For i = 1 To objCurrentFolder.Items.Count
        If objCurrentFolder.Items(i).Class = olMail Then
           'Export the information of each flagged email to Excel
           Set objMail = objCurrentFolder.Items(i)
           If objMail.IsMarkedAsTask = True And objMail.FlagStatus <> olFlagComplete Then
              Set objFlaggedMail = objMail
 
              With objExcelWorksheet
                   nLastRow = .Range("A" & .Rows.Count).End(xlUp).Row + 1
                   .Range("A" & nLastRow) = objFlaggedMail.Subject
                   .Range("B" & nLastRow) = objFlaggedMail.TaskStartDate
                   .Range("C" & nLastRow) = objFlaggedMail.TaskDueDate
                   .Range("D" & nLastRow) = objFlaggedMail.SenderName
                   .Range("E" & nLastRow) = objFlaggedMail.To
              End With
          End If
        End If
    Next i
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessMailFolders(objSubfolder)
       Next
    End If
End Sub

4. Terakhir, letakkan kursor di subrutin "ExportAllFlaggedEmailsToExcel" dan tekan tombol "F5".
5. Kemudian, pilih file Outlook di kotak dialog baru.
6. Saat Anda mendapatkan prompt "Selesai", Anda juga akan mendapatkan file Excel baru, seperti gambar di bawah ini.

Lindungi Pandangan Anda dari Korupsi

Outlook rentan terhadap kesalahan dan kerusakan, oleh karena itu tugas yang sangat sulit bagi kami untuk melindungi data Outlook kami. Tidak diragukan lagi, most cara mujarab dan praktis adalah dengan membuat backup data reguler untuk Outlook. Selain itu, kami juga perlu mendapatkan alat perbaikan Outlook yang kuat dan tepercaya, seperti DataNumen Outlook Repair. Ini akan berguna jika alat perbaikan kotak masuk tidak berpengaruh.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk memperbaiki SQL Server dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com