How to Batch Open Multiple RSS Articles in Web Browser with Outlook VBA

At times, when viewing RSS items in your Outlook, you may want to see the original post in web browser. It’s easy to view a single RSS article. But, if you want to bath process multiple RSS articles, you’d better use the smart method in this article.

Perhaps you’ve subscribed some RSS feeds in your Outlook. In this way, you can receive the latest updated posts of the relevant websites or blogs. Yet, the RSS items in Outlook are in Plain Text format. That means they lack the formats of the original posts. Therefore, sometimes, you may want to view the original posts in web browser. In this situation, you can select a RSS item and click “View Article” button in the ribbon, which will quickly access the website of the article.View RSS Article

But, if you want to batch open multiple RSS articles in web browser, the standard way above is too troublesome. Hence, here we will introduce another way that is much more efficient.

Batch Open Multiple RSS Articles in Web Browser

  1. To begin with, trigger Outlook VBA editor.
  2. Then, put the following VBA code into an unused module.
Sub BatchOpenMultipleRSSArticles()
    Dim objDictionary As Object
    Dim objSelection As Outlook.Selection
    Dim objRSSItem As Outlook.PostItem
    Dim i As Long
    Dim strArticleURL As String
    Dim objInternetExplorer As Object
    Dim n As Integer
    Dim varArticleURLs As Variant
    Dim varArticleURL As Variant
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
    'Get selected RSS Items
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
 
    For i = objSelection.Count To 1 Step -1
        If TypeOf objSelection(i) Is PostItem Then
           Set objRSSItem = objSelection(i)
 
           'Get the Article URL of the RSS Item
           strArticleURL = objRSSItem.PropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/id/{00062041-0000-0000-C000-000000000046}/8901001F")
 
           'Add URLs to Dictionary
           If objDictionary.Exists(strArticleURL) = False Then
              objDictionary.Add strArticleURL, 1
           End If
        End If
    Next
 
    'Open RSS Articles in Internet Explorer
    Set objInternetExplorer = CreateObject("InternetExplorer.Application")
    varArticleURLs = objDictionary.Keys
    For n = LBound(varArticleURLs) To UBound(varArticleURLs)
        varArticleURL = varArticleURLs(n)
 
        If n = 0 Then
           objInternetExplorer.Visible = True
           objInternetExplorer.navigate varArticleURL
        Else
           objInternetExplorer.navigate varArticleURL, CLng(2048)
        End If
    Next
End Sub

VBA Code - Batch Open Multiple RSS Articles in Web Browser

  1. Next, follow the “Optional Step” introduced in the article – “How to Run VBA Code in Your Outlook” to add this macro to Quick Access Toolbar or ribbon.
  2. Finally, you can try this macro.
  • At first, select the RSS items which you want to view in web browser.
  • Then, click the macro button in Quick Access Toolbar or ribbon.Run Macro on Selected RSS Items
  • At once, the RSS articles will be opened in the Internet Explorer, like the following screenshot.Batch Opened RSS Articles

Restore Corrupt Outlook Data

There are multiple factors due to which Outlook data can become compromised, such as human errors, virus infection, software faults and hardware failures. In a nutshell, although you keep cautious all the time, unexpected disasters can take place at any time. Hence, you ought to learn how to cope with Outlook corruption. Generally speaking, when suffering this issue, you can firstly try the inbox repair tool. And if it fails, you can continue taking recourse to an reliable external tool, such as DataNumen Outlook Repair.

Author Introduction:

Shirley Zhang is a data recovery expert in DataNumen, Inc., which is the world leader in data recovery technologies, including mdf fix and outlook repair software products. For more information visit www.datanumen.com