Ինչպե՞ս ավտոմատ կերպով ընդգծել Outlook- ում չպատասխանած կարևոր էլ-նամակները

Որպեսզի հիշեք կարևոր նամակներին պատասխանելը, կարող եք ցանկանալ, որ Outlook- ը ցույց տա ձեր կարևոր նամակները, որոնք չեք պատասխանել որոշակի մանիֆեստի գույնով, դրանք ընդգծելու համար: Այժմ այս հոդվածը կսովորեցնի ձեզ, թե ինչպես ձեռք բերել այն:

Երբևէ կարոտե՞լ եք որևէ կարևոր նամակ և ժամանակին չեք պատասխանել: Եթե ​​ձեզ նման խնդիրներ են առաջացրել, միգուցե հույս ունենաք, որ Outlook- ը կարող է ընդգծել այն կարևոր էլ-նամակները, որոնք դուք չեք պատասխանել: Այժմ հետևյալում մենք ձեզ կառաջնորդենք դրան հասնել VBA- ով: Եթե ​​VBA- ին անծանոթ եք, դիմեք իմ նախորդ հոդվածին ՝ «Ինչպես գործարկել VBA կոդը ձեր Outlook- ում" միեւնույն ժամանակ.

Ավտոմատ նշեք այն կարևոր էլ-նամակները, որոնք չեք պատասխանել

1. Հենց սկզբից մուտք գործեք VBA խմբագիր «Alt + F11» - ի միջոցով Outlook- ում:
2. Դրանից հետո, նոր պատուհանում, պատճենեք ներքևի կոդը «ThisOutlookSession» նախագծում:

Private WithEvents objSentFolder As Outlook.Folder
Private WithEvents objSentMails As Outlook.Items
Private objInbox As Outlook.Folder

'On startup, auto update the replied status of the emails in Inbox
Private Sub Application_Startup()
    Set objSentFolder = Outlook.Application.Session.GetDefaultFolder(olFolderSentMail)
    Set objSentMails = objSentFolder.Items
    Set objInbox = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Call UpdateRepliedStatus(objInbox)
End Sub

'After sending an email, auto update the replied status of the emails in Inbox
Private Sub objSentMails_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       Call UpdateRepliedStatus(objInbox)
    End If
End Sub

Private Sub UpdateRepliedStatus(ByVal objFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objRepliedProperty As Outlook.UserProperty
    Dim strRepliedStatus As String
 
    'Write the replied status to a new user property of emails
    For i = objFolder.Items.Count To 1 Step -1
        If objFolder.Items(i).Class = olMail Then
           Set objMail = objFolder.Items(i)
 
           Set objRepliedProperty = objMail.UserProperties.Find("Replied", True)
           If objRepliedProperty Is Nothing Then
              Set objRepliedProperty = objMail.UserProperties.Add("Replied", olText, True)
           End If
 
           strRepliedStatus = objMail.PropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x10810003")
           If (Not (strRepliedStatus = 102)) And (Not (strRepliedStatus = 103)) Then
              objRepliedProperty.Value = "No"
           Else
              objRepliedProperty.Value = "Yes"
           End If
 
           objMail.Save
        End If
    Next
End Sub

3. Դրանից հետո տեղափոխեք կուրսորը «Application_Startup» մակրոյի վրա և սեղմեք «F5»:
4. Ավելի ուշ, փակիր այս պատուհանը:
5. Հետևաբար, հետևեք հետևյալ քայլերին ՝ Inbox- ում տարրերի պայմանական ձևավորման կանոն ստեղծելու համար:

• Նախ, անցեք «Մուտքի արկղ» պանակին:
• Դրանից հետո անցեք «Դիտել» ներդիրին և կտտացրեք «Դիտել պարամետրերը»:
• Նոր երկխոսության դաշտում կտտացրեք «Պայմանական ձևաչափում» կոճակին:
• Հաջորդ «Պայմանական ձևաչափում» երկխոսության դաշտում կտտացրեք «Ավելացնել» -ին և մուտքագրեք նոր կանոնի անուն, ինչպիսին է «Չպատասխանված կարևոր էլ-նամակները»:
• Ավելի ուշ կտտացրեք «Տառատեսակ button» կոճակին և բացեք «Տառատեսակ» երկխոսության պատուհանում տառատեսակի ոճն ու գույնը:
• Տառատեսակը նշելուց հետո «Պայմանական ձևավորում» երկխոսության պատուհանում սեղմեք «Պայման…»:
• Դրանից հետո «terտիչ» էկրանին, «Ընդլայնված» ներդիրում, ավելացրեք երկու զտիչ:

1. «Կարևորություն»> «հավասար է»> «Բարձր»
2. «Պատասխանել»> «է (ճշգրիտ)»> «Ոչ»

• Ի վերջո, կտտացրեք մի շարք «OK» ՝ ձևաչափման այս կանոնը պահպանելու համար:

6. Մուտքի արկղ վերադառնալուց հետո բոլոր կարևոր էլ-նամակները, որոնց դուք չեք պատասխանել, ընդգծվել են հատուկ տառատեսակով և գույնով:

Մի անհապաղ եղեք Outlook- ի տվյալների պաշտպանության հարցում

Անթիվ օգտատերեր դեռևս կարծում են, որ տվյալների վնասումը երբեք տեղի չի ունենա իրենց հետ։ Իրականում նման մտքերը բացարձակապես սխալ են և ռիսկային։ Շատ դեպքերում, նույնիսկ փոքր սխալը կարող է հեշտությամբ հանգեցնել տվյալների կորստի։ Օրինակ, եթե պատահաբար սեղմեք անհայտ էլ.փոստերում վնասակար հղման վրա, ձեր Outlook ֆայլը կարող է վարակվել վիրուսով և նույնիսկ վնասվել։ Հետևաբար, դուք պետք է միշտ զգույշ լինեք տվյալների պաշտպանության հարցում, օրինակ՝ կանոնավոր կերպով պահպանելով PST պահուստավորումը և պատրաստելով հզոր շտկման գործիք, ինչպիսին է… DataNumen Outlook Repair, որը կարող է շտկել Outlook- ը խնդիրները միանգամից:

Հեղինակի ներածություն.

Shirley Zhang- ը տվյալների վերականգման փորձագետ է DataNumen, Inc., որը տվյալների վերականգման տեխնոլոգիաների համաշխարհային առաջատարն է, այդ թվում վերականգնել mdf և հեռանկարների նորոգման ծրագրակազմի արտադրանքները: Լրացուցիչ տեղեկությունների համար այցելեք www.datanumen.com