How to Batch Disable All Custom Conditional Formatting Rules in Your Outlook

In Outlook, you can create various custom conditional formatting rules to change the display font and color of the items. If one day you desire to batch disable all of such custom rules, you can use the method introduced in this article.

Conditional formatting feature allows users to use different fonts and colors to highlight the emails based on their custom criteria. It is pretty convenient. But if afterwards, for some reasons, like resetting the view, you may hope to disable all these custom conditional formatting rules. In this case, you had better utilize the following way, which can help you achieve it in bulk.

Batch Disable All Custom Conditional Formatting Rules in Your Outlook

Batch Disable All Custom Conditional Formatting Rules

  1. At the very outset, launch your Outlook application.
  2. Then, in the Outlook main window, you should press “Alt + F11” key buttons.
  3. Next, the “Microsoft Visual Basic for Applications” window will display. In it, you should open a module which is not in use.
  4. Subsequently, copy and paste the following VBA code into this module.
Sub DisableAllCustomConditionalFormattingRules()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Select a specific Outlook data file
    Set objOutlookFile = Application.Session.PickFolder
 
    If Not (objOutlookFile Is Nothing) Then
       For Each objFolder In objOutlookFile.Folders
           Call ProcessFolder(objFolder)
       Next
       MsgBox "Completed!", vbExclamation
    End If
End Sub

Sub ProcessFolder(ByVal objCurrentFolder As Outlook.Folder)
    Dim objView As Outlook.TableView
    Dim objRule As Outlook.AutoFormatRule
    Dim objSubfolder As Outlook.Folder
 
    If objCurrentFolder.DefaultItemType = olMailItem Then
       If objCurrentFolder.CurrentView.ViewType = olTableView Then
          Set objView = objCurrentFolder.CurrentView
 
          'Disable all conditional formatting rules
          For Each objRule In objView.AutoFormatRules
              If Not objRule.Standard Then
                 objRule.Enabled = False
              End If
          Next

          objView.Save
          objView.Apply
       End If
 
       'Process subfolders recursively
       If objCurrentFolder.Folders.count > 0 Then
          For Each objSubfolder In objCurrentFolder.Folders
              Call ProcessFolder(objSubfolder)
          Next
       End If
    End If
End Sub

VBA Code - Batch Disable All Custom Conditional Formatting Rules

  1. After that, you can trigger this macro by hitting the “Run” icon the toolbar or simply hitting F5 key button.
  2. Later, you’ll be required to select a source Outlook data file under which you want to disable all the conditional formatting rules.Select a Specific Outlook Data File
  3. After you selecting one file and click “OK”, the macro will start to disable all of the custom formatting rules.
  4. When the macro completes, you’ll get a prompt suggesting “Completed”. Now, you can check “View Settings” > “Conditional Formatting” in each folder. Finally, you will see that all the custom conditional formatting rules have been disabled.

What If Outlook Crashes

Although Outlook boasts of myriad features, it is still error prone. At worst, it can crash without any warnings. Therefore, what should you do in the event of crash? Generally, you can try the inbox repair tool to fix PST issues in the first place. But if it fails, you can proceed to resort to an external tool, like DataNumen Outlook Repair.

Author Introduction:

Shirley Zhang is a data recovery expert in DataNumen, Inc., which is the world leader in data recovery technologies, including sql corruption and outlook repair software products. For more information visit www.datanumen.com