How to Quickly Find All Outlook Rules that Auto Forward Emails to a Specific Person

This post will teach you a method to quickly find all rules which configure Outlook to auto forward emails to a specific person.

If you’ve created a great amount of rules in Outlook and now need to make some modifications on specific rules, such as the rules that auto forward emails to a specific person, since Outlook doesn’t provide features to search rules, you have to manually find the specific rules. It can be considerably troublesome in face of multiple rules. Therefore, here we’ll teach  a quick means to find all the rules that auto forward emails to a specific person.

Quickly Find All Rules that Auto Forward Emails to a Specific Person

  1. At the outset, launch Outlook application.
  2. Then, get access to VBA editor according to “How to Run VBA Code in Your Outlook“.
  3. Next, put the following code into an unused module.
Sub FindAllRules_AutoForwardEmailsToSpecificPerson()
    Dim strFind As String
    Dim objRules As Outlook.Rules
    Dim i As Long
    Dim objRule As Outlook.Rule
    Dim objRuleAction As Outlook.RuleAction
    Dim objForwardAction As Outlook.SendRuleAction
    Dim objFWActionRecipients As Outlook.Recipients
    Dim objFWActionRecipient As Outlook.Recipient
    Dim strFWRecipients As String
 
    'Enter the email address of the specific person
    strFind = InputBox("Specify the email address:", "Find", "johnsmith@datanumen.com")
 
    If strFind <> "" Then
       Set objRules = Outlook.Application.Session.DefaultStore.GetRules
 
       For i = objRules.Count To 1 Step -1
           Set objRule = objRules(i)
 
           strFWRecipients = ""
           For Each objRuleAction In objRule.Actions
               If (objRuleAction.ActionType = olRuleActionForward) Or (objRuleAction.ActionType = olRuleActionForwardAsAttachment) Then
 
                  Set objForwardAction = objRuleAction
                  Set objFWActionRecipients = objForwardAction.Recipients
 
                  For Each objFWActionRecipient In objFWActionRecipients
                      strFWRecipients = objFWActionRecipient.Name & " - " & objFWActionRecipient.Address & " ; " & strFWRecipients
                  Next
               End If
           Next
 
           If InStr(strFWRecipients, strFind) > 0 Then
              objRule.Enabled = True
              objRules.Save
           ElseIf strFWRecipients = "" Then
              objRule.Enabled = False
              objRules.Save
           End If
       Next
    End If
End Sub

VBA Code - Quickly Find All Rules that Auto Forward Emails to a Specific Person

  1. After that, run this macro via either pressing “F5” key or clicking the “Run” in toolbar.
  2. Then, you need enter the specific person’s email address in the small dialog box.Specify Person
  3. Finally, after the macro finishes, you can go to “File” menu and click “Manage Rules & Alerts” button.
  4. In the new “Rules and Alerts” window, as you can see, only the rules, which auto forward mails to the specific person, are enabled with a tick. And the other rules are disabled, like the following screenshot.Only Specific Rules Are Enabled

When Outlook Data Is Virus-infected

Similar to other ordinary files, Outlook PST file can be attacked by viruses and malware easily. It is because that email borne viruses are considerably common. For instance, once you download any malicious email attachments, your Outlook file can be corrupted. At that point, you have no choice but to take aid of a potent PST repair tool, such as DataNumen Outlook Repair.

Author Introduction:

Shirley Zhang is a data recovery expert in DataNumen, Inc., which is the world leader in data recovery technologies, including repair mdf and outlook repair software products. For more information visit www.datanumen.com

Leave a Reply

Your email address will not be published. Required fields are marked *