Kako brzo izdvojiti priloge iz svih Outlook datoteka s porukama u Windows folderu

Možda ste pohranili više Outlook poruka e-pošte u .msg formatu u Windows folder. I kasnije, ako želite da izdvojite priloge iz ovih datoteka, možete koristiti način na koji se dijeli u ovom članku.

Prilično je lako izdvojiti priloge iz e-poruka u vašem Outlooku. Ali šta je sa e-porukama koje su izvezene kao .msg datoteke u Windows folderu? Općenito, prvo morate otvoriti ove .msg datoteke u svom Outlooku, a zatim spremiti priloge iz njih jedan po jedan. Možda ćete se osjećati previše nezgrapnim. Dakle, nakon toga ćemo vas naučiti još jednom mnogo bržem rješenju.

Izvucite priloge iz svih Outlook datoteka s porukama u Windows folderu

1. Za početak, start svoju Outlook aplikaciju i pokrenite VBA editor.
2. Zatim, u prozoru „Microsoft Visual Basic za aplikacije“, kopirajte VBA kod u nastavku u modul koji se ne koristi.

Dim strAttachmentFolder As String

Sub ExtractAttachmentsFromEmailsStoredinWindowsFolder()
    Dim objShell, objWindowsFolder As Object
 
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       'Create a new folder for saving extracted attachments
       strAttachmentFolder = "E:\Attachments-" & Format(Now, "MMDDHHMMSS") & "\"
       MkDir (strAttachmentFolder)
       Call ProcessFolders(objWindowsFolder.self.Path & "\")
       MsgBox "Completed!", vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessFolders(strFolderPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFiles As Object
    Dim objFile As Object
    Dim objItem As Object
    Dim i As Long
    Dim objSubFolder As Object

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strFolderPath)
    Set objFiles = objFolder.Files
 
    For Each objFile In objFiles
        If objFileSystem.GetExtensionName(objFile) = "msg" Then
           'Open the Outlook emails stored in Windows folder
           Set objItem = Session.OpenSharedItem(objFile.Path)

           If TypeName(objItem) = "MailItem" Then
              If objItem.Attachments.Count > 0 Then
                 'Extract attachments
                 For i = objItem.Attachments.Count To 1 Step -1
                     objItem.Attachments(i).SaveAsFile strAttachmentFolder & objItem.Attachments(i).FileName
                 Next
              End If
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubFolder In objFolder.SubFolders
           If ((objSubFolder.Attributes And 2) = 0) And ((objSubFolder.Attributes And 4) = 0) Then
              Call ProcessFolders(objSubFolder.Path)
           End If
       Next
    End If
End Sub

3. Nakon toga, pomaknite kursor u prvu potprogram i pritisnite tipku “F5”.
4. Nakon toga, od vas će se tražiti da odaberete izvorni Windows folder u iskačućem dijaloškom okviru.
5. Nakon klika na “OK”, makro će nastaviti da radi.
6. Kada se završi, dobićete poruku "Završeno".
7. Sada možete dobiti pristup unaprijed definiranoj lokalnoj mapi za spremanje ekstrahiranih priloga.

Efikasno riješite probleme s Outlookom

Budući da je Outlook sklon greškama, morate biti oprezni dok radite sa Outlook objektima, kao što je nikada ne vjerovati datotekama ili vezama ugrađenim u nepoznate e-poruke i tako dalje. U suprotnom, vaša Outlook datoteka može se lako oštetiti. Pod tim okolnostima, čak ni alat za unutrašnje popravke neće biti od velike pomoći. Ono čemu možete pribjeći je samo iskusan vanjski uslužni program, na primjer DataNumen Outlook Repair. Može popraviti PST datoteku s lakoćom.

Uvod za autora:

Shirley Zhang je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oštećen sql i Outlook softverski proizvodi za popravku. Za više informacija posjetite www.datanumen.com