Kuinka saada ilmoitus, jos et saa vastausta tiettyyn sähköpostiin odotetussa ajassa

Tämä artikkeli opettaa sinulle nopean tempun VBA:n avulla, jotta Outlook kysyy automaattisesti, lähetetäänkö sähköposti-ilmoitus, kun et ole saanut vastausta tiettyyn sähköpostiin tietyn ajan kuluessa.

Joskus elintärkeissä sähköposteissa odotat varmasti sen vastauksia. Toisin sanoen sinun on toivottava, että vastaanottaja voi vastata sinulle mahdollisimman pian. Muussa tapauksessa, niin kauan kuin et ole vielä saanut vastausta odotetussa ajassa, lähetät vastaanottajalle uudelleen seurantailmoituksen. Siksi vastauksena tähän vaatimukseen esittelemme tässä menetelmän, joka käyttää VBA:ta, jotta Outlook varoittaa ja kehottaa sinua automaattisesti tällaisessa tapauksessa. Lue lisää saadaksesi yksityiskohtaiset vaiheet ja koodit.

Saat ilmoituksen, jos et saa vastausta tiettyyn sähköpostiin odotetussa ajassa

1. Heti alussa start Outlookisi.
2. Sitten sinun on asetettava tietty muistutusaika tietylle sähköpostille.

• Napsauta ensin hiiren oikealla painikkeella tiettyä sähköpostia.
• Valitse sitten "Seuranta" > "Lisää muistutus".
• Valintaikkunassa voit asettaa muistutuksen ajan samaksi kuin tietyn ajan, jonka kuluessa haluat saada vastauksen.

3. Tämän jälkeen paina "Alt + F11" -näppäinpainikkeita päästäksesi Outlook VBA -editoriin.
4. Avaa seuraavaksi uudessa ikkunassa "ThisOutlookSession" -projekti ja kopioi seuraavat koodit siihen.

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

'If receive the reply, clear the flag and remove the reminder
Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objSentItems As Outlook.Items
    Dim objVariant As Variant
    Dim i As Long
    Dim strSubject As String
    Dim dSendTime As String
 
    Set objSentItems = Outlook.Application.Session.GetDefaultFolder(olFolderSentMail).Items
 
    If Item.Class = olMail Then
       For i = 1 To objSentItems.Count
           If objSentItems.Item(i).Class = olMail Then
              Set objVariant = objSentItems.Item(i)
              strSubject = LCase(objVariant.Subject)
              dSendTime = objVariant.SentOn
 
              If LCase(Item.Subject) = "re: " & strSubject Or InStr(LCase(Item.Subject), strSubject) > 0 Then
                 If Item.SentOn > dSendTime Then
                    With objVariant
                         .ClearTaskFlag
                         .ReminderSet = False
                         .Save
                    End With
                 End If
              End If
           End If
       Next i
    End If
End Sub

'Get a prompt asking if to send a notification email
Private Sub Application_Reminder(ByVal Item As Object)
    Dim strPrompt As String
    Dim nResponse As Integer
    Dim objFollowUpMail As Outlook.MailItem
 
    'You can change the subject as per your real case
    If (Item.Class = olMail) And (LCase(Item.Subject) = "datanumen outlook repair") Then
       strPrompt = "You haven't yet recieved the reply of " & Chr(34) & Item.Subject & Chr(34) & " within your expected time. Do you want to send a follow-up notification email?"
       nResponse = MsgBox(strPrompt, vbYesNo + vbQuestion, "Confirm to Send a Follow-Up Notification Email")
       If nResponse = vbYes Then
          Set objFollowUpMail = Application.CreateItem(olMailItem)
          With objFollowUpMail
               .To = Item.Recipients.Item(1).Address
               .Subject = "Follow Up: " & Chr(34) & Item.Subject & Chr(34)
               .Body = "Please respond to my email " & Chr(34) & Item.Subject & Chr(34) & "as soon as possible"
               .attachments.Add Item
               .Display
          End With
       End If
    End If
End Sub

5. Allekirjoita tämä koodi myöhemmin.
6. Muuta myöhemmin Outlook-makroasetusta digitaalisesti allekirjoitettujen makrojen sallimiseksi.
7. Lopulta restart Outlook aktivoidaksesi uuden makron. Tästä eteenpäin Outlook toimii seuraavasti:

• Jos olet saanut vastauksen tiettyyn sähköpostiin ennen kuin sen muistutus tulee näkyviin, Outlook poistaa lipun automaattisesti ja poistaa muistutuksen käytöstä.
• Jos et ole saanut vastausta, kun sen muistutus käynnistyy, Outlook kysyy, haluatko lähettää seurantailmoituksen. Jos valitset "Kyllä", sähköposti lähetetään. Jos valitset "Ei", kehote katoaa heti.

Ratkaise ärsyttävät Outlook-ongelmat

Koska Outlook on virhealtis, estämiseksi Outlookin korruptio, sinun ei pitäisi luottaa vain Saapuneet-työkaluun Scanpst.exe. Sinun tulisi valmistaa toinen tehokas ja hyvämaineinen korjaustyökalu, kuten DataNumen Outlook Repair, joka voi poistaa ärsyttävät ongelmat, joita Scanpst.exe ei voi ratkaista.

Tekijän esittely:

Shirley Zhang on tietojen palauttamisen asiantuntija DataNumen, Inc., joka on maailman johtava tietojen palautustekniikoissa, mukaan lukien sql korruptio ja Outlookin korjausohjelmistotuotteet. Lisätietoja osoitteessa www.datanumen.com