Kuidas kiiresti kõik failid a Zip Outlooki meili manus

Outlooki lahendused September 29, 2025

Paljud kasutajad loodavad printida kõik failid, mis on tihendatud a zip Outlooki meili manusena ilma seda tülikat salvestamata ja lahti pakkimata zip manus. Seetõttu tutvustatakse selles artiklis palju tõhusamaid viise selle realiseerimiseks.

Kui soovite printida a zip manusena, võite olla harjunud sellele pihta panema ja lindil nuppu "Kiirprintimine" klõpsama. Sel viisil palub Outlook teil siiski salvestada ja tühistadazip see esiteks. Kui soovite neid tüütuid samme vältida, võite kasutada järgmist VBA koodi.

Printige kiiresti kõik failid a Zip Outlooki meili manus

Printige kõik failid a Zip E-kirja manus

  1. Alustuseks start oma Outlooki rakendust.
  2. Seejärel hankige juurdepääs Outlooki VBA redaktorile, järgides artiklis näidatud samme – "Kuidas Outlookis VBA-koodi käivitada".
  3. Järgmisena saate avada projekti ThisOutlookSession või kasutamata mooduli.
  4. Seejärel kopeerige ja kleepige allolev VBA kood.
Dim objShell As Object
Dim objFileSystem As Object

Sub PrintAllFilesInZipAttachment ()
    Dim objAttachmentSelection As Outlook.AttachmentSelection
    Dim objAttachment, objTempAttachment As Outlook.Attachment
    Dim strTempFolder As String
    Dim strSavingPath As String
    Dim objTempMail As Outlook.MailItem
    Dim strFileName As String
 
    'Get selected attachment
    Set objAttachmentSelection = Outlook.Application.ActiveExplorer.AttachmentSelection
    Set objAttachment = objAttachmentSelection.Item(1)

    If Right(LCase(objAttachment.filename), 3) = "zip" Then
 
       'Save & Unzip the zip attachment
       Set objShell = CreateObject("Shell.Application")
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
       strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Unzip" & Format(Now, "yyyymmddhhmmss")
       MkDir (strTempFolder)
 
       strSavingPath = strTempFolder & "\" & objAttachment.filename
       objAttachment.SaveAsFile (strSavingPath)
       objShell.NameSpace((strTempFolder)).CopyHere objShell.NameSpace((strSavingPath)).Items
  
       'Attach Unzipped files to a temp mail
       Set objTempMail = Outlook.Application.CreateItem(olMailItem)
       objTempMail.Display
       strFileName = Dir(strTempFolder & "\")
 
       While Len(strFileName) > 0
             objTempMail.Attachments.Add (strTempFolder & "\" & strFileName)
             strFileName = Dir()
       Wend
 
       'Print all attachments of the temp email
       Call PrintFiles(objTempMail)
 
       objTempMail.Close olDiscard
 
       objFileSystem.DeleteFolder (strTempFolder)
    End If
End Sub

Sub PrintFiles(ByVal objMail As Outlook.MailItem)
    Dim objAttachment As Outlook.Attachment
    Dim strTempFolder, strFilePath As String
    Dim objTempFolder As Object
    Dim objTempFolderItem As Object
 
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\TEMP" & Format(Now, "yyyymmddhhmmss")
    MkDir (strTempFolder)
 
    'Print all attachments
    For Each objAttachment In objMail.Attachments
        If Right(LCase(objAttachment.filename), 3) <> "zip" Then
           strFilePath = strTempFolder & "\" & objAttachment.filename
           objAttachment.SaveAsFile (strFilePath)
 
           Set objShell = CreateObject("Shell.Application")
           Set objTempFolder = objShell.NameSpace(0)
           Set objTempFolderItem = objTempFolder.ParseName(strFilePath)
           objTempFolderItem.InvokeVerbEx ("print")
        End If
    Next
 
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

VBA kood – printige kõik failid a Zip E-kirja manus

  1. Pärast seda sulgege praegune VBA redaktori aken.
  2. Hiljem avage Outlooki suvandid, et lisada kiirpääsu tööriistaribale uus makro.
  3. Lõpuks saate pildistada:
  • Esmalt valige a zip e-kirja manusena.
  • Seejärel klõpsake kiirpääsu tööriistaribal makrot.Käivitage makro kiirpääsu tööriistariba kaudu
  1. Valitud failid tihendatakse korraga zip manus prinditakse.

Varundage Outlooki andmefailid

Võib-olla olete avastanud, et Outlook on altid korruptsioonile. Kui Outlook saab rikutud, on teie Outlooki andmed lost. Seetõttu on oluline teha oma Outlooki andmefailidest regulaarselt varukoopiaid, et saaksite Outlooki andmeid hõlpsasti varundada. Kuid kui leiate, et varukoopia on mitu nädalat vana ja ebatõhus, ei jää teil muud üle, kui pöörduda usaldusväärse ja kogenud PST taastamine tööriist, näiteks DataNumen Outlook Repair.

Autori sissejuhatus:

Shirley Zhang on andmete taastamise ekspert DataNumen, Inc., mis on maailmas juhtiv andmete taastamise tehnoloogiate, sealhulgas kahjustatud mdf ja Outlooki remonditarkvaratooted. Lisateabe saamiseks külastage www.datanumenCom

Kommentaarid on suletud.