How to Auto Check and Display If the Incoming Emails Are BCC’d to You with Outlook VBA

In order to prevent yourself from replying the emails which are simply BCC’d to you, you must desire that Outlook can auto check and display if the incoming emails are BCC’d to you. This post will teach you how to create a new column for the “BCC” info with Outlook VBA.

Actually in my previous article – “How to Auto Mark Each Email BCC’d To You with a Warning Notice in Outlook”, I’ve introduced a workaround that can create a warning for the emails BCC’d to you, like the following screenshot. This method is making use of a rule and color categories.

BCC Warning via Rule & Categories

Unlike the above means, the following method will use Outlook VBA to create a new column which is dedicated for this “if the incoming emails are BCC’d to you” information, shown as the image below:

New Column to Display If the Incoming Emails Are BCC’d to You

Auto Display If the Incoming Emails Are BCC’d to You

  1. In the first place, launch Outlook and press “Alt + F11” key buttons.
  2. In the popup “Microsoft Visual Basic for Applications” window, then you ought to open a new module.
  3. Then copy and paste the following VBA codes into it.
Sub CheckBCC()
    Dim objItems As Outlook.Items
    Dim objItem As Object
    Dim objProperty As Outlook.UserProperty
    Dim strTo As String
    Dim strCC As String
    Dim strBCC As String
    Dim strMyName As String
 
    Set objItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
 
    For Each objItem In objItems
        strTo = objItem.To
        strCC = objItem.CC
 
        'Change to your own name in low case
        strMyName = "datanumen"
 
        If (InStr(LCase(strTo), strMyName) > 0) Or (InStr(LCase(strCC), strMyName) > 0) Then
           strBCC = "NOT BCC'd"
        Else
           strBCC = "BCC'd"
        End If
 
        Set objProperty = objItem.UserProperties.Add("BCC'd Or NOT", olText, True)
        objProperty.Value = strBCC
        objItem.Save
    Next
End Sub

VBA Codes - Display BCC Information for the Existing Emails

  1. Next click the “Run” button to start the current macro.Run the Current Macro
  2. Subsequently, you ought to open the “ThisOutlookSession” project and copy the following codes into it.
Public WithEvents objItems As Outlook.Items

Private Sub Application_Startup()
    Set objItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub objItems_ItemAdd(ByVal Item As Object)
    Dim objProperty As Outlook.UserProperty
    Dim strTo As String
    Dim strCC As String
    Dim strBCC As String
    Dim strMyName As String
 
    If Item.Class = olMail Then
       strTo = Item.To
       strCC = Item.CC
 
       'Change to your own name in low case
       strMyName = "datanumen"
 
       If InStr(LCase(strTo), strMyName) > 0 Or InStr(LCase(strCC), strMyName) > 0 Then
          strBCC = "NOT BCC'd"
       Else
          strBCC = "BCC'd"
       End If
 
       Set objProperty = Item.UserProperties.Add("BCC'd Or NOT", olText, True)
       objProperty.Value = strBCC
       Item.Save
    End If
End Sub

VBA Codes - Auto Check and Display If the Incoming Emails Are BCC’d to You

  1. After that, you need to sign the “ThisOutlookSession” VBA project and change your Outlook macro security level to low.
  2. Later you can back to your email list and add the new “BCC’d Or NOT” field.
  • Firstly, switch to “View” tab and click on “View Settings” button.
  • In the new popup dialog box, then hit “Columns” button.
  • Then in “Show Columns” dialog box, select “User-defined fields in Inbox” in the “Select available columns” from.
  • After that, pitch on “BCC’d Or NOT” field.
  • Subsequently, click “Add” button.
  • Then optionally you can change the column order.
  • Lastly click a series of “OK” to close all the dialog boxes.Add the "BCC'd Or NOT" Column
  1. Eventually, after you back to the email list, you will see the new column. Also, from now on, Outlook will auto check if you’re BCC’d in all incoming emails and display the information in the new “BCC’d Or NOT” column.

Keep Mindful of All Risks around Your Outlook Data

Outlook does a good job as an email client, but it doesn’t mean that you’ll never encounter any troubles in it. Outlook is error prone. So you should keep cautious all the time. Perhaps, you may push your Outlook data into danger accidentally. If you suffer serious PST data error, then the inbox repair tool, Scanpst.exe won’t be a lot of help. You would be required to recur to a more powerful one like DataNumen Outlook Repair, which is good at fixing Outlook issues.

Author Introduction:

Shirley Zhang is a data recovery expert in DataNumen, Inc., which is the world leader in data recovery technologies, including mdf corruption repair and outlook repair software products. For more information visit www.datanumen.com

Comments are closed.