Ինչպե՞ս ծանուցում ստանալ, եթե չստանաք որոշակի նամակի պատասխանը սպասված ժամկետում

Այս հոդվածը ձեզ կսովորեցնի արագ հնարք ՝ օգտագործելով VBA ՝ թույլ տալով, որ Outlook- ը ավտոմատ ձեզ հուշի ՝ ուղարկել ծանուցում էլ.

Timesամանակ առ ժամանակ, կենսականորեն կարևոր էլ-նամակների համար, դուք հաստատ կսպասեք դրա պատասխաններին: Այլ կերպ ասած, դուք պետք է հույս ունենաք, որ ստացողը կարող է հնարավորինս շուտ պատասխանել ձեզ: Հակառակ դեպքում, քանի դեռ դեռ չեք ստացել պատասխանը ձեր սպասված ժամկետում, դուք նորից կուղարկեք ստացողին հետագա ծանուցման էլ. Հետևաբար, ի պատասխան այս պահանջի, մենք այստեղ կներկայացնենք մի մեթոդ, որն օգտագործում է VBA- ն ՝ Outlook- ը դարձնելու համար, որպեսզի ավտոմատ նախազգուշացնի և հուշի ձեզ նման դեպքում: Կարդացեք ՝ մանրամասն քայլերն ու ծածկագրերը ստանալու համար:

Ստացեք ծանուցում, եթե չստանաք որոշակի էլ-նամակի պատասխանը սպասված ժամկետում

1. Հենց ամենասկզբում, սtarձեր հայացքը:
2. Ապա դուք պետք է նշեք հատուկ հիշեցման ժամանակը որոշակի էլ. Փոստին:

• Նախ, աջ սեղմեք կոնկրետ էլ. Փոստի վրա:
• Դրանից հետո ընտրեք «Հետևել»> «Ավելացնել հիշեցում»:
• Երկխոսության պատուհանում կարող եք սահմանել հիշեցման ժամանակը նույնը, ինչ կոնկրետ ժամանակը, որի ընթացքում ցանկանում եք ստանալ դրա պատասխանը:

3. Դրանից հետո սեղմեք «Alt + F11» հիմնական կոճակները Outlook VBA խմբագիր մուտք գործելու համար:
4. Նոր պատուհանում հաջորդը բացեք «ThisOutlookSession» նախագիծը և պատճենեք հետևյալ կոդերը դրա մեջ:

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

'If receive the reply, clear the flag and remove the reminder
Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objSentItems As Outlook.Items
    Dim objVariant As Variant
    Dim i As Long
    Dim strSubject As String
    Dim dSendTime As String
 
    Set objSentItems = Outlook.Application.Session.GetDefaultFolder(olFolderSentMail).Items
 
    If Item.Class = olMail Then
       For i = 1 To objSentItems.Count
           If objSentItems.Item(i).Class = olMail Then
              Set objVariant = objSentItems.Item(i)
              strSubject = LCase(objVariant.Subject)
              dSendTime = objVariant.SentOn
 
              If LCase(Item.Subject) = "re: " & strSubject Or InStr(LCase(Item.Subject), strSubject) > 0 Then
                 If Item.SentOn > dSendTime Then
                    With objVariant
                         .ClearTaskFlag
                         .ReminderSet = False
                         .Save
                    End With
                 End If
              End If
           End If
       Next i
    End If
End Sub

'Get a prompt asking if to send a notification email
Private Sub Application_Reminder(ByVal Item As Object)
    Dim strPrompt As String
    Dim nResponse As Integer
    Dim objFollowUpMail As Outlook.MailItem
 
    'You can change the subject as per your real case
    If (Item.Class = olMail) And (LCase(Item.Subject) = "datanumen outlook repair") Then
       strPrompt = "You haven't yet recieved the reply of " & Chr(34) & Item.Subject & Chr(34) & " within your expected time. Do you want to send a follow-up notification email?"
       nResponse = MsgBox(strPrompt, vbYesNo + vbQuestion, "Confirm to Send a Follow-Up Notification Email")
       If nResponse = vbYes Then
          Set objFollowUpMail = Application.CreateItem(olMailItem)
          With objFollowUpMail
               .To = Item.Recipients.Item(1).Address
               .Subject = "Follow Up: " & Chr(34) & Item.Subject & Chr(34)
               .Body = "Please respond to my email " & Chr(34) & Item.Subject & Chr(34) & "as soon as possible"
               .attachments.Add Item
               .Display
          End With
       End If
    End If
End Sub

5. Դրանից հետո ստորագրեք այս կոդը:
6. Ավելի ուշ փոխեք Outlook մակրո պարամետրը ՝ թվային ստորագրությամբ մակրոները թույլատրելու համար:
7. Ի վերջո restart Outlook ՝ նոր մակրոը ակտիվացնելու համար: Այսուհետ, Outlook- ը կաշխատի որպես հետևյալը.

• Եթե ​​ստացել եք հատուկ էլփոստի պատասխանը նախքան դրա հիշեցումը կհայտնվի, Outlook- ը ավտոմատ կերպով կմաքրի դրոշը և կասեցնի հիշեցումը:
• Եթե ​​դուք չեք ստացել պատասխանը, երբ հիշեցումը գործարկում է, Outlook- ը ձեզանից կխնդրի ուղարկել հետագա ծանուցման էլ. Եթե ​​ընտրեք «Այո», էլ-նամակը կուղարկվի: Եթե ​​ընտրեք «Ոչ», հուշումը միանգամից կվերանա:

Կարգավորեք անհանգստացնող հեռանկարային խնդիրները

Քանի որ Outlook- ը հակված է սխալներին `կանխելու համար Հեռանկարային կոռուպցիա, ավելի լավ է ոչ միայն ապավինել մուտքի արկղի գործիքի ՝ Scanpst.exe- ի: Դուք պետք է պատրաստեք ևս մեկ ուժեղ և հեղինակավոր վերանորոգման գործիք, ինչպիսին է DataNumen Outlook Repair, որը կարող է վերացնել անհանգստացնող խնդիրները, որոնք Scanpst.exe- ն չի կարող կարգավորել:

Հեղինակի ներածություն.

Shirley Zhang- ը տվյալների վերականգման փորձագետ է DataNumen, Inc., որը տվյալների վերականգման տեխնոլոգիաների համաշխարհային առաջատարն է, այդ թվում sql կոռուպցիան և հեռանկարների նորոգման ծրագրակազմի արտադրանքները: Լրացուցիչ տեղեկությունների համար այցելեք www.datanumen.com