Ինչպես արագ գործարկել հատուկ կանոն բոլոր փոստի թղթապանակներում Outlook VBA-ով

Outlook լուծումներ Սեպտեմբեր 29, 2025

Լռելյայնորեն, դուք կարող եք կանոններ գործարկել միայն մեկ թղթապանակում միաժամանակ: Այս հոդվածում մենք կսովորեցնենք ձեզ, թե ինչպես օգտագործել VBA կոդի մի մասը՝ բոլոր փոստի թղթապանակներում հատուկ կանոն գործարկելու համար:

Outlook-ը թույլ է տալիս օգտվողներին ձեռքով գործարկել կանոնը: Դուք կարող եք պարզապես մուտք գործել «Կանոններ և հիշեցումներ» երկխոսության տուփը և սեղմել «Գործարկել կանոնները հիմա» կոճակը: Հաջորդ երկխոսության վանդակում ընտրեք որոշակի կանոն և ընտրեք թղթապանակ, որտեղ ցանկանում եք գործարկել այս կանոնը: Բայց, եթե ցանկանում եք արագ գործարկել կանոնը բոլոր փոստի թղթապանակներում, կարող եք օգտագործել հետևյալ VBA կոդը:

Արագ գործարկեք հատուկ կանոն բոլոր փոստի թղթապանակներում

Առաջին հերթին, սtarձեր Outlook ծրագիրը:
Ապա Outlook- ի հիմնական պատուհանում սեղմեք «Alt + F11» ստեղնային կոճակները:
Հաջորդ «Microsoft Visual Basic հավելվածների համար» պատուհանում դուք պետք է բացեք չօգտագործվող մոդուլը:
Այնուհետև պատճենեք ստորև նշված VBA կոդը այս մոդուլի պատուհանում: Բացի այդ, դուք պետք է փոխեք որոշ տողեր՝ հիմնվելով ձեր սեփական գործի վրա, օրինակ՝ կանոնի անունը:

Sub RunSpecificRule_AllMailFolders()
    Dim objStores As Outlook.Stores
    Dim objStore As Outlook.Store
    Dim objPSTFile As Outlook.Folder
    Dim objFolders As Outlook.folders
    Dim objFolder As Object

    Set objStores = Outlook.Application.Session.Stores
 
    'Process all Outlook PST files in your Outlook
    For Each objStore In objStores
        Set objPSTFile = objStore.GetRootFolder
        For Each objFolder In objPSTFile.folders
            Call ProcessFolders(objFolder)
        Next
    Next

    MsgBox "Complete!", vbExclamation + vbOKOnly, "Run Rule "
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim objRules As Outlook.Rules
    Dim objRule As Outlook.Rule
    Dim objSubfolder As Outlook.Folder

    Set objRules = Outlook.Application.Session.DefaultStore.GetRules
    'Change the rule name as per your actual case
    Set objRule = objRules.Item("Move Mails to Temp")
 
    On Error Resume Next
    'Only work on non-empty Mail folder
    If objCurrentFolder.Items.count > 0 And objCurrentFolder.DefaultItemType = olMailItem Then
       With objRule
            .Enabled = True
            .Execute ShowProgress:=True, Folder:=objCurrentFolder, IncludeSubfolders:=True
       End With
    End If
 
    'Process subfolders recursively
    If objCurrentFolder.folders.count > 0 Then
       For Each objSubfolder In objCurrentFolder.folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

Դրանից հետո դուք պետք է ստուգեք ձեր Outlook մակրո կարգավորումները՝ համոզվելով, որ մակրոները թույլատրված են:
Ի վերջո կարող եք փորձել:

Պարզապես սեղմեք «RunSpecificRule_AllMailFolders» ենթածրագրի մեջ:
Այնուհետև սեղմեք F5 կոճակը՝ այս կոդը գործարկելու համար:
Հաջորդը մակրոն անմիջապես կաշխատի:
Ավարտելուց հետո դուք կստանաք հաղորդագրություն, ինչպես հետևյալ սքրինշոթը: Դա վերաբերում է կանոնն ավարտված է։

Զգուշացեք վնասակար մակրոներից

Ինչպես մենք բոլորս գիտենք, վնասակար էլ. նամակները գնալով ավելի են տարածվում: Նման նամակները հաճախ կրում են վնասակար մակրոներ: Այսպիսով, եթե դուք սահմանել եք ձեր Outlook մակրո անվտանգության մակարդակը ցածր, դուք պետք է զգուշանաք թաքնված վիրուսներից և չարամիտ ծրագրերից: Ավելին, խելամիտ է ձեռք բերել հզոր PST ամրագրման գործիք, ինչպիսին է DataNumen Outlook Repair, Կարողանում է վերանորոգել PST ֆայլ և արդյունահանեք առավելագույն տվյալներ ձեզ համար՝ առանց քրտնաջանության:

Հեղինակի ներածություն.

Shirley Zhang- ը տվյալների վերականգման փորձագետ է DataNumen, Inc., որը տվյալների վերականգման տեխնոլոգիաների համաշխարհային առաջատարն է, այդ թվում վերականգնել mdf և հեռանկարների նորոգման ծրագրակազմի արտադրանքները: Լրացուցիչ տեղեկությունների համար այցելեք www.datanumen.com