Kuinka käyttää erilaisia ​​kirjasusvärejä sähköpostien vastaamiseen ja edelleenlähettämiseen Outlook VBA: n avulla

Oletusarvoisesti et voi antaa Outlookin käyttää automaattista kirjasimen väriä sähköpostiin vastaamiseen ja edelleenlähetykseen. Siksi, jos sinulla on tällainen vaatimus, voit lukea tämän sivunost oppia älykäs lähestymistapa.

Outlook sallii sinun määrittää vain kirjasimen, jota käytetään sekä sähköposteihin vastaamiseen että edelleenlähetykseen. Voit siirtyä kohtaan "Tiedosto"> "Asetukset". Valitse sitten "Outlook-asetukset" -kohdassa "Mail" -välilehti ja napsauta "Paperi ja kirjasimet ..." -painiketta. Seuraavassa ikkunassa näet Fontti-painikkeen kohdassa Viestien vastaaminen tai edelleenlähetys. Napsauta sitä ja voit määrittää tietyn fonttivärin sähköposteihin vastaamiseen ja edelleenlähettämiseen.

Monet käyttäjät toivovat kuitenkin käyttävänsä erilaisia ​​kirjasusvärejä sähköposteihin vastaamiseen tai edelleenlähettämiseen. Vaikka Outlook ei tarjoa suoria ominaisuuksia tälle, se voidaan silti toteuttaa VBA-koodilla. Lue nyt saadaksesi tällaisen osan VBA-koodista.

Käytä erilaisia ​​kirjasusvärejä sähköposteihin vastaamiseen ja edelleenlähetykseen

1. Sillä kutentart, käynnistä Outlook-sovellus.
2. Käynnistä sitten VBA-editori viitteelläKuinka suorittaa VBA-koodi Outlookissa".
3. SeuraavaksiObjektin lisääminen Library Viite VBA: ssa", Lisää viittaus" MS Word Object Library ”.
4. Kopioi sitten seuraava koodi ThisOutlookSession-projektiin.

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Dim objReply As Outlook.MailItem
    Dim objReplyDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReply = objMail.Reply
    objReply.Display
    Set objReplyDoc = objReply.GetInspector.WordEditor
    objReplyDoc.Range(0, 0).Select
    Set objDocSelection = objReplyDoc.Application.Selection
    'Use "Pink" font in "Reply"
    objDocSelection.Font.ColorIndex = wdPink
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objReplyAll As Outlook.MailItem
    Dim objReplyAllDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReplyAll = objMail.ReplyAll
    objReplyAll.Display
    Set objReplyAllDoc = objReplyAll.GetInspector.WordEditor
    objReplyAllDoc.Range(0, 0).Select
    Set objDocSelection = objReplyAllDoc.Application.Selection
    'Use "Green" font in "Reply All"
    objDocSelection.Font.ColorIndex = wdGreen
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objForward As Outlook.MailItem
    Dim objForwardDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objForward = objMail.Forward
    objForward.Display
    Set objForwardDoc = objForward.GetInspector.WordEditor
    objForwardDoc.Range(0, 0).Select
    Set objDocSelection = objForwardDoc.Application.Selection
    'Use "Blue" font in Forward
    objDocSelection.Font.ColorIndex = wdBlue
End Sub

5. Sen jälkeen restart Outlook aktivoi tämän makron.
6. Lopuksi voit kokeilla.

• Valitse tai avaa sähköposti.
• Napsauta sitten Vastaa-painiketta. Vastaamalla sähköpostiin, voit kirjoittaa joitain sanoja runkoon. Kirjasimen värin on oltava vaaleanpunainen.
• Tai napsauta Vastaa kaikille -painiketta. Syötä uudessa "vastaamalla kaikkiin" -postiin sanat rungossa. Kirjasimen väri on varmasti vihreä.
• Napsauta vastaavasti eteenpäin -painiketta. Uudet sanat näkyvät edelleenlähetyspostissa sinisenä.

Käytä luotettavaa ohjelmistoa

Siinä tapauksessa että Outlookin korruptio, Most käyttäjät pyrkivät turvautumaan Outlook-palautusohjelmistoon. Markkinoilla on suuri määrä tällaisia ​​ohjelmia. Jotkut niistä ovat jopa maksuttomia. Sinun tulisi kuitenkin varoa tuntemattomista lähteistä tulevia, koska ne saattavat pahentaa ja pahentaa nykyistä tapausta. Sinun pitäisi käyttää apuna luotettavaa ja kokenutta työkalua, kuten DataNumen Outlook Repair.

Tekijän esittely:

Shirley Zhang on tietojen palauttamisen asiantuntija DataNumen, Inc., joka on maailman johtava tietojen palautustekniikoissa, mukaan lukien vioittunut sql ja Outlookin korjausohjelmistotuotteet. Lisätietoja osoitteessa www.datanumen.com