Τρόπος γρήγορης εξαγωγής όλων των φακέλων και στοιχείων του Outlook στην ενότητα "Αγαπημένα" σε φάκελο Windows

Εάν θέλετε να εξάγετε όλους τους φακέλους του Outlook καθώς και τα στοιχεία του στην ενότητα "Αγαπημένα", μπορείτε να ανατρέξετε σε αυτό το άρθρο. Εδώ θα σας δείξουμε πώς να το επιτύχετε σε γρήγορο χρόνο.

Γενικά, οι φάκελοι και τα αντικείμενά του στην ενότητα "Αγαπημένα" έχουν μεγάλη σημασία και απαιτούνται συχνά. Επομένως, κατά καιρούς, μπορεί να θέλετε να τα εξαγάγετε στην τοπική μονάδα δίσκου. Με τον τυπικό τρόπο, πρέπει να δημιουργήσετε φακέλους Windows σύμφωνα με τους φακέλους στο "Favorites" και να αποθηκεύσετε αντικείμενα ως αρχεία MSG ένα προς ένα στην τοπική μονάδα δίσκου. Αυτό είναι πολύ κουραστικό. Ως εκ τούτου, εδώ θα εκθέσουμε έναν πολύ πιο αποτελεσματικό τρόπο. Τώρα διαβάστε για να το πάρετε.

Εξαγωγή όλων των φακέλων και στοιχείων στην ενότητα "Αγαπημένα" σε φάκελο των Windows

1. Αρχικά, αποκτήστε πρόσβαση στο πρόγραμμα επεξεργασίας VBA στο Outlook ανατρέχοντας στο "Τρόπος εκτέλεσης κώδικα VBA στο Outlook".
2. Στη συνέχεια, αντιγράψτε τον ακόλουθο κώδικα σε μια κενή λειτουργική μονάδα.

Sub ExportAllFoldersItems_InFavorites_ToWindowsFolder()
    Dim objShell As Object
    Dim objWindowsFolder As Object
    Dim objFileSystem As Object
    Dim strWindowsFolder As String
    Dim objNavigationPane As Outlook.NavigationPane
    Dim objNavigationModule As Outlook.NavigationModule
    Dim objNavigationGroup As Outlook.NavigationGroup
    Dim objNavigationFolder As Outlook.NavigationFolder
    Dim objFolder As Outlook.Folder
    Dim strFolderPath As String
    Dim objItem As Object
    Dim strFilePath As String
    Dim i As Long
 
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    If Not objWindowsFolder Is Nothing Then
       strWindowsFolder = objWindowsFolder.self.Path & "\"
     
       'Get "Favorites" section
       Set objNavigationPane = Application.ActiveExplorer.NavigationPane
       Set objNavigationModule = objNavigationPane.Modules.GetNavigationModule(olModuleMail)
       Set objNavigationGroup = objNavigationModule.NavigationGroups.GetDefaultNavigationGroup(olFavoriteFoldersGroup)
 
       'Export the folders and items in "Favorites" section
       For Each objNavigationFolder In objNavigationGroup.NavigationFolders
           Set objFolder = objNavigationFolder.Folder
           strFolderPath = strWindowsFolder & objFolder.Name
           objFileSystem.CreateFolder strFolderPath
 
           For Each objItem In objFolder.Items
               strSubject = objItem.Subject
               strFileName = strSubject & ".msg"
 
               i = 0
               Do Until False
                  strFilePath = strFolderPath & "\" & strFileName
                  If objFileSystem.FileExists(strFilePath) Then
                     i = i + 1
                     strFileName = strSubject & " (" & i & ").msg"
                  Else
                     Exit Do
                  End If
               Loop
 
               objItem.SaveAs strFilePath, olMSG
          Next
       Next
 
       'Open the Windows folder
       Call Shell("explorer.exe " & strWindowsFolder, vbNormalFocus)
    End If
End Sub

3. Στη συνέχεια, κάντε κλικ στο εικονίδιο "Εκτέλεση" στη γραμμή εργαλείων.
4. Στη συνέχεια, στο αναδυόμενο παράθυρο διαλόγου, επιλέξτε έναν φάκελο Windows προορισμού και κάντε κλικ στο "OK".
5. Όταν ολοκληρωθεί η μακροεντολή, θα εμφανιστεί ο φάκελος των Windows.
6. Σε αυτόν τον φάκελο των Windows, οι φάκελοι και τα στοιχεία του στην ενότητα "Αγαπημένα" έχουν εξαχθεί, όπως το παρακάτω στιγμιότυπο οθόνης.

Επαναφορά δεδομένων του Outlook από αντίγραφα ασφαλείας

Συνιστάται ιδιαίτερα να δημιουργείτε αντίγραφα ασφαλείας των αρχείων του Outlook σε τακτική βάση. Επειδή εάν υποφέρετε από καταστροφή αρχείων του Outlook, μπορείτε ανακτήστε το Outlook δεδομένα από αντίγραφα ασφαλείας εύκολα. Ωστόσο, εάν δεν έχετε τέτοιο αντίγραφο ασφαλείας, πρέπει να επιχειρήσετε επίπονη επιδιόρθωση του Outlook. Εκείνη τη στιγμή, το εργαλείο επιδιόρθωσης εισερχομένων δεν θα βοηθήσει πολύ. Πρέπει να λάβετε βοήθεια για την επιδιόρθωση εξωτερικού εργαλείου, όπως DataNumen Outlook Repair.

Εισαγωγή συγγραφέα:

Η Shirley Zhang είναι ειδικός ανάκτησης δεδομένων στο DataNumen, Inc., η οποία είναι ο παγκόσμιος ηγέτης στις τεχνολογίες ανάκτησης δεδομένων, συμπεριλαμβανομένων κατεστραμμένο sql και προϊόντα λογισμικού επισκευής προοπτικών. Για περισσότερες πληροφορίες επισκεφθείτε www.datanumen.com