Kuinka tallentaa päivittäin saapuvien sähköpostien kokonaismäärä automaattisesti Excel-tiedostoon

Tämä artikkeli opettaa sinulle, kuinka voit antaa Outlookin automaattisesti laskea, kuinka monta sähköpostia olet saanut päivittäin, ja kirjoittaa numeron Excel-tiedostoon.

Monien käyttäjien on laskettava päivittäin vastaanotettujen sähköpostien kokonaismäärä. Lisäksi monet ovat tottuneet tallentamaan kokonaismäärän Excel-tiedostoon helpompaa tarkistamista varten. Tässä tapauksessa voit tietysti laskea ja tallentaa manuaalisesti joka päivä. Se on kuitenkin hieman hankalaa. Ja saatat unohtaa tehdä sen joskus. Siksi sinun on haluttava kätevä menetelmä, joka voi saada Outlookin tekemään sen automaattisesti. Vastauksena tähän vaatimukseen opetamme sinulle seuraavassa, kuinka VBA:ta käytetään sen toteuttamiseen.

Tallenna saapuvien sähköpostien kokonaismäärä päivittäin automaattisesti Excel-tiedostoon

1. Käynnistä Outlook-sovellus heti alusta.
2. Paina sitten "Alt + F11" pikanäppäimiä Outlookin pääikkunassa.
3. Avaa seuraavaksi ponnahdusikkunassa VBA-editori "ThisOutlookSession" -projekti.
4. Kopioi ja liitä seuraavat VBA-koodit sitten tähän projektiin.

Private Sub Application_Reminder(ByVal Item As Object)
    If Item.Class = olTask And Item.Subject = "Update Email Count" Then
       Call GetAllInboxFolders
    End If
End Sub

Private Sub GetAllInboxFolders()
    Dim objInboxFolder As Outlook.Folder
    Dim strExcelFile As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nNextEmptyRow As Integer
    Dim lEmailCount As Long
 
    lEmailCount = 0
    Set objInboxFolder = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Call UpdateEmailCount(objInboxFolder, lEmailCount)
 
    ‘Change the path to the Excel file
    strExcelFile = "E:\Email\Email Count.xlsx"
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Open(strExcelFile)
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = nNextEmptyRow - 1
    objExcelWorksheet.Range("B" & nNextEmptyRow) = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
    objExcelWorksheet.Range("C" & nNextEmptyRow) = lEmailCount
 
    'Fit the columns from A to C
    objExcelWorksheet.Columns("A:C").AutoFit
   
    'Save the changes and close the Excel file
    objExcelWorkbook.Close SaveChanges:=True
End Sub

Private Sub UpdateEmailCount(objFolder As Outlook.Folder, ByRef lCurEmailCount As Long)
    Dim objItems As Outlook.Items
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim strDay As String
    Dim strReceivedDate As String
    Dim lEmailCount As Long
    Dim objSubFolder As Outlook.Folder
 
    Set objItems = objFolder.Items
 
    objItems.SetColumns ("ReceivedTime")
    strDay = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
 
    For Each objItem In objItems
        If objItem.Class = olMail Then
           Set objMail = objItem
           strReceivedDate = Year(objMail.ReceivedTime) & "-" & Month(objMail.ReceivedTime) & "-" & Day(objMail.ReceivedTime)
           If strReceivedDate = strDay Then
              lCurEmailCount = lCurEmailCount + 1
           End If
        End If
    Next
 
    'Process the subfolders in the folder recursively
    If (objFolder.Folders.Count > 0) Then
       For Each objSubFolder In objFolder.Folders
           Call UpdateEmailCount(objSubFolder, lCurEmailCount)
       Next
    End If
End Sub

5. Allekirjoita seuraavaksi tämä koodi ja muuta Outlook-makroasetukset sallimaan allekirjoitetut makrot.
6. Sen jälkeen sinun on luotava toistuva tehtävä päivittäin.

• Napsauta ensin Tehtävät-ruudussa "Uusi tehtävä" -painiketta.
• Napsauta ponnahdusikkunassa Uusi tehtävä -painiketta "Toistuminen".
• Valitse sitten seuraavassa valintaikkunassa "Päivittäin", "Joka 1 päivä(t)" ja "Ei lopetuspäivää" ja paina lopuksi "OK".
• Vaihda myöhemmin tehtävän aihe ja muistutus tarpeidesi mukaan.
• Napsauta lopuksi "Tallenna ja sulje" -painiketta.

7. Tästä eteenpäin joka kerta, kun tämän tehtävän muistutus hälyttää, Outlook laskee automaattisesti eilen vastaanotetut sähköpostit ja tallentaa sitten numeron Excel-tiedostoon seuraavan kuvakaappauksen mukaisesti:

Pakene pysyvää PST-tietojen menetystä

Kukaan ei ole valmis hyväksymään pysyvää PST-tietojen menetystä. Outlook PST-tiedosto on kuitenkin alttiina korruptiolle. Siksi sinun tulee ryhtyä riittäviin varotoimiin, kuten tehdä johdonmukainen ja ajan tasalla oleva PST-tietojen varmuuskopio ja säilyttää tehokas PST-palautus työkalu läheisyydessä, kuten DataNumen Outlook Repair.

Tekijän esittely:

Shirley Zhang on tietojen palauttamisen asiantuntija DataNumen, Inc., joka on maailman johtava tietojen palautustekniikoissa, mukaan lukien sql korjaus ja Outlookin korjausohjelmistotuotteet. Lisätietoja osoitteessa www.datanumen.com