Ինչպես խմբաքանակով հեռացնել բոլոր էլփոստի հասցեները հատուկ տիրույթով ձեր Outlook կոնտակտներից

Outlook լուծումներ Սեպտեմբեր 29, 2025
Կիսվել հիմա ՝

Երբեմն կարող եք հուսալ, որ ձեր կոնտակտներից կհեռացնեք բոլոր էլփոստի հասցեները որոշակի տիրույթով: Այս իրավիճակում դուք պետք է չցանկանաք դա անել մեկ առ մեկ։ Այսպիսով, այս պost ձեզ շատ ավելի խելացի մեթոդ կսովորեցնի:

Օրինակ, ընկերությունը փոխում է իր անունը: Միևնույն ժամանակ, ընկերության տիրույթը նույնպես փոխվում է: Այնուամենայնիվ, Outlook-ում դուք շատ կոնտակտներ եք պահել այս ընկերությունում, որոնց էլփոստի հասցեները հին տիրույթում են: Իհարկե, այս էլփոստի հասցեներն այլևս վավեր չեն: Հետևաբար, այս պարագայում, եթե ցանկանում եք հեռացնել այս էլփոստի հասցեները մեկ քայլով, կարող եք օգտագործել հետևյալ կերպ.Խմբաքանակով հեռացրեք բոլոր էլփոստի հասցեները հատուկ տիրույթով ձեր Outlook կոնտակտներից

Կոնտակտներից հեռացրեք բոլոր էլփոստի հասցեները հատուկ տիրույթով

  1. Համար, ինչպեսtart, մուտք գործեք Outlook VBA խմբագրիչ ստեղնաշարի դյուրանցմամբ – «Alt + F11»:
  2. Այնուհետև նոր պատուհանում դատարկ մոդուլում տեղադրեք հետևյալ VBA կոդը.
Dim strDomain As String

Sub BatchRemoveAllEmailAddressesInSpecificDomain()
    Dim objStore As Store
    Dim objFolder As Folder
    Dim lTotalCount As Long
 
    'Input the specific domain
    strDomain = InputBox("Enter the specific domain:", , "@false.com")
 
    If Len(strDomain) <> 0 Then
       lTotalCount = 0
       'Process all Contact folders in your Outlook
       For Each objStore In Application.Session.Stores
           For Each objFolder In objStore.GetRootFolder.Folders
               If objFolder.DefaultItemType = olContactItem Then
                  Call ProcessContactFolders(objFolder, lTotalCount)
               End If
           Next
       Next
 
       'Prompt you
       MsgBox lTotalCount & " email addresses in " & strDomain & " are removed!", vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessContactFolders(ByVal objCurrentFolder As Folder, ByRef lCount As Long)
    Dim objContacts As Items
    Dim i As Long
    Dim objContact As ContactItem
 
    Set objContacts = objCurrentFolder.Items
 
    For i = objContacts.Count To 1 Step -1
        If TypeName(objContacts(i)) = "ContactItem" Then
           Set objContact = objContacts(i)
 
           'Check 3 email addresses of each contact
           If InStr(objContact.Email1Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email1Address = ""
              objContact.Email1DisplayName = ""
           ElseIf InStr(objContact.Email2Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email2Address = ""
              objContact.Email2DisplayName = ""
           ElseIf InStr(objContact.Email3Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email3Address = ""
              objContact.Email3DisplayName = ""
           End If
 
           objContact.Save
        End If
     Next
 
     If objCurrentFolder.Folders.Count > 0 Then
        For Each objSubfolder In objCurrentFolder.Folders
            Call ProcessContactFolders(objSubfolder, lCount)
        Next
     End If
End Sub

VBA Code - խմբաքանակով Կոնտակտներից հեռացնել բոլոր էլփոստի հասցեները հատուկ տիրույթով

  1. Դրանից հետո կուրսորը դրեք «BatchRemoveAllEmailAddressesInSpecificDomain» ենթածրագրում:
  2. Վերջապես, սեղմեք «F5» ստեղնը այս մակրո գործարկելու համար:
  3. Այնուհետև մուտքագրեք կոնկրետ տիրույթը թռուցիկ երկխոսության վանդակում:Մուտքագրեք տիրույթ
  4. «OK» սեղմելուց հետո մակրոն կաշխատի:
  5. Երբ այն ավարտվի, դուք կստանաք հաղորդագրություն արդյունքների մասին:Արդյունքների մասին հուշում
  6. Այժմ դուք կարող եք ստուգել կոնտակտները: Բոլոր էլփոստի հասցեները կոնկրետ տիրույթով պետք է անհետացած լինեն։Հեռացված էլփոստի հասցեները

Պահպանեք ձեր Outlook ֆայլը

Քանի որ ավելի ու ավելի շատ ռիսկեր են պարունակում ձեր Outlook-ը, ավելի ու ավելի դժվար է դառնում պաշտպանել ձեր արժեքավոր Outlook տվյալները: Օրինակ, դուք ոչ միայն պետք է համառեք կանոնավոր տվյալների կրկնօրինակումներում, այլև պետք է զգույշ լինեք ձեր գործողություններին: Խելամիտ չէ հեշտությամբ վստահել անհայտ ուղարկողների նամակներին: Հակառակ դեպքում, եթե այն կրում է վիրուս, ձեր Outlook ֆայլը կվարակվի: Այդ ժամանակ դուք պետք է փորձեք Outlook- ի նորոգում ուշագրավ ամրագրման գործիքի միջոցով, ինչպիսին է DataNumen Outlook Repair.

Հեղինակի ներածություն.

Shirley Zhang- ը տվյալների վերականգման փորձագետ է DataNumen, Inc., որը տվյալների վերականգման տեխնոլոգիաների համաշխարհային առաջատարն է, այդ թվում վերականգնել Sql Server և հեռանկարների նորոգման ծրագրակազմի արտադրանքները: Լրացուցիչ տեղեկությունների համար այցելեք www.datanumen.com

Կիսվել հիմա ՝

Comments փակվում են: