Cara Cepat Menunda Pengiriman Email Tertentu hingga Jam Kerja di Outlook Anda

Jika Anda perlu mencegah diri Anda mengirim email tertentu di luar jam kerja, Anda dapat menggunakan metode yang ditunjukkan dalam artikel ini. Itu dapat membiarkan Outlook memeriksa secara otomatis apakah sedang dalam jam kerja saat Anda mengirim email tertentu dan menundanya hingga jam kerja.

Kadang-kadang, saat Anda menulis dan mengirim email tidak dalam jam kerja Anda. Dalam hal ini, Anda mungkin ingin menunda pengiriman email ini hingga jam kerja berikutnya. Umumnya, Anda dapat menggunakan fitur asli “Delay Delivery” untuk menunda email tersebut. Namun, dengan demikian, Anda harus menentukan waktu pengiriman setiap saat. Ini terlalu merepotkan. Setelah itu, kami akan membagikan Anda sepotong kode VBA, yang dapat secara otomatis memeriksa apakah itu dalam jam kerja saat Anda mengirim email tertentu dan dengan cepat menunda pengiriman hingga jam kerja.

Cepat Tunda Mengirim Email Tertentu hingga Jam Kerja

1. Pertama-tama, luncurkan program Outlook Anda.
2. Kemudian di layar utama Outlook yang muncul, Anda dapat menekan tombol "Alt + F11".
3. Selanjutnya Anda akan mendapatkan akses ke editor Outlook VBA dengan sukses.
4. Setelah itu, Anda perlu mencari dan membuka proyek "ThisOutlookSession".
5. Selanjutnya, salin kode VBA berikut ke jendela proyek ini.

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
    Dim objMail As MailItem
    Dim NewSendTime As String
    Dim bDelayMail As Boolean
    Dim nPrompt As Integer
 
    bDelayMail = True
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Work on specific emails only
       'You can change the conditions as per your needs
       If objMail.Recipients.Item(1).Address = "boss@datanumen.com" Then
 
          Select Case Weekday(Date, vbMonday)
                 'Delay 2 days if today is Saturday
                 Case 6
                      NewSendTime = (Date + 2) & " 09:00:00"
                 'Delay 1 days if today is Saturday
                 Case 7
                      NewSendTime = (Date + 1) & " 09:00:00"
                 Case Else
                      If DatePart("h", Now) < 9 Then
                         'Delay to 9 o'clock if now is too early
                         NewSendTime = Date & " 09:00:00"
                      ElseIf DatePart("h", Now) > 18 Then
                         Select Case Weekday(Date, vbMonday)
                                'Delay 3 days if today is Friday and now is over 6 PM
                                Case 5
                                     NewSendTime = (Date + 3) & " 09:00:00"
                                'Delay to 9 o'clock if now is before 6 PM
                                Case Else
                                     NewSendTime = (Date + 1) & " 09:00:00"
                         End Select
                      Else
                         bDelayMail = False
                      End If
            End Select
 
            If bDelayMail = True And objMail.DeferredDeliveryTime = "1/1/4501" Then
               'Ask if to delay sending this email
               nPrompt = MsgBox("Outside Working Hours:" & vbCrLf & "Do you want to delay this email until " & NewSendTime & "?", vbYesNo + vbExclamation, "Delay Email")
 
               If nPrompt = vbYes Then
                  objMail.DeferredDeliveryTime = NewSendTime
               Else
                  objMail.DeferredDeliveryTime = "1/1/4501"
               End If
           End If
       End If
    End If
End Sub

6. Nanti Anda akan diminta untuk memberikan sertifikat digital ke email ini.
7. Dan kemudian ubah pengaturan makro Outlook Anda untuk mengizinkan makro yang ditandatangani.
8. Mulai sekarang, setiap kali Anda mengirim email yang memenuhi kriteria yang telah ditentukan, jika di luar jam kerja, Anda akan mendapatkan prompt seperti gambar berikut:
9. Jika Anda memilih "Ya", Outlook akan menjadwalkannya untuk dikirim hingga jam kerja.

Menyelamatkan File Outlook yang Rusak

Outlook telah mendapatkan banyak pujian karena segudang fiturnya. Namun, itu masih memiliki kelemahan yang mematikan. Itu Outlook rentan terhadap kesalahan dan korupsi. Karenanya, Anda harus mencadangkan file Outlook Anda secara teratur. Ini dapat mencegah Anda dari kehilangan data Outlook yang menyakitkan. Selain itu, Anda sebaiknya mendapatkan alat perbaikan yang hebat, seperti DataNumen Outlook Repair, Yang dapat perbaiki Outlook masalah dalam hitungan detik.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk pemulihan mdf dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com