Kako automatski koristiti različite boje fonta za odgovaranje i prosljeđivanje e-pošte s programom Outlook VBA

Prema zadanim postavkama ne možete dopustiti da Outlook automatski koristi različite boje fonta za odgovaranje i prosljeđivanje e-pošte. Stoga, ako imate takav zahtjev, možete pročitati ovu strost naučiti pametan pristup.

Outlook vam dopušta samo da odredite font koji se koristi za odgovaranje i prosljeđivanje e-pošte. Možete otići na “Datoteka” > “Opcije”. Zatim, u "Opcijama programa Outlook", otvorite karticu "Pošta" i kliknite gumb "Dopisnice i fontovi...". U sljedećem prozoru možete vidjeti gumb "Font" u "Odgovaranje ili prosljeđivanje poruka". Pritisnite ga, a zatim možete postaviti određenu boju fonta za odgovaranje i prosljeđivanje e-pošte.

Međutim, mnogi se korisnici nadaju da će koristiti različite boje fonta za odgovaranje ili prosljeđivanje e-pošte. Iako Outlook ne pruža nikakve izravne značajke za to, to se još uvijek može realizirati pomoću VBA koda. Sada čitajte kako biste dobili takav dio VBA koda.

Automatsko korištenje različitih boja fonta za odgovaranje i prosljeđivanje e-pošte

1. Za astart, pokrenite Outlook aplikaciju.
2. Zatim pokrenite VBA editor s referencom na "Kako pokrenuti VBA kod u vašem Outlooku".
3. Zatim, u skladu s “Kako dodati biblioteku objekatarary Referenca u VBA“, dodajte referencu na „MS Word Object Library ”.
4. Nakon toga kopirajte sljedeći kod u projekt “ThisOutlookSession”.

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Dim objReply As Outlook.MailItem
    Dim objReplyDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReply = objMail.Reply
    objReply.Display
    Set objReplyDoc = objReply.GetInspector.WordEditor
    objReplyDoc.Range(0, 0).Select
    Set objDocSelection = objReplyDoc.Application.Selection
    'Use "Pink" font in "Reply"
    objDocSelection.Font.ColorIndex = wdPink
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objReplyAll As Outlook.MailItem
    Dim objReplyAllDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReplyAll = objMail.ReplyAll
    objReplyAll.Display
    Set objReplyAllDoc = objReplyAll.GetInspector.WordEditor
    objReplyAllDoc.Range(0, 0).Select
    Set objDocSelection = objReplyAllDoc.Application.Selection
    'Use "Green" font in "Reply All"
    objDocSelection.Font.ColorIndex = wdGreen
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objForward As Outlook.MailItem
    Dim objForwardDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objForward = objMail.Forward
    objForward.Display
    Set objForwardDoc = objForward.GetInspector.WordEditor
    objForwardDoc.Range(0, 0).Select
    Set objDocSelection = objForwardDoc.Application.Selection
    'Use "Blue" font in Forward
    objDocSelection.Font.ColorIndex = wdBlue
End Sub

5. Nakon toga, reztart Outlook za aktiviranje ove makronaredbe.
6. Konačno, možete pokušati.

• Odaberite ili otvorite e-poštu.
• Zatim kliknite gumb "Odgovori". U odgovoru na e-poštu možete unijeti neke riječi u tijelo. Boja fonta mora biti ružičasta.
• Ili kliknite gumb "Odgovori svima". U novoj poruci "odgovara svima" unesite riječi u tijelo. Boja fonta je sigurno zelena.
• Na sličan način kliknite gumb "Naprijed". U pošti za prosljeđivanje nove riječi bit će prikazane plavom bojom.

Obratite se pouzdanom softveru

U slučaju Outlook korupcija, Most korisnici obično pribjegavaju Outlook softveru za oporavak. Postoji velika količina takvih programa dostupnih na tržištu. A neki od njih su čak i besplatni. Ipak, trebali biste se čuvati onih iz nepoznatih izvora jer oni mogu pogoršati trenutni slučaj. Trebali biste uzeti pomoć pouzdanog i iskusnog alata, npr DataNumen Outlook Repair.

Uvod za autora:

Shirley Zhang stručnjakinja je za oporavak podataka u DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oštećeni sql i softverske proizvode za popravak Outlooka. Za više informacija posjetite www.datanumen.com