Πώς να επισυνάψετε γρήγορα τις συγκεκριμένες σελίδες ενός εγγράφου του Word σε ένα μήνυμα ηλεκτρονικού ταχυδρομείου του Outlook

Το MS Word διαθέτει μια άμεση δυνατότητα που υποστηρίζει τους χρήστες να στείλουν το τρέχον έγγραφο του Word ως συνημμένο email. Αλλά μερικές φορές, μπορεί να ελπίζετε μόνο να επισυνάψετε τις συγκεκριμένες σελίδες ενός εγγράφου του Word σε ένα μήνυμα ηλεκτρονικού ταχυδρομείου του Outlook. Τώρα, αυτό το άρθρο θα σας μοιραστεί μια μέθοδο.

Για να στείλετε ένα ολόκληρο έγγραφο του Word ως συνημμένο email στην εφαρμογή MS Word, μπορείτε απλώς να μεταβείτε στο μενού "Αρχείο" και να μεταβείτε στην καρτέλα "Αποθήκευση & Αποστολή", κάτω από την οποία μπορείτε να βρείτε το κουμπί "Αποστολή ως συνημμένο". Ωστόσο, μερικές φορές, αυτό που θέλετε να στείλετε μπορεί να είναι μόνο συγκεκριμένες σελίδες του εγγράφου. Σε αυτήν την περίπτωση, μπορείτε να χρησιμοποιήσετε τη μέθοδο που εισάγεται στα ακόλουθα για να το πετύχετε.

Επισυνάψτε τις συγκεκριμένες σελίδες ενός εγγράφου του Word σε ένα email

1. Πρώτα απ 'όλα, θα πρέπει να ανοίξετε το έγγραφο προέλευσης του Word του οποίου τις συγκεκριμένες σελίδες θέλετε να στείλετε σε email.
2. Στη συνέχεια, αφού μπείτε στο παράθυρο του MS Word, πρέπει να πατήσετε τα πλήκτρα "Alt + F11".
3. Στη συνέχεια, θα έχετε πρόσβαση στον επεξεργαστή VBA στο MS Word.
4. Μετά από αυτό, πρέπει να ενεργοποιήσετε το "Microsoft Outlook Object Library”. Μπορείτε να πατήσετε «Εργαλεία» > «Αναφορά» για να το πετύχετε.
5. Στη συνέχεια, θα πρέπει να αντιγράψετε τον ακόλουθο κώδικα VBA σε μια λειτουργική μονάδα που δεν χρησιμοποιείται.

Sub AttachSpecificPagesToOutlookEmail()
    Dim strDocumentName As String
    Dim objSelectedPages As Word.Range
    Dim objTempDocument As Word.Document
    Dim objTempRange As Word.Range
    Dim i As Long
    Dim strTempDocument As String
    Dim objOutlookApp As Outlook.Application
    Dim objMail As Outlook.MailItem
 
    strDocumentName = Left(ActiveDocument.Name, InStr(ActiveDocument.Name, ".") - 1)
 
    'Copy the contents from Page 2 to 4
    'You can change the page as per your own needs
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=2
    Set objSelectedPages = Selection.Range
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=4
    objSelectedPages.End = Selection.Bookmarks("\Page").Range.End
    objSelectedPages.Select
    objSelectedPages.Copy
 
    'Paste the copied contents into a new Word Document
    Set objTempDocument = Word.Application.Documents.Add
    objTempDocument.Activate
    Set objTempRange = objTempDocument.Range(0, 0)
    objTempRange.PasteAndFormat (wdFormatOriginalFormatting)

    For i = objTempDocument.Paragraphs.Count To 1 Step -1
        If Len(objTempDocument.Paragraphs(i).Range) = 1 Then
           objTempDocument.Paragraphs(i).Range.Delete
        Else
           Exit For
        End If
    Next i
 
    'Save this document
    strTempDocument = "E:\" & strDocumentName & " (Excerpt).doc"
    objTempDocument.SaveAs2 strTempDocument, wdFormatDocument
 
    'Attach the new document to a new Outlook email
    On Error Resume Next
    Set objOutlookApp = GetObject(, "Outlook.Application")
    If objOutlookApp Is Nothing Then
       Set objOutlookApp = CreateObject("Outlook.Application")
    End If
 
    Set objMail = objOutlookApp.CreateItem(olMailItem)
    objMail.Attachments.Add (strTempDocument)
    objMail.Display
 
    objTempDocument.Close False
    Kill strTempDocument
End Sub

6. Τέλος, μπορείτε να εκτελέσετε αυτήν τη μακροεντολή. Απλώς πατήστε το πλήκτρο F5 ή πατήστε το εικονίδιο "Εκτέλεση" στη γραμμή εργαλείων.
7. Αφού ολοκληρωθεί η μακροεντολή, θα εμφανιστεί ένα νέο μήνυμα ηλεκτρονικού ταχυδρομείου του Outlook, το οποίο επισυνάπτεται με ένα απόσπασμα του εγγράφου προέλευσης του Word, όπως το ακόλουθο στιγμιότυπο οθόνης:

Εξαγωγή μέγιστων δεδομένων από κατεστραμμένο αρχείο Outlook

Εάν έχετε χρησιμοποιήσει το Outlook για δεκαετίες, μπορεί να έχετε αντιμετωπίσει διάφορα ζητήματα του Outlook, συμπεριλαμβανομένων αναδυόμενων εσωτερικών μηνυμάτων σφάλματος, ξαφνικών σφαλμάτων καθώς και σοβαρής ζημιάς στα αρχεία. Λόγω του γεγονότος ότι η Σάρωση, το ενσωματωμένο εργαλείο επισκευής, μπορεί να αντιμετωπίσει μόνο τα μικρά προβλήματα, καλύτερα να έχετε ένα εξωτερικό ισχυρό εργαλείο επιδιόρθωσης εύχρηστο, ας πούμε DataNumen Outlook Repair. Είναι σε θέση να αντλήσει τα μέγιστα δεδομένα από το κατεστραμμένο αρχείο δεδομένων του Outlook.

Εισαγωγή συγγραφέα:

Η Shirley Zhang είναι ειδικός ανάκτησης δεδομένων στο DataNumen, Inc., η οποία είναι ο παγκόσμιος ηγέτης στις τεχνολογίες ανάκτησης δεδομένων, συμπεριλαμβανομένων επιδιόρθωση sql και προϊόντα λογισμικού επισκευής προοπτικών. Για περισσότερες πληροφορίες επισκεφθείτε www.datanumen.com