How to Batch Export the URLs of Multiple RSS Articles from Outlook to Excel

If you want to quickly export the URLs of multiple RSS articles from your Outlook to an Excel worksheet, you can employ the method introduced in this article. It is able to let you accomplish this in bulk.

Maybe you have subscribed multiple RSS feeds in your Outlook. In this way, you don’t need to check your favorite website or blogs by accessing them one by one in Internet browser every time. You can check all of them directly in your Outlook. Now, when viewing and discovering some important RSS articles, you may want to export and record their URLs to an Excel worksheet. In the followings, we will introduce you a method to batch export multiple RSS articles’ URLs to Excel.

Batch Export the Full Article URLs of Multiple RSS Articles to Excel

  1. At the very beginning, start your Outlook program.
  2. Then, get access to VBA editor via “Alt + F11” keys.
  3. Next, enable “MS Excel Object Library Reference” according to “How to Add an Object Library Reference in VBA“.
  4. Subsequently, put the following code into an unused module.
Sub BatchExportRSSArticleURLs()
    Dim objSelection As Outlook.Selection
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim objRSSItem As Outlook.PostItem
    Dim i As Long
    Dim strArticleURL As String
    Dim nLastRow As Integer
 
    'Get selected RSS Items
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
 
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "RSS Article"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 2) = "URL"
         .Cells(1, 2).Font.Bold = True
    End With
 
    For i = objSelection.Count To 1 Step -1
        If TypeOf objSelection(i) Is PostItem Then
           Set objRSSItem = objSelection(i)
 
           'Get the Article URL of the RSS Item
           strArticleURL = objRSSItem.PropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/id/{00062041-0000-0000-C000-000000000046}/8901001F")
 
           'Export URLs to Excel
           nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
           objExcelWorksheet.Range("A" & nLastRow) = objRSSItem.Subject
           objExcelWorksheet.Range("B" & nLastRow) = strArticleURL
        End If
    Next
 
    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

VBA Code - Batch Export the Full Article URLs of Multiple RSS Items to Excel

  1. Later, add this macro to Quick Access Toolbar (QAT) or ribbon with reference to “How to Run VBA Code in Your Outlook“.
  2. Finally, you can take a shot.
  • To begin with, select multiple RSS items.
  • Then, click the macro button in QAT or ribbon.Run Macro on Selected RSS Articles
  • At once, an Excel worksheet will display, which are recording the URLs of all the selected RSS articles.Exported RSS Article URLs in Excel

Extract Maximum Outlook Data from Corrupt PST

You must be worried when your Outlook PST file is compromised. In general, the inbox repair tool is a recommended tool that you can employ in the first place. If it fails, you can purchase a more experienced and reliable external utility, such as DataNumen Outlook Repair. It is capable of dealing with PST corruption, getting back maximum PST data like a breeze.

Author Introduction:

Shirley Zhang is a data recovery expert in DataNumen, Inc., which is the world leader in data recovery technologies, including SQL Server corruption and outlook repair software products. For more information visit www.datanumen.com

Comments are closed.