Cara Cepat Melampirkan Halaman Tertentu dari Dokumen Word ke Email Outlook

MS Word memiliki fitur langsung yang mendukung pengguna untuk mengirim dokumen Word saat ini sebagai lampiran email. Namun terkadang, Anda mungkin hanya berharap untuk melampirkan halaman tertentu dari dokumen Word ke email Outlook. Sekarang, artikel ini akan membagikan Anda sebuah metode.

Untuk mengirim seluruh dokumen Word sebagai lampiran email di aplikasi MS Word, Anda cukup masuk ke menu "File" dan geser ke tab "Simpan & Kirim", di mana Anda dapat menemukan tombol "Kirim sebagai Lampiran". Namun, terkadang, yang ingin Anda kirimkan mungkin hanya halaman dokumen tertentu. Dalam situasi ini, Anda dapat menggunakan metode yang diperkenalkan berikut ini untuk menyelesaikannya.

Lampirkan Halaman Tertentu dari Dokumen Word ke Email

1. Pertama, Anda harus membuka dokumen Word sumber yang halaman spesifiknya ingin Anda kirim dalam email.
2. Kemudian, setelah masuk ke jendela MS Word, Anda perlu menekan tombol "Alt + F11".
3. Selanjutnya, Anda akan mendapatkan akses ke editor VBA di MS Word.
4. Setelah itu, Anda harus mengaktifkan “Microsoft Outlook Object Library ”. Anda dapat menekan "Alat"> "Referensi" untuk mencapainya.
5. Selanjutnya, Anda harus menyalin kode VBA berikut ke modul yang tidak digunakan.

Sub AttachSpecificPagesToOutlookEmail()
    Dim strDocumentName As String
    Dim objSelectedPages As Word.Range
    Dim objTempDocument As Word.Document
    Dim objTempRange As Word.Range
    Dim i As Long
    Dim strTempDocument As String
    Dim objOutlookApp As Outlook.Application
    Dim objMail As Outlook.MailItem
 
    strDocumentName = Left(ActiveDocument.Name, InStr(ActiveDocument.Name, ".") - 1)
 
    'Copy the contents from Page 2 to 4
    'You can change the page as per your own needs
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=2
    Set objSelectedPages = Selection.Range
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=4
    objSelectedPages.End = Selection.Bookmarks("\Page").Range.End
    objSelectedPages.Select
    objSelectedPages.Copy
 
    'Paste the copied contents into a new Word Document
    Set objTempDocument = Word.Application.Documents.Add
    objTempDocument.Activate
    Set objTempRange = objTempDocument.Range(0, 0)
    objTempRange.PasteAndFormat (wdFormatOriginalFormatting)

    For i = objTempDocument.Paragraphs.Count To 1 Step -1
        If Len(objTempDocument.Paragraphs(i).Range) = 1 Then
           objTempDocument.Paragraphs(i).Range.Delete
        Else
           Exit For
        End If
    Next i
 
    'Save this document
    strTempDocument = "E:\" & strDocumentName & " (Excerpt).doc"
    objTempDocument.SaveAs2 strTempDocument, wdFormatDocument
 
    'Attach the new document to a new Outlook email
    On Error Resume Next
    Set objOutlookApp = GetObject(, "Outlook.Application")
    If objOutlookApp Is Nothing Then
       Set objOutlookApp = CreateObject("Outlook.Application")
    End If
 
    Set objMail = objOutlookApp.CreateItem(olMailItem)
    objMail.Attachments.Add (strTempDocument)
    objMail.Display
 
    objTempDocument.Close False
    Kill strTempDocument
End Sub

6. Terakhir, Anda dapat menjalankan makro ini. Cukup tekan tombol F5 atau ketuk ikon "Run" di toolbar.
7. Setelah makro selesai, email Outlook baru akan ditampilkan, yang dilampirkan dengan kutipan dari dokumen Word sumber, seperti tangkapan layar berikut:

Ekstrak Data Maksimum dari File Outlook Rusak

Jika Anda telah menggunakan Outlook selama beberapa dekade, Anda mungkin telah dihadapkan dengan berbagai masalah Outlook, termasuk pesan kesalahan dalam popup, crash tiba-tiba, serta kerusakan file yang serius. Karena fakta bahwa scanpst, alat perbaikan bawaan, hanya dapat menangani masalah kecil, Anda sebaiknya menyimpan alat perbaikan eksternal yang kuat, katakanlah DataNumen Outlook Repair. Itu mampu menarik data maksimum dari file data Outlook yang rusak.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk memperbaiki sql dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com