How to Auto Disable the Reminders of All “Free” Calendar Items in Your Outlook

Perhaps you frequently need to disable the reminders of the “free” calendar items manually. Now, in this article, we’ll introduce a method to let Outlook auto realize it.

If you’ve enabled and set a default reminder time for calendar items, every time when you create a new calendar item, it will be taken with an enabled reminder, irrespective of whether the item is shown as “free”, “busy” or others. Yet, you may wish that the “free” calendar items have no reminder. Therefore, in general, you always need to manually disable the reminders. But this way is too troublesome. So, in the followings, we will share a method to configure Outlook to auto disable the reminders of “free” calendar items.

Default Reminder for Calendar Items

Auto Disable the Reminders of All “Free” Calendar Items

  1. To start with, launch Outlook program.
  2. Then, trigger Outlook VBA editor with accordance to “How to Run VBA Code in Your Outlook“.
  3. Next, put the following code into the “ThisOutlookSession” project.
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objAppointment As Outlook.AppointmentItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olAppointment Then
       Set objAppointment = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olAppointment Then
       Set objAppointment = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objAppointment_Open(Cancel As Boolean)
    Call DisableReminderForFreeItem(objAppointment)
End Sub

Private Sub objAppointment_PropertyChange(ByVal Name As String)
    If Name = "BusyStatus" Then
       Call DisableReminderForFreeItem(objAppointment)
    End If
End Sub

Private Sub DisableReminderForFreeItem(ByVal objAppointment As Outlook.AppointmentItem)
    'Auto disable reminder of free calendar item
    If objAppointment.BusyStatus = olFree Then
       objAppointment.ReminderSet = False
    End If
End Sub

VBA Code - Auto Disable the Reminders of All "Free" Calendar Items

  1. After that, move cursor to the “Application_Startup” subroutine.
  2. Later, press “F5” key button to run this macro.
  3. Finally, you can have a try.
  • First off, create a new appointment.
  • Then, select “Free” from the dropdown list of “Show As”.Change "Show As" to "Free"
  • At once, you can see that the reminder has been changed to “None”.Disabled Reminders for "Free" Calendar Items

Take It Easy In Case of Outlook Corruption

A Majority of users tend to get panic and frustrating when they come across PST corruption in Outlook. Of course, you can be worried for a while. Yet, you have to calm down as soon as possible and take immediate operations to rescue corrupt Outlook data. It can be achieved by either inbox repair tool or a proficient third party tool, such as DataNumen Outlook Repair.

Author Introduction:

Shirley Zhang is a data recovery expert in DataNumen, Inc., which is the world leader in data recovery technologies, including recover sql and outlook repair software products. For more information visit

Comments are closed.