Τρόπος εξαγωγής παρτίδας όλων των μηνυμάτων ηλεκτρονικού ταχυδρομείου σε μια συνομιλία ως αρχεία κειμένου μέσω του Outlook VBA

Μερικές φορές, μπορεί να θέλετε να καταγράψετε παρτίδα όλα τα μηνύματα ηλεκτρονικού ταχυδρομείου σε μια συγκεκριμένη συνομιλία και στη συνέχεια να τα εξαγάγετε κατά παρτίδα στον τοπικό φάκελο ως αρχεία κειμένου. Αυτό το άρθρο θα σας διδάξει πώς να το αποκτήσετε γρήγορα.

Για κάποιο λόγο, μπορεί να χρειαστεί να εξάγετε όλα τα μηνύματα ηλεκτρονικού ταχυδρομείου σε μια συγκεκριμένη συνομιλία στην τοπική μονάδα δίσκου. Εάν το κάνετε χειροκίνητα, δηλαδή να βρείτε και να αποθηκεύσετε ένα προς ένα, θα είναι ένα κουραστικό και επίπονο έργο. Επομένως, καλύτερα να αναζητήσετε άλλη ταχύτερη μέθοδο, όπως η ακόλουθη. Θα χρησιμοποιήσει ένα κομμάτι κώδικα VBA για να το πάρει χωρίς να ιδρώσει.

Μαζική εξαγωγή όλων των μηνυμάτων σε μια συνομιλία ως αρχεία κειμένου

1. Στην αρχή, ξεκινήστε την εφαρμογή Outlook.
2. Στη συνέχεια, πατήστε τα πλήκτρα "Alt + F11" για πρόσβαση στο πρόγραμμα επεξεργασίας του Outlook VBA.
3. Στη συνέχεια, στο νέο παράθυρο, πρέπει να ανοίξετε μια ενότητα που δεν χρησιμοποιείται ή να εισαγάγετε απευθείας μια νέα μονάδα.
4. Στη συνέχεια, θα πρέπει να αντιγράψετε και να επικολλήσετε τους ακόλουθους κώδικες VBA σε αυτήν την ενότητα.

Public strFilePath, strFileName As String

Sub ExportMailsInConversationAsTXT()
    Dim objSelectedMail As Outlook.MailItem
    Dim objConversation As Outlook.Conversation
    Dim objMail As Outlook.MailItem

    Set objSelectedMail = ActiveExplorer.Selection.Item(1)
    Set objConversation = objSelectedMail.GetConversation
 
    If Not (objConversation Is Nothing) Then
       'Get all root items in this conversation
       For Each objMail In objConversation.GetRootItems
 
          strFileName = objMail.Subject
 
          'Remove the unsupported characters in email subject
          strFileName = Replace(strFileName, "/", " ")
          strFileName = Replace(strFileName, "\", " ")
          strFileName = Replace(strFileName, ":", "")
          strFileName = Replace(strFileName, "?", " ")
          strFileName = Replace(strFileName, Chr(34), " ")

          strFileName = Format(objMail.ReceivedTime, "YYYY-MM-DD") & "_" & strFileName & ".txt"
 
         'Export as Text files
         'Change "E:\" to other local folder path as per your needs
         strFilePath = "E:\" & strFileName
         objMail.SaveAs strFilePath, OLTXT

         'Process all children as well
         Call ProcessChildren(objMail, objConversation)
      Next
   End If

   MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessChildren(objCurMail As Outlook.MailItem, objCurConversation As Outlook.Conversation)
    Dim objItems As Outlook.SimpleItems
    Dim objItem As Outlook.MailItem
 
    Set objItems = objCurConversation.GetChildren(objCurMail)

    If objItems.Count > 0 Then
       For Each objItem In objItems
 
           strFileName = objItem.Subject
 
           strFileName = Replace(strFileName, "/", " ")
           strFileName = Replace(strFileName, "\", " ")
           strFileName = Replace(strFileName, ":", "")
           strFileName = Replace(strFileName, "?", " ")
           strFileName = Replace(strFileName, Chr(34), " ")
 
           strFileName = Format(objItem.ReceivedTime, "yyyy-mm-dd") & "_" & strFileName & ".txt"
 
           strFilePath = "E:\" & strFileName
           objItem.SaveAs strFilePath, OLTXT
 
           'Process all children recursively
           Call ProcessChildren(objItem, objCurConversation)
       Next
    End If
End Sub

5. Μετά από αυτό, μπορείτε να προσθέσετε το νέο έργο VBA στη γραμμή εργαλείων γρήγορης πρόσβασης ως συνήθως.
6. Αργότερα βεβαιωθείτε ότι το επίπεδο ασφάλειας μακροεντολής του Outlook είναι χαμηλό.
7. Τέλος, μπορείτε να δοκιμάσετε.

• Αρχικά, επιλέξτε ένα email.
• Στη συνέχεια, κάντε κλικ στο νέο κουμπί μακροεντολής στη γραμμή εργαλείων γρήγορης πρόσβασης.
• Όταν λάβετε το μήνυμα "Ολοκλήρωση", μπορείτε να ανοίξετε τον προκαθορισμένο τοπικό φάκελο, στον οποίο θα δείτε τα μηνύματα ηλεκτρονικού ταχυδρομείου σε μορφή "TXT".

Συμβουλές για την επαναφορά δεδομένων PST μετά από διαφθορά

Συχνά, στο Outlook, ενδέχεται να συναντήσετε διάφορα σφάλματα του Outlook, μερικά από τα οποία μπορεί να είναι σοβαρά, ώστε να οδηγήσουν άμεσα σε καταστροφή του PST. Εκείνη τη στιγμή, πρέπει να λάβετε μέτρα για να επισκευή PST αρχείο για να βρείτε πίσω τα πολύτιμα δεδομένα σας. Σε αυτή την περίπτωση, μπορείτε απλά να επαναλάβετε ένα αξιόπιστο και καλά αποδεδειγμένο εργαλείο, όπως DataNumen Outlook Repair.

Εισαγωγή συγγραφέα:

Η Shirley Zhang είναι ειδικός ανάκτησης δεδομένων στο DataNumen, Inc., η οποία είναι ο παγκόσμιος ηγέτης στις τεχνολογίες ανάκτησης δεδομένων, συμπεριλαμβανομένων ανάκτηση sql server και προϊόντα λογισμικού επισκευής προοπτικών. Για περισσότερες πληροφορίες επισκεφθείτε www.datanumen.com