Automatische Verwendung verschiedener Schriftfarben zum Beantworten und Weiterleiten von E-Mails mit Outlook VBA

Standardmäßig können Sie Outlook nicht automatisch unterschiedliche Schriftfarben zum Beantworten und Weiterleiten von E-Mails verwenden lassen. Wenn Sie eine solche Anforderung haben, können Sie diese Seite lesenost einen klugen Ansatz lernen.

In Outlook können Sie nur eine Schriftart angeben, die sowohl zum Beantworten als auch zum Weiterleiten von E-Mails verwendet wird. Sie können zu "Datei"> "Optionen" gehen. Wechseln Sie dann unter "Outlook-Optionen" zur Registerkarte "E-Mail" und klicken Sie auf die Schaltfläche "Briefpapier und Schriftarten ...". Im folgenden Fenster sehen Sie die Schaltfläche „Schriftart“ unter „Antworten oder Weiterleiten von Nachrichten“. Klicken Sie darauf, und Sie können eine bestimmte Schriftfarbe für das Beantworten und Weiterleiten von E-Mails festlegen.

Viele Benutzer hoffen jedoch, unterschiedliche Schriftfarben zum Beantworten oder Weiterleiten von E-Mails verwenden zu können. Obwohl Outlook hierfür keine direkten Funktionen bietet, kann es dennoch mit VBA-Code realisiert werden. Lesen Sie jetzt weiter, um einen solchen VBA-Code zu erhalten.

Automatische Verwendung verschiedener Schriftfarben zum Beantworten und Weiterleiten von E-Mails

1. Für astart Starten Sie die Outlook-Anwendung.
2. Starten Sie dann den VBA-Editor mit dem Verweis auf „So führen Sie VBA-Code in Outlook aus".
3. Als nächstes gemäß „So fügen Sie eine Objektbibliothek hinzurary Referenz in VBAFügen Sie den Verweis auf „MS Word Object Library ”.
4. Kopieren Sie anschließend den folgenden Code in das Projekt "ThisOutlookSession".

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Dim objReply As Outlook.MailItem
    Dim objReplyDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReply = objMail.Reply
    objReply.Display
    Set objReplyDoc = objReply.GetInspector.WordEditor
    objReplyDoc.Range(0, 0).Select
    Set objDocSelection = objReplyDoc.Application.Selection
    'Use "Pink" font in "Reply"
    objDocSelection.Font.ColorIndex = wdPink
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objReplyAll As Outlook.MailItem
    Dim objReplyAllDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReplyAll = objMail.ReplyAll
    objReplyAll.Display
    Set objReplyAllDoc = objReplyAll.GetInspector.WordEditor
    objReplyAllDoc.Range(0, 0).Select
    Set objDocSelection = objReplyAllDoc.Application.Selection
    'Use "Green" font in "Reply All"
    objDocSelection.Font.ColorIndex = wdGreen
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objForward As Outlook.MailItem
    Dim objForwardDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objForward = objMail.Forward
    objForward.Display
    Set objForwardDoc = objForward.GetInspector.WordEditor
    objForwardDoc.Range(0, 0).Select
    Set objDocSelection = objForwardDoc.Application.Selection
    'Use "Blue" font in Forward
    objDocSelection.Font.ColorIndex = wdBlue
End Sub

5. Danach restart Outlook, um dieses Makro zu aktivieren.
6. Schließlich können Sie es versuchen.

• Wählen Sie eine E-Mail aus oder öffnen Sie sie.
• Klicken Sie dann auf die Schaltfläche "Antworten". Bei der Beantwortung von E-Mails können Sie einige Wörter in den Text eingeben. Die Schriftfarbe muss pink sein.
• Oder klicken Sie auf die Schaltfläche "Allen antworten". Geben Sie in der neuen Mail "Allen antworten" Wörter in body ein. Die Schriftfarbe ist sicherlich grün.
• Klicken Sie ebenfalls auf die Schaltfläche "Weiterleiten". In der Weiterleitungsmail werden die neuen Wörter blau angezeigt.

Greifen Sie auf zuverlässige Software zurück

Im Falle von Outlook-Korruption, Most Benutzer greifen in der Regel auf Outlook-Wiederherstellungssoftware zurück. Es gibt eine große Anzahl solcher Programme auf dem Markt. Und einige von ihnen sind sogar kostenlos. Trotzdem sollten Sie sich vor unbekannten Quellen hüten, da diese den aktuellen Fall immer schlimmer machen können. Sie sollten sich an ein zuverlässiges und erfahrenes Werkzeug wenden, wie z DataNumen Outlook Repair.

Einführung des Autors:

Shirley Zhang ist eine Datenrettungsexpertin in DataNumen, Inc., das weltweit führend bei Datenwiederherstellungstechnologien ist, einschließlich beschädigtes SQL und Outlook-Reparatursoftwareprodukte. Für weitere Informationen besuchen Sie www.datanumen.com €XNUMX