2 kiiret viisi teise meili saatmiseks ainult Outlooki e-kirjade BCC-saajatele

Saadate e-kirja mitmele adressaadile ja sisestate mõned neist väljale "BCC". Hiljem, kui soovite saata teise kirja ainult Pimekoopia adressaatidele, saate kasutada selles artiklis jagatud vahendeid.

Kas olete kunagi saatnud Outlooki e-kirju mitmele adressaadile, millest osa on väljal „BCC”? Mõnikord võiksite pärast sellise meili saatmist saata teise kirja teatud tüüpi adressaatidele, näiteks BCC-saajatele. Näiteks soovite saata neile teatud lisamärkmeid. Nüüd tutvustame teile kahte võimalust. Esimene kasutab kopeerimist ja kleepimist. Ja viimane on tänu VBA koodile tegelikult palju tõhusam. Saate valida vastavalt oma vajadustele.

1. meetod: kopeerige BCC saajad käsitsi uude meili

1. Esiteks valige kausta „Saadetud üksused” meililoendis algne e-kiri.
2. Seejärel topeltklõpsake sellel kirjal, et avada see oma sõnumiaknas.
3. Seejärel valige uues aknas "BCC" real üks adressaat.
4. Järgmisena vajutage kõigi BCC adressaatide valimiseks klahvikombinatsiooni Ctrl + A.
5. Hiljem paremklõpsake ja valige kontekstimenüüst "Kopeeri".
6. Pärast seda sulgege see meil.
7. Seejärel looge vahekaardil "Kodu" nupuga "Uus e-kiri" uus e-kiri.
8. Lõpuks kleepige kopeeritud Pimekoopia saajad selle uue meili väljale Saaja.
9. Praegu saate seda uut kirja koostada ja saata soovi korral

2. meetod: saatke teine ​​e-kiri BCC adressaatidele VBA kaudu

1. Esiteks vajutage VBA redaktori avamiseks klahvikombinatsiooni Alt + F11.
2. Seejärel pange allolev VBA kood kasutamata moodulisse.

Sub SendAnotherEmailToBCCRecipients()
    Dim objOriginalMail As Outlook.MailItem
    Dim objRecipient As Outlook.Recipient
    Dim objNewMail As Outlook.MailItem
    Dim objNewRecipient As Outlook.Recipient
 
    'Get source email
    Select Case TypeName(Application.ActiveWindow)
           Case "Inspector"
                Set objOriginalMail = ActiveInspector.CurrentItem
           Case "Explorer"
                Set objOriginalMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    'Copy the BCC recipients to "To" field in new mail
    Set objNewMail = Outlook.Application.CreateItem(olMailItem)
    For Each objRecipient In objOriginalMail.Recipients
        If objRecipient.Type = olBCC Then
           Set objNewRecipient = objNewMail.Recipients.Add(objRecipient)
           objNewRecipient.Type = olTo
           objNewRecipient.Resolve
        End If
    Next
 
    'Change the new email details
    With objNewMail
        .Subject = "Additional Notes for " & objOriginalMail.Subject
        .Body = "Type mail body here....."
        .Attachments.Add ("E:\Dos & Don'ts.txt")
        .Importance = olImportanceHigh
        .ReadReceiptRequested = True
        .Send
        .Display
    End With
End Sub

3. Seejärel lisage see makro kiirpääsu tööriistaribale, viidates "Kuidas Outlookis VBA-koodi käivitada".
4. Lõpuks proovige seda makrot kohe.

• Alustuseks valige või avage algne meil.
• Seejärel klõpsake kiirpääsu tööriistaribal makrot.
• Järgmisena saadetakse välja uus e-kiri. Selle saajad on algse e-kirja BCC saajad, nagu järgmine pilt.

Salvestage oma Outlooki andmed õigeaegselt

Väga soovitav on Outlooki parandamine niipea, kui teie Outlook on kahjustatud. Esiteks võite kasutada sisseehitatud remondiutiliiti Scanpst. Kuid mõnikord võivad teid Scanpsti tõrked esineda, kuna kahju on ületanud postkasti tööriista võimekuse. Sel ajal on teie viimane abinõu kasutada usaldusväärset ja tugevat kolmanda osapoole tööriista, näiteks DataNumen Outlook Repair.

Autori sissejuhatus:

Shirley Zhang on andmete taastamise ekspert DataNumen, Inc., mis on maailmas juhtiv andmete taastamise tehnoloogiate, sealhulgas kahjustatud mdf ja Outlooki remonditarkvaratooted. Lisateabe saamiseks külastage www.datanumenCom