Kako grupno ukloniti sve adrese e-pošte s određenom domenom iz Outlook kontakata

Ponekad se možete nadati da ćete iz svojih kontakata ukloniti sve adrese e-pošte s određenom domenom. U ovoj situaciji, sigurno niste voljni činiti to jedno po jedno. Dakle, ova strost naučit će vas daleko pametnijoj metodi.

Na primjer, tvrtka promijeni naziv. U međuvremenu se mijenja i domena tvrtke. Međutim, u Outlooku ste pohranili mnogo kontakata u ovoj tvrtki, čije su adrese e-pošte sa starom domenom. Naravno, ove adrese e-pošte više nisu važeće. Stoga, pod ovim okolnostima, ako želite ukloniti ove adrese e-pošte odjednom, možete upotrijebiti sljedeći način.

Skupno uklanjanje svih adresa e-pošte s određenom domenom iz kontakata

1. Za astart, pristupite Outlook VBA uređivaču tipkovnim prečacem – “Alt + F11”.
2. Zatim u novom prozoru postavite sljedeći VBA kod u prazan modul.

Dim strDomain As String

Sub BatchRemoveAllEmailAddressesInSpecificDomain()
    Dim objStore As Store
    Dim objFolder As Folder
    Dim lTotalCount As Long
 
    'Input the specific domain
    strDomain = InputBox("Enter the specific domain:", , "@false.com")
 
    If Len(strDomain) <> 0 Then
       lTotalCount = 0
       'Process all Contact folders in your Outlook
       For Each objStore In Application.Session.Stores
           For Each objFolder In objStore.GetRootFolder.Folders
               If objFolder.DefaultItemType = olContactItem Then
                  Call ProcessContactFolders(objFolder, lTotalCount)
               End If
           Next
       Next
 
       'Prompt you
       MsgBox lTotalCount & " email addresses in " & strDomain & " are removed!", vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessContactFolders(ByVal objCurrentFolder As Folder, ByRef lCount As Long)
    Dim objContacts As Items
    Dim i As Long
    Dim objContact As ContactItem
 
    Set objContacts = objCurrentFolder.Items
 
    For i = objContacts.Count To 1 Step -1
        If TypeName(objContacts(i)) = "ContactItem" Then
           Set objContact = objContacts(i)
 
           'Check 3 email addresses of each contact
           If InStr(objContact.Email1Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email1Address = ""
              objContact.Email1DisplayName = ""
           ElseIf InStr(objContact.Email2Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email2Address = ""
              objContact.Email2DisplayName = ""
           ElseIf InStr(objContact.Email3Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email3Address = ""
              objContact.Email3DisplayName = ""
           End If
 
           objContact.Save
        End If
     Next
 
     If objCurrentFolder.Folders.Count > 0 Then
        For Each objSubfolder In objCurrentFolder.Folders
            Call ProcessContactFolders(objSubfolder, lCount)
        Next
     End If
End Sub

3. Nakon toga postavite kursor u potprogram “BatchRemoveAllEmailAddressesInSpecificDomain”.
4. Na kraju kliknite tipku "F5" za pokretanje ove makronaredbe.
5. Nakon toga u skočni dijaloški okvir unesite određenu domenu.
6. Nakon klika na “OK”, makro će se pokrenuti.
7. Kada završi, dobit ćete poruku o rezultatima.
8. Sada možete provjeriti kontakte. Sve adrese e-pošte s određenom domenom su sigurno nestale.

Sačuvajte svoju Outlook datoteku

Uz sve više rizika koji okružuju vaš Outlook, sve je teže zaštititi svoje vrijedne Outlook podatke. Na primjer, ne samo da trebate ustrajati u redovitom sigurnosnom kopiranju podataka, već morate paziti i na svoje operacije. Nije mudro odmah vjerovati e-porukama nepoznatih pošiljatelja. U suprotnom, ako nosi virus, vaša će Outlook datoteka biti zaražena. U to vrijeme morate pokušati Outlook popravak putem izvanrednog alata za popravak, kao što je DataNumen Outlook Repair.

Uvod za autora:

Shirley Zhang stručnjakinja je za oporavak podataka u DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oporaviti se Sql Server i softverske proizvode za popravak Outlooka. Za više informacija posjetite www.datanumen.com