Jak automaticky používat různé barvy písma pro odpovídání a přeposílání e-mailů pomocí aplikace Outlook VBA

Ve výchozím nastavení nemůžete nechat Outlook automaticky používat různé barvy písma pro odpovídání a přeposílání e-mailů. Pokud tedy máte takový požadavek, můžete si přečíst tuto strost naučit se chytrý přístup.

Outlook umožňuje pouze určit písmo použité pro odpovídání i přeposílání e-mailů. Můžete přejít na „Soubor“> „Možnosti“. Poté v části „Možnosti aplikace Outlook“ přejděte na kartu „Pošta“ a klikněte na tlačítko „Šablony a písma…“. V následujícím okně uvidíte tlačítko „Písmo“ v části „Odpovídání nebo přeposílání zpráv“. Klikněte na něj a poté můžete nastavit konkrétní barvu písma pro odpovídání a přeposílání e-mailů.

Mnoho uživatelů však doufá, že pro odpovídání nebo přeposílání e-mailů použije různé barvy písma. Ačkoli Outlook pro to neposkytuje žádné přímé funkce, stále jej lze realizovat pomocí kódu VBA. Nyní čtěte dále a získejte takový kus kódu VBA.

Automaticky používat různé barvy písma pro odpovídání a přeposílání e-mailů

1. Pro jakotart, spusťte aplikaci Outlook.
2. Poté spusťte editor VBA s odkazem na „Jak spustit kód VBA ve vašem Outlooku".
3. Dále v souladu s „Jak přidat objekt Library Reference ve VBA“, Přidat odkaz na„ MS Word Object Library “.
4. Následně zkopírujte následující kód do projektu „ThisOutlookSession“.

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Dim objReply As Outlook.MailItem
    Dim objReplyDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReply = objMail.Reply
    objReply.Display
    Set objReplyDoc = objReply.GetInspector.WordEditor
    objReplyDoc.Range(0, 0).Select
    Set objDocSelection = objReplyDoc.Application.Selection
    'Use "Pink" font in "Reply"
    objDocSelection.Font.ColorIndex = wdPink
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objReplyAll As Outlook.MailItem
    Dim objReplyAllDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReplyAll = objMail.ReplyAll
    objReplyAll.Display
    Set objReplyAllDoc = objReplyAll.GetInspector.WordEditor
    objReplyAllDoc.Range(0, 0).Select
    Set objDocSelection = objReplyAllDoc.Application.Selection
    'Use "Green" font in "Reply All"
    objDocSelection.Font.ColorIndex = wdGreen
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objForward As Outlook.MailItem
    Dim objForwardDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objForward = objMail.Forward
    objForward.Display
    Set objForwardDoc = objForward.GetInspector.WordEditor
    objForwardDoc.Range(0, 0).Select
    Set objDocSelection = objForwardDoc.Application.Selection
    'Use "Blue" font in Forward
    objDocSelection.Font.ColorIndex = wdBlue
End Sub

5. Poté restar• Outlook aktivovat toto makro.
6. Nakonec to můžete vyzkoušet.

• Vyberte nebo otevřete e-mail.
• Poté klikněte na tlačítko „Odpovědět“. Při odpovědi na e-mail můžete do textu zadat některá slova. Barva písma musí být růžová.
• Nebo klikněte na tlačítko „Odpovědět všem“. V nové poště „odpovídání na všechny“ zadejte slova do textu. Barva písma je určitě zelená.
• Podobně klikněte na tlačítko „Vpřed“. V přeposílané poště budou nová slova zobrazena modře.

Využijte spolehlivý software

V případě Outlook korupce, Most uživatelé mají tendenci se uchýlit k softwaru pro obnovu Outlook. Na trhu existuje velké množství takových programů. A některé z nich jsou dokonce zdarma. Měli byste si však dávat pozor na ty z neznámých zdrojů, protože mohou současný případ zhoršit a zhoršit. Měli byste využít spolehlivý a zkušený nástroj DataNumen Outlook Repair.

Úvod autora:

Shirley Zhang je expertem na obnovu dat DataNumen, Inc., která je světovým lídrem v oblasti technologií pro obnovu dat, včetně poškozený sql a výhledové softwarové produkty pro opravy. Pro více informací navštivte www.datanumen.com