Cómo eliminar por lotes todas las direcciones de correo electrónico con un dominio específico de sus contactos de Outlook

En ocasiones, es posible que desee eliminar todas las direcciones de correo electrónico con un dominio específico de sus contactos. En esta situación, no debe estar dispuesto a hacerlo uno por uno. Por lo tanto, este post le enseñará un método mucho más inteligente.

Por ejemplo, una empresa cambia de nombre. Mientras tanto, el dominio de la empresa también se modifica. Sin embargo, en Outlook, ha almacenado muchos contactos en esta empresa, cuyas direcciones de correo electrónico pertenecen al dominio anterior. Por supuesto, estas direcciones de correo electrónico ya no son válidas. Por lo tanto, bajo esta circunstancia, si desea eliminar estas direcciones de correo electrónico de una sola vez, puede utilizar la siguiente forma.

Eliminar por lotes todas las direcciones de correo electrónico con un dominio específico de los contactos

1. Porque comotart, acceda al editor de Outlook VBA mediante el atajo de teclas - "Alt + F11".
2. Luego, en la nueva ventana, coloque el siguiente código VBA en un módulo vacío.

Dim strDomain As String

Sub BatchRemoveAllEmailAddressesInSpecificDomain()
    Dim objStore As Store
    Dim objFolder As Folder
    Dim lTotalCount As Long
 
    'Input the specific domain
    strDomain = InputBox("Enter the specific domain:", , "@false.com")
 
    If Len(strDomain) <> 0 Then
       lTotalCount = 0
       'Process all Contact folders in your Outlook
       For Each objStore In Application.Session.Stores
           For Each objFolder In objStore.GetRootFolder.Folders
               If objFolder.DefaultItemType = olContactItem Then
                  Call ProcessContactFolders(objFolder, lTotalCount)
               End If
           Next
       Next
 
       'Prompt you
       MsgBox lTotalCount & " email addresses in " & strDomain & " are removed!", vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessContactFolders(ByVal objCurrentFolder As Folder, ByRef lCount As Long)
    Dim objContacts As Items
    Dim i As Long
    Dim objContact As ContactItem
 
    Set objContacts = objCurrentFolder.Items
 
    For i = objContacts.Count To 1 Step -1
        If TypeName(objContacts(i)) = "ContactItem" Then
           Set objContact = objContacts(i)
 
           'Check 3 email addresses of each contact
           If InStr(objContact.Email1Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email1Address = ""
              objContact.Email1DisplayName = ""
           ElseIf InStr(objContact.Email2Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email2Address = ""
              objContact.Email2DisplayName = ""
           ElseIf InStr(objContact.Email3Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email3Address = ""
              objContact.Email3DisplayName = ""
           End If
 
           objContact.Save
        End If
     Next
 
     If objCurrentFolder.Folders.Count > 0 Then
        For Each objSubfolder In objCurrentFolder.Folders
            Call ProcessContactFolders(objSubfolder, lCount)
        Next
     End If
End Sub

3. Después de eso, coloque el cursor en la subrutina "BatchRemoveAllEmailAddressesInSpecificDomain".
4. Finalmente, haga clic en el botón de la tecla "F5" para activar esta macro.
5. Posteriormente, ingrese el dominio específico en el cuadro de diálogo emergente.
6. Después de hacer clic en "Aceptar", se ejecutará la macro.
7. Cuando termine, recibirá un mensaje sobre los resultados.
8. Ahora puedes comprobar los contactos. Todas las direcciones de correo electrónico con el dominio específico deben haber desaparecido.

Conserve su archivo de Outlook

Con cada vez más riesgos en torno a Outlook, es cada vez más difícil proteger sus valiosos datos de Outlook. Por ejemplo, no solo debe persistir en las copias de seguridad de datos regulares, sino que también debe tener cuidado con sus operaciones. No es aconsejable confiar fácilmente en los correos electrónicos de remitentes desconocidos. De lo contrario, si lleva virus, su archivo de Outlook se infectará. En ese momento, debes intentar Reparación de Outlook a través de una herramienta de reparación notable, como DataNumen Outlook Repair.

Introducción del autor:

Shirley Zhang es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo recuperar Sql Server y productos de software de reparación de Outlook. Para más información visite www.datanumen.com