How to Batch Remove the Pictures in the Business Cards of All Outlook Contacts

If you want to batch remove the pictures in the business cards of all contacts, namely changing all business cards to “Text Only” style, you can use the way in this article. It can let you accomplish such a seemingly troublesome task in a jiffy.

When you add a photo to a contact, the photo will be auto added to the contact’s business card. Then, if you prefer to show business cards in “Text Only” style, you have to manually remove the pictures in business cards one by one. That could be quite cumbersome and tedious. Thus, in the followings, we will teach you a much handier approach. It allows you to realize it in batches.

Batch Remove the Pictures in the Business Cards of All Contacts

  1. At the very beginning, start Outlook and open a Contacts folder.
  2. Then, double click on a contact to open it.
  3. Next, in the opened Contact window, double click on the “Business Card”.
  4. In the subsequent “Edit Business Card” dialog box, choose “Text Only” from the drop down list of “Layout”.Change Business Card Layout to "Text Only"
  5. Later, click “OK” and save this contact.
  6. After that, keep selecting this contact and press “Alt + F11” to trigger Outlook VBA editor.
  7. In the displayed “Microsoft Visual Basic for Applications” window, copy the following VBA code into a module.
Dim objModelContact As Outlook.ContactItem

Sub RemovePicturesBusinessCard_AllContacts()
    Dim objStore As Outlook.Store
    Dim objFolder As Outlook.Folder
 
    'Get the model contact whose business card is "Text Only".
    Set objModelContact = Outlook.Application.ActiveExplorer.Selection.Item(1)
 
    For Each objStore In Outlook.Application.Session.Stores
        For Each objFolder In objStore.GetRootFolder.Folders
            If objFolder.DefaultItemType = olContactItem Then
               Call ProcessContactsFolders(objFolder)
            End If
        Next
    Next
End Sub

Sub ProcessContactsFolders(ByVal objContactsFolder As Outlook.Folder)
    Dim i As Integer
    Dim objContact As Outlook.ContactItem
    Dim objSubfolder As Outlook.Folder
 
    For i = objContactsFolder.Items.Count To 1 Step -1
        If objContactsFolder.Items(i).Class = olContact Then
           Set objContact = objContactsFolder.Items(i)

           objContact.BusinessCardLayoutXml = objModelContact.BusinessCardLayoutXml
           objContact.Save
        End If
    Next
 
    'Process all subfolders recursively
    If objContactsFolder.Folders.Count > 0 Then
       For Each objSubfolder In objContactsFolder.Folders
           Call ProcessContactsFolders(objSubfolder)
       Next
    End If
End Sub

VBA Code - Batch Remove the Pictures in the Business Cards of All Contacts

  1. After that, tap on “F5” key button to run this macro now.
  2. Finally, when macro finishes, you can go back to Contacts folders. You will see that the pictures in all contacts’ business cards have been removed.All Pictures in Business Cards Are Removed

Manage Your Outlook Items Well

As a regular user of Outlook, you are likely to have a great amount of items in the Outlook, including miscellaneous emails, various contacts, numerous calendar items, etc. In face of so many items, you should regularly clean up the useless and old items from your Outlook. Otherwise, over time, Outlook file can get oversized. Then, it will become more prone to corruption. Once your PST file is corrupt, you will need to resort to an outstanding and reliable Outlook recovery tool, such as DataNumen Outlook Repair to get back valuable Outlook data.

Author Introduction:

Shirley Zhang is a data recovery expert in DataNumen, Inc., which is the world leader in data recovery technologies, including mdf repair and outlook repair software products. For more information visit www.datanumen.com