A beszélgetésben lévő összes e-mail kötegelt exportálása szöveges fájlként az Outlook VBA-n keresztül

Néha érdemes lehet kötegelt rögzíteni az összes e-mailt egy adott beszélgetésben, majd csoportosan exportálni őket a helyi mappába szöveges fájlként. Ebből a cikkből megtudhatja, hogyan szerezheti meg gyorsan.

Valamilyen oknál fogva előfordulhat, hogy egy bizonyos beszélgetésben lévő összes e-mailt exportálnia kell a helyi meghajtóra. Ha ezt manuálisan teszi meg, nevezetesen egyesével megkeresi és elmenti, fárasztó és fáradságos feladat lesz. Ezért jobb, ha más gyorsabb módszert keres, például a következőt. Egy darab VBA-kódot használ, hogy izzadság nélkül megkapja.

A beszélgetésben lévő összes levél kötegelt exportálása szöveges fájlként

1. A legelején indítsa el az Outlook alkalmazást.
2. Ezután nyomja meg az „Alt + F11” billentyűket az Outlook VBA szerkesztő eléréséhez.
3. Ezt követően az új ablakban meg kell nyitnia egy nem használt modult, vagy közvetlenül be kell illesztenie egy új modult.
4. Ezután másolja és illessze be a következő VBA-kódokat ebbe a modulba.

Public strFilePath, strFileName As String

Sub ExportMailsInConversationAsTXT()
    Dim objSelectedMail As Outlook.MailItem
    Dim objConversation As Outlook.Conversation
    Dim objMail As Outlook.MailItem

    Set objSelectedMail = ActiveExplorer.Selection.Item(1)
    Set objConversation = objSelectedMail.GetConversation
 
    If Not (objConversation Is Nothing) Then
       'Get all root items in this conversation
       For Each objMail In objConversation.GetRootItems
 
          strFileName = objMail.Subject
 
          'Remove the unsupported characters in email subject
          strFileName = Replace(strFileName, "/", " ")
          strFileName = Replace(strFileName, "\", " ")
          strFileName = Replace(strFileName, ":", "")
          strFileName = Replace(strFileName, "?", " ")
          strFileName = Replace(strFileName, Chr(34), " ")

          strFileName = Format(objMail.ReceivedTime, "YYYY-MM-DD") & "_" & strFileName & ".txt"
 
         'Export as Text files
         'Change "E:\" to other local folder path as per your needs
         strFilePath = "E:\" & strFileName
         objMail.SaveAs strFilePath, OLTXT

         'Process all children as well
         Call ProcessChildren(objMail, objConversation)
      Next
   End If

   MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessChildren(objCurMail As Outlook.MailItem, objCurConversation As Outlook.Conversation)
    Dim objItems As Outlook.SimpleItems
    Dim objItem As Outlook.MailItem
 
    Set objItems = objCurConversation.GetChildren(objCurMail)

    If objItems.Count > 0 Then
       For Each objItem In objItems
 
           strFileName = objItem.Subject
 
           strFileName = Replace(strFileName, "/", " ")
           strFileName = Replace(strFileName, "\", " ")
           strFileName = Replace(strFileName, ":", "")
           strFileName = Replace(strFileName, "?", " ")
           strFileName = Replace(strFileName, Chr(34), " ")
 
           strFileName = Format(objItem.ReceivedTime, "yyyy-mm-dd") & "_" & strFileName & ".txt"
 
           strFilePath = "E:\" & strFileName
           objItem.SaveAs strFilePath, OLTXT
 
           'Process all children recursively
           Call ProcessChildren(objItem, objCurConversation)
       Next
    End If
End Sub

5. Ezt követően a szokásos módon hozzáadhatja az új VBA-projektet a Gyorselérési eszköztárhoz.
6. Később ellenőrizze az Outlook makró biztonsági szintjét alacsonyra.
7. Végül egy próbát tehetsz.

• Először válasszon ki egy e-mailt.
• Ezután kattintson az új makró gombra a Gyorselérési eszköztárban.
• Amikor a „Complete” üzenetet kapja, megnyithatja az előre meghatározott helyi mappát, amelyben az e-maileket „TXT” formátumban fogja látni.

Tippek a PST-adatok visszaállításához korrupció után

Az Outlookban gyakran találkozhat különféle Outlook-hibákkal, amelyek némelyike ​​olyan súlyos lehet, hogy egyenesen a PST meghibásodásához vezet. Ilyenkor lépéseket kell tennie javítás PST fájlt, hogy visszakeresse értékes adatait. Ebben az esetben egyszerűen visszatérhet egy jó hírű és jól bevált eszközhöz, mint pl DataNumen Outlook Repair.

Szerző Bevezetés:

Shirley Zhang adat-helyreállítási szakértő DataNumen, Inc., amely világelső az adat-helyreállítási technológiák területén, beleértve meggyógyul sql server és outlook javítószoftver termékek. További információért látogasson el www.datanumen.com