Sådan bruges automatisk forskellige skrifttypefarver til besvarelse og videresendelse af e-mails med Outlook VBA

Outlook-løsninger September 29, 2025

Som standard kan du ikke lade Outlook automatisk bruge forskellige skrifttypefarver til at besvare og videresende e-mails. Derfor, hvis du har et sådant krav, kan du læse denne sideost at lære en smart tilgang.

Outlook tillader kun dig at angive en skrifttype, der bruges til både besvarelse og videresendelse af e-mails. Du kan gå til "File"> "Options". Derefter skal du i “Outlook-indstillinger” dreje til “Mail” -fanen og klikke på knappen “Papirvarer og skrifttyper…”. I det efterfølgende vindue kan du se knappen "Font" i "Besvarelse eller videresendelse af meddelelser". Klik på den, og derefter kan du indstille en bestemt skrifttypefarve til besvarelse og videresendelse af e-mails.

Skift skrifttype ved besvarelse eller videresendelse af beskeder

Imidlertid håber mange brugere at bruge forskellige skrifttypefarver til at besvare eller videresende e-mails. Selvom Outlook ikke giver nogen direkte funktioner til dette, kan det stadig realiseres med VBA-kode. Læs videre for at få sådan et stykke VBA-kode.

Brug automatisk forskellige skrifttypefarver til besvarelse og videresendelse af e-mails

  1. For somtart, start Outlook-applikationen.
  2. Derefter udløser VBA-editoren med henvisning til “Sådan køres VBA-kode i din Outlook".
  3. Derefter i overensstemmelse med “Sådan tilføjes et objekt Library Reference i VBA“, Tilføj henvisningen til“ MS Word Object Library ”.
  4. Kopier derefter følgende kode i “ThisOutlookSession” -projektet.
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Dim objReply As Outlook.MailItem
    Dim objReplyDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReply = objMail.Reply
    objReply.Display
    Set objReplyDoc = objReply.GetInspector.WordEditor
    objReplyDoc.Range(0, 0).Select
    Set objDocSelection = objReplyDoc.Application.Selection
    'Use "Pink" font in "Reply"
    objDocSelection.Font.ColorIndex = wdPink
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objReplyAll As Outlook.MailItem
    Dim objReplyAllDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReplyAll = objMail.ReplyAll
    objReplyAll.Display
    Set objReplyAllDoc = objReplyAll.GetInspector.WordEditor
    objReplyAllDoc.Range(0, 0).Select
    Set objDocSelection = objReplyAllDoc.Application.Selection
    'Use "Green" font in "Reply All"
    objDocSelection.Font.ColorIndex = wdGreen
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objForward As Outlook.MailItem
    Dim objForwardDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objForward = objMail.Forward
    objForward.Display
    Set objForwardDoc = objForward.GetInspector.WordEditor
    objForwardDoc.Range(0, 0).Select
    Set objDocSelection = objForwardDoc.Application.Selection
    'Use "Blue" font in Forward
    objDocSelection.Font.ColorIndex = wdBlue
End Sub

VBA-kode - Brug automatisk forskellige skrifttypefarver til besvarelse og videresendelse af e-mails

  1. Derefter restart Outlook for at aktivere denne makro.
  2. Endelig kan du prøve.
  • Vælg eller åbn en e-mail.
  • Klik derefter på “Svar” -knappen. I svar på e-mail kan du skrive nogle ord i brødteksten. Fontfarven skal være lyserød."Pink" skrifttype i "Svar"
  • Eller klik på knappen "Svar alle". I den nye "besvare alle" mail skal du indtaste ord i brødteksten. Fontfarven er helt sikkert grøn."Grøn" skrifttype i "Svar alle"
  • Klik ligeledes på knappen "Videresend". I videresendelsesmailen vises de nye ord med blåt."Blå" skrifttype i "Frem"

Brug pålidelig software

I tilfælde af Outlook korruptionMost brugere har tendens til at ty til Outlook-gendannelsessoftware. Der er en stor mængde af sådanne programmer tilgængelige på markedet. Og nogle af dem er endda gratis. Ikke desto mindre bør du være opmærksom på dem fra ukendte kilder, fordi de kan gøre den nuværende sag værre og værre. Du burde tage hjælp af et pålideligt og erfaren værktøj, ligesom DataNumen Outlook Repair.

Forfatter Introduktion:

Shirley Zhang er ekspert i datagendannelse i DataNumen, Inc., som er verdens førende inden for datagendannelsesteknologier, herunder beskadiget sql og Outlook-reparationssoftwareprodukter. For mere information besøg www.datanumen.com

Kommentarer er lukket.