How to Batch Open & View Multiple Outlook Emails in Your Browser

Many objects, such as gif animates, are not supported in Outlook emails. If you hope to view these objects, you can view emails in browser. In this article, we will teach you how to batch open multiple emails in your browser.

When you insert gif or flash animations into an Outlook email, you will find that they are static, not animated. If you receive many such emails and want to view these inserted objects in proper status, you can view them in browser. To do this for one email, you can just open it and then click “Actions” and “View in Browser”. Yet, if you wish to perform on multiple emails, the above way is too tedious. Thus, in the followings, we will teach you a more efficient way.Batch Open & View Multiple Outlook Emails in Browser

Batch Open & View Multiple Emails in Browser

  1. At the very outset, launch Outlook application.
  2. Then, get access to VBA editor by “Alt + F11”.
  3. Next, put the following VBA code into a module.
Sub BatchOpenViewEmailsInBrowser()
    Dim objSelection As Outlook.Selection
    Dim strTempFolder As String
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim strSubject As String
    Dim strHTMLFile As String
    Dim objInternetExplorer As Object

    Set objSelection = Application.ActiveExplorer.Selection
 
    If Not (objSelection Is Nothing) Then
       'Save the selected emails as HTML files in Temp folder
       strTempFolder = CStr(Environ("USERPROFILE")) & "\AppData\Local\Temp\Mails" & Format(Now, "yyyymmddhhmmss") & "\"
       MkDir (strTempFolder)
 
       For i = objSelection.Count To 1 Step -1
           If TypeOf objSelection(i) Is MailItem Then
              Set objMail = objSelection(i)
              strSubject = objMail.Subject
 
              strSubject = Replace(strSubject, "/", " ")
              strSubject = Replace(strSubject, "\", " ")
              strSubject = Replace(strSubject, ":", "")
              strSubject = Replace(strSubject, "?", " ")
              strSubject = Replace(strSubject, Chr(34), " ")
 
              objMail.SaveAs strTempFolder & strSubject & ".htm", olHTML
           End If
       Next
 
       'Open the HTML files in Internet Explorer
       strHTMLFile = Dir(strTempFolder)

       Do While Len(strHTMLFile) > 0
          Set objInternetExplorer = CreateObject("InternetExplorer.Application")
          objInternetExplorer.Visible = True
          objInternetExplorer.navigate strTempFolder & strHTMLFile
          Set objInternetExplorer = Nothing
          strHTMLFile = Dir
       Loop
    End If
End Sub

VBA Code - Batch Open & View Multiple Emails in Browser

  1. Afterwards, exit the current window.
  2. Later, add this macro to Quick Access Toolbar according to “How to Run VBA Code in Your Outlook“.Add Macro to Quick Access Toolbar
  3. Eventually, follow the steps below to try this macro.
  • Firstly, select several emails in the mail list.
  • Then, click the macro button in Quick Access Toolbar.Run Macro on Selected Emails
  • Immediately, these emails will be opened in your Internet Explorer, like the following screenshot.Opened Emails in Browser

Protect Your Outlook from Damage

Nowadays, data losses are occurring almost every day everywhere. Therefore, it’s common that many users complain that their Outlook file gets damaged. In such cases, you will definitely proceed to attempt PST repair. Generally, you can firstly try the inbuilt fix tool – Scanpst. Nevertheless, it may not help you. At that time, you need resort to an external versatile repair tool, such as DataNumen Outlook Repair.

Author Introduction:

Shirley Zhang is a data recovery expert in DataNumen, Inc., which is the world leader in data recovery technologies, including corrupt sql and outlook repair software products. For more information visit www.datanumen.com